VPF::Совместное использование EhLib и FIBPlus

bruha

Дата 11.6.2006, 16:02 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 13
Регистрация: 11.6.2006

Репутация: нет
Всего: нет

В ehlib нет драйверов под fibplus, и хотя все данные из датасета отображаются нормально, хотелось бы также иметь возможность локальной сортировки и фильтра.
Подскажите решение этой проблемы.

PS если у кого есть, очень нужен полный русский хелп по EhLib, заранее благодарен (-8 мыло [email protected]

Alex

Дата 12.6.2006, 22:17 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Экс. модератор
Сообщений: 4147
Регистрация: 25.3.2002
Где: Москва

Репутация: 17
Всего: 162

Код


unit EhLibFIB;

{$I EhLib.Inc}

interface

uses
  Classes, SysUtils, DB, 
  DbUtilsEh, DBGridEh, pFIBDataSet;

type
  TFIBDatasetFeaturesEh = class(TSQLDatasetFeaturesEh)
  public
    constructor Create; override;
    procedure ApplySorting(Sender: TObject; DataSet: TDataSet; IsReopen: Boolean); override;
    procedure ApplyFilter(Sender: TObject; DataSet: TDataSet; IsReopen: Boolean); override;
  end;

implementation

function DateValueToIBSQLStringProc(DataSet: TDataSet; Value: Variant): String;
begin
  Result := '''' + FormatDateTime('MM"/"DD"/"YYYY', Value) + '''';
end;

constructor TFIBDatasetFeaturesEh.Create; 
begin
  DateValueToSQLString := DateValueToIBSQLStringProc;
  SQLPropName := 'SelectSQL';
end;

procedure TFIBDatasetFeaturesEh.ApplySorting(Sender: TObject; DataSet: TDataSet; IsReopen: Boolean);
var FLD  : array of TVarRec ;
    sort : array of boolean;
    I,J  : integer;
    Grid : TCustomDBGridEh;
begin
  if Sender is TCustomDBGridEh then begin
    Grid:=TCustomDBGridEh(Sender);
    J:=Grid.SortMarkedColumns.Count;
    setlength(fld,J);setlength(sort,J);
    for i:=0 to pred(j) do
      begin
       fld[i].VType:=vtAnsiString;
       string(fld[i].VString):=Grid.SortMarkedColumns[i].fieldname;
       sort[i]:=Grid.SortMarkedColumns[i].Title.SortMarker=smDownEh;
      end;
      TpFibDataset(Dataset).DoSort(fld,sort);
    end;
end;

procedure TFIBDatasetFeaturesEh.ApplyFilter(Sender: TObject; DataSet: TDataSet; IsReopen: Boolean);
begin
  if TDBGridEh(Sender).STFilter.Local then begin
    DataSet.Filter :=
      GetExpressionAsFilterString(TDBGridEh(Sender),
        GetOneExpressionAsLocalFilterString, nil, False, True);
    DataSet.Filtered:=true;
    end
  else
    ApplyFilterSQLBasedDataSet(TDBGridEh(Sender), DateValueToSQLString, IsReopen, SQLPropName);
end;

initialization
  RegisterDatasetFeaturesEh(TFIBDatasetFeaturesEh, TpFIBDataSet);
end.

--------------------

Написать можно все - главное четко представлять, что ты хочешь получить в конце.

bruha

Дата 13.6.2006, 11:49 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 13
Регистрация: 11.6.2006

Репутация: нет
Всего: нет

Отлично!! Огромное спасибо, сортировка и фильтр теперь работают smile

Возникли еще вопросы по совместной работе EhLib и FIBPlus, не знаю может надо отдельную тему, но напишу сюда.

Теперь интересует работа с таблицами Мастер-Деталь, а именно:
Есть таблица ПРОБА, в ней кроме всего прочего поле КОД_ЗАКАЗЧИКА, и есть таблица ЗАКАЗЧИК с полями КОД_ЗАКАЗЧИКА и ИМЯ_ЗАКАЗЧИКА. Как мне теперь в одном гриде (DBGridEh) отобразить таблицу ПРОБА, но вместо поля КОД_ЗАКАЗЧИКА чтобы отображалось ИМЯ_ЗАКАЗЧИКА, а при изменении (MouseClick по полю) появлялся бы выпадающий список со всеми записями поля ИМЯ_ЗАКАЗЧИКА таблицы ЗАКАЗЧИК. Ну и соответственно чтобы работала сортировка и фильтр по этому полю.

Интересуют описания разных способов (или хотя бы каким пользуетесь вы), а также ссылки на статьи, доки по этой теме (чтобы работало в связке EhLib+FIBPlus). Заранее благодарен (=

Сейчас у меня в датасете ПРОБА добавлено поле ИМЯЗАКАЗЧИКА, событие OnGetText которого вызывает SQL запрос, который возвращает ИМЯ_ЗАКАЗЧИКА по КОДУ_ЗАКАЗЧИКА. Т.е. отображается в гриде то, что надо, но понятное дело не работает сортировка, фильтр и нет выпадающего списка. smile

Alex

Дата 13.6.2006, 12:03 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Экс. модератор
Сообщений: 4147
Регистрация: 25.3.2002
Где: Москва

Репутация: 17
Всего: 162

Цитата(bruha @ 13.6.2006, 12:49

)

Одна тема одни вопрос. Смотрите Lookup они едины для всех и никаких отличий в работе при связки EhLib+FIB+ нет

--------------------

Написать можно все - главное четко представлять, что ты хочешь получить в конце.

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Базы данных и репортинг \| Следующая тема »