VPF::Экспорт данных с Дельфи в Excel - Форум программистов

Asia

Дата 15.9.2006, 07:32 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 6
Регистрация: 15.9.2006

Репутация: нет
Всего: нет

Здравствуйте, уважаемые программисты Дельфи!

У меня вот такая проблема:
я создала проект в Дельфи, состоящий из табличек (Paradox созданных в Database Desktop), запроса к ним (который высвечивает по заданному конкретному полю необходимые данные с этой таблички), данные запроса отображаются на отдельной форме, но затем результаты запроса надо отобразить в виде отчета, чтобы можно было их распечатать, я умею подсоединять результаты данного запроса к QuickReport, но преподаватель требует, чтобы их (результаты запроса с формы)можно было отобразить (экспортировать) в Microsoft Excel, с чем я ни разу не сталкивалась.

Навыки в Дельфи у меня на уровне начинающего программиста - могу установить необходимые компоненты, прописать в них код.

Не могли бы вы более подробно проинструктировть как можно экспортировать результаты запроса с Дельфи в Microsoft Excel.

Могу выслать свой проект и форму отчета в Microsoft Excel.

Заранее благодарна.
Жду ваших ответов (е-мэйл: [email protected]).

Fedia

Дата 15.9.2006, 08:15 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 465
Регистрация: 2.8.2006
Где: первым встречаю р ассвет

Репутация: 3
Всего: 13

Asia, а статья отсюда не помогла ? Я наверное не точно выразился. Для создания отчетов в Excel очень хорошо подойдет использование компонента TExcelApplication или OLE (Excel.Application). Например:

Код


var
   Excel: variant;
//.....................  
   Excel:=CreateOleObject('Excel.Application');
   Excel.visible:=false;
   Excel.DisplayAlerts:=false;
   Excel.WorkBooks.Add();
   Excel.Workbooks[1].WorkSheets[1].Cells.Item[1, 1]:='test';
   try
     Excel.Workbooks.item[1].SaveAs(OutFile);
   finally
     Excel.Quit;
     Excel:=null;
   end;

Посмотри все же статью.

--------------------

Накануне решающей битвы
Я иду, и надеждою зыбкой
Озаряется эта дорога,
Я мечтаю увидеть улыбку
На лице победившего Бога…

Vas

Дата 15.9.2006, 12:00 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 830
Регистрация: 29.6.2005
Где: Stavropol region

Репутация: 23
Всего: 28

Может подойдет

Код


Procedure TForm1.Button2Click(Sender: TObject);
var
    ExcelApp, Workbook, Range, Cell1, Cell2, ArrayData  : Variant;
    BeginCol, BeginRow, i, j : integer;
    RowCount, ColCount : integer;
Begin
   Screen.Cursor:=crHourGlass;
   // Координаты левого верхнего угла области, в которую будем выводить данные
   BeginCol:=1;
   BeginRow:=2;
   // Размеры выводимого массива данных
   RowCount:=Query1.RecordCount+2;
   ColCount:=Query1.Fields.Count;
   // Создание Excel
   ExcelApp:=CreateOleObject('Excel.Application');
   // Отключаем реакцию Excel на события, чтобы ускорить вывод информации
   ExcelApp.Application.EnableEvents := false;
   //  Создаем Книгу (Workbook)
   //  Если заполняем шаблон, то Workbook := ExcelApp.WorkBooks.Add('C:\MyTemplate.xls');
   Workbook := ExcelApp.WorkBooks.Add;
   // Создаем Вариантный Массив, который заполним выходными данными
   ArrayData := VarArrayCreate([1, RowCount, 1, ColCount], varVariant);
   // Заполняем массив
   for j:=0 to ColCount-1 do
       ArrayData[1,J+1]:=DBGrid1.Columns[j].Title.Caption;
   i:=2;
   Query1.DisableControls;
   Query1.First;
   while not Query1.Eof do
   begin
      for J:=0 to ColCount-1 do
           ArrayData[I,J+1]:=Query1.Fields[j].Value;
      Query1.Next;
      i:=i+1;
      ProgressBar1.Position:=ProgressBar1.Position+ProgressBar1.Step;
   end;
   ArrayData[RowCount,1]:='Всего записей: '+IntToStr(Query1.RecordCount);
   Query1.First;
   Query1.EnableControls;
   // Левая верхняя ячейка области, в которую будем выводить данные
   Cell1:=WorkBook.WorkSheets[1].Cells[BeginRow, BeginCol];
   // Правая нижняя ячейка области, в которую будем выводить данные
   Cell2:=WorkBook.WorkSheets[1].Cells[BeginRow+RowCount-1,BeginCol+ColCount-1];
   // Область, в которую будем выводить данные
   Range := WorkBook.WorkSheets[1].Range[Cell1, Cell2];
   // А вот и сам вывод данных
   // Намного быстрее поячеечного присвоения
   Range.Value := ArrayData;
   // Делаем Excel видимым
   ExcelApp.Visible := true;
   ExcelApp:=Unassigned;
   Screen.Cursor:=crDefault;
End;

А вообще в интернете много про экспорт в эксель написано

--------------------

И опыт, сын ошибок трудных, И гений, парадоксов друг, И случай, бог изобретатель. ... (А.С. Пушкин)

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Базы данных и репортинг \| Следующая тема »