VPF::Отправка e-mail при помощи VBS - Форум программистов

mihanik

Дата 11.12.2009, 20:26 (ссылка)

(нет голосов)

Загрузка ...

-=Белый Медведь=-

Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 61
Всего: 109

Написал функцию отправки e-mail при помощи VBS.
Может, пригодиться кому...

Код



'********************************************************************
'*
'*  Функция   : SendEMail
'*  Описание  : Функция отправляет письмо по указанному адресу
'*  Вход      : 
'*            strFrom - e-mail отправителя
'*            strLogin - логин на smtp-сервер
'*            strPass - пароль на smtp-сервер
'*            SMTPServer - smtp-сервер
'*            strTo - e-mail адресата
'*            strTextbody - текст письма
'*  Выход     : 0 - ошибок при отправке не произошло
'*                номер ошибки + расшифровка при ошибке отправки
'*
'********************************************************************

Function SendEMail ( byval strFrom, byval strLogin, byval strPass, byval SMTPServer, byval strTo, byval strTextbody)

intSMTPPort = 25        '    Порт SMTP Сервера
bSMTPUseSSL = False        '    При соединении с SMTP через SSL, необходимо изменить значение на True
intUseAuth = 1            '    Если SMTP-аутентификация не требуется, можно установить значение 0. Для NTLM аутентификации - значение  2

On Error Resume Next

    Err.Clear

    Set objEmail = CreateObject("CDO.Message")
    
        objEmail.From = strFrom
        objEmail.To = strTo
        objEmail.Subject = "Robot's report."
         
        objEmail.Configuration.Fields.Item _
            ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
        objEmail.Configuration.Fields.Item _
            ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = SMTPServer
        objEmail.Configuration.Fields.Item _
            ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = intUseAuth
        objEMail.Configuration.Fields.Item _
            ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = bSMTPUseSSL
        objEmail.Configuration.Fields.Item _
            ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = intSMTPPort
        objEmail.Configuration.Fields.Item _
            ("http://schemas.microsoft.com/cdo/configuration/sendusername") = strLogin
        objEmail.Configuration.Fields.Item _ 
            ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = strPass
        
        objEmail.Textbody = strTextbody
        objEmail.Configuration.Fields.Update
        objEmail.Send
    
    Set objEmail = Nothing
    
    If Err.Number Then
        SendEMail = Err.Number & " - " & Err.Description
    Else 
        SendEMail = 0
    End If
    
    On Error Goto 0

End Function

Пример использования

Код


SendEMail ("[email protected]", "user", "Password", "smtp.server.ru", "[email protected]", "Ля-ля-ля!!!")

Это сообщение отредактировал(а) mihanik - 11.12.2009, 20:30

--------------------

Программистами не рождаются, - это родовая травма...

localhost

Дата 13.12.2009, 13:41 (ссылка)

(нет голосов)

Загрузка ...

Хирург-длятехкт

Профиль
Группа: Участник
Сообщений: 712
Регистрация: 8.11.2005
Где: Н.Новгород

Репутация: 37
Всего: 43

Так а чо отдельным топиком, а в прилепленой теме сюда ссылка? smile

--------------------

ВСЕ Нижегородцы! Отмечаемся здесь!!!
Jabber ID: [email protected]

user posted image

1 Пользователей читают эту тему (1 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| MS Windows \| Следующая тема »