Форум программистов [Powered by Invision Power Board]

Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате

Форум программистов > XML, XSL > Как найти все узлы между двумя узлами с помощью XS

Автор: Hinikato 20.5.2011, 00:00

Здравствуйте!

Прошу помощи в решении следующей задачи: у меня есть XML документ, упрощенно для лучшего понимания задачи такой:

Код


<?xml version="1.0" encoding="utf-8"?>
<pricelist>
  <category>Категория 1</category>
  <vendor>Производитель 1.1.</vendor>
  <product>Продукт 1.1.1</product>
  <product>Продукт 1.1.2</product>
  <product>Продукт 1.1.3</product>
  <category>Категория 2</category>
  <product>Продукт 2.1</product>
  <vendor>Производитель 2.1</vendor>
  <product>Продукт 2.1.1</product>
  <product>Продукт 2.1.2</product>
</pricelist>

Нужно его преобразовать в древовидный вид, а именно такой:

Код


<?xml version="1.0" encoding="utf-8"?>
<pricelist>
  <category name="Категория 1">
    <vendor name="Производитель 1.1.">
      <product>Продукт 1.1.1</product>
      <product>Продукт 1.1.2</product>
      <product>Продукт 1.1.3</product>
    </vendor>
  </category>
  <category name="Категория 2">
    <vendor name="Unknown">
      <product>Продукт 2.x</product>
    </vendor>
    <vendor name="Производитель 2.1">
      <product>Продукт 2.1.1</product>
      <product>Продукт 2.1.2</product>
    </vendor>
  </category>
</pricelist>

Некоторые пояснения:
- продукты для которых не указан производитель попадают в специальный производитель с именем Unknown, такой Unknown производитель может быть только один в каждой категории.
- цифры у продуктов и производителей я добавил только для примера.
- вообще в прайсе все имена категорий уникальны.
- имена продуктов и производителей уникальны в пределах категории, но могут повторяться в пределах прайса.

Я только начал изучать XLST, написал пока такой .xsl файл (могут быть ошибки, т.к. я его переделал для этого упрощенного примера:

Код


<?xml version='1.0' encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>

    <xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="table">
      <pricelist>
      <xsl:apply-templates select="//category"/>
      </pricelist>
    </xsl:template>

    <xsl:template match="category">
      <xsl:variable name="category_name">
        <xsl:value-of select="child::text()"/>
      </xsl:variable>
      <category name="{$category_name}">
        <xsl:variable name="next_category"
                     select="(self::node()/following-sibling::category)[1]" />
        <xsl:variable name="current_category" select="self::node()"/>
<!--
Тут непонятно что писать...

Я нашел фрагмент со следующей страницы: http://www.biglist.com/lists/xsl-list/archives/200201/msg00659.html
 <xsl:copy-of select="following-sibling::*
                        [generate-id(following-sibling::comma[1]) =
                         generate-id($next-comma)]" />
Но как его использовать здесь непонятно...
-->  

      </category>
    </xsl:template>
</xsl:stylesheet>

Пояснения и вопрос еще я добавил в комментариях XML.

Прошу помощи именно по XML части. Как можно получить на выходе документ в нужном виде из исходного?

Автор: diadiavova 20.5.2011, 13:15

Честно говоря не знаю, как это будет работать на реальном примере, а не на упрощенном(надо проверять), но так вроде работает. Думаю, в случае чего, разберешься в логике и подправишь.

Код


<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" />

  <xsl:template match="/">
    <pricelist>
      <xsl:apply-templates select="//category"/>
    </pricelist>
  </xsl:template>

    <xsl:template match="//category">
        <category name="{.}">
      <xsl:variable name="curcat" select="."/>
      <xsl:variable name="nodes" 
                    select="
                        following-sibling::product[preceding-sibling::*
                            [(name() = 'vendor') or (name() = 'category')][1] = $curcat]"/>
            <xsl:if test="$nodes">
                <vendor name="Unknown">
                    <xsl:for-each select="$nodes">
                        <xsl:copy-of select="."/>
                    </xsl:for-each>
                </vendor>
            </xsl:if>
      <xsl:for-each select="following-sibling::vendor[preceding-sibling::category[1] = $curcat]">
        <xsl:variable name="curven" select="."/>
        <vendor name="{$curven}">
          <xsl:for-each select="following-sibling::product[(preceding-sibling::vendor[1] = $curven) and 
                                    (preceding-sibling::category[1] = $curcat)]">
            <xsl:copy-of select="."/>
          </xsl:for-each>
        </vendor>
      </xsl:for-each>
        </category>
    </xsl:template>
</xsl:stylesheet>

Автор: Hinikato 25.5.2011, 19:34

diadiavova, спасибо тебе огромное за помощь. Так получилось, что к моменту как ты написал это сообщение мне уже помогли решить задачу

НО, твое решение, я думаю пригодится очень многим, да может быть и мне в будущем, спасибо за помощь!

Добавлено через 40 секунд
Вопрос решен.