Форум программистов [Powered by Invision Power Board]

Код
#!/usr/bin/perl -w
use 5.010; use strict; use warnings;
use Socket;
die "Usage: perl -w get.pl http://hostname/file target\n" unless 2 == @ARGV;
my ($host, $file) = shift =~ m'http://([^/]++)(/.*)' or die;
socket my $S, AF_INET, SOCK_STREAM, getprotobyname 'tcp' or die $!;
connect $S, sockaddr_in 80, scalar gethostbyname $host or die $!;
$S = select $S; $| = 1; $S = select $S; $| = 1;
binmode $S or die $!;
print $S <<OK;
GET $file HTTP/1.1
Host: $host
User-Agent: Opera/9.22
Accept: */*
Connection: Keep-Alive, TE
TE: identity, chunked

OK
$_ = <$S>;
close($S), die $_ unless /200/;
my $chunked = 0; my $cl = 0;
while (<$S>) {
    tr/\r//d; chomp; last unless length;
    given ($_) {
        when (/^Transfer-Encoding:\s*(\w+)/i) { $chunked = 1 if $1 =~ /chunked/ }
        when (/^Content-Length:\s*(\d+)/i) { $cl = $1 }
    }
}
my $r = "";
if ($chunked) {
    my $sz = <$S>;
    $sz =~ tr/\r//d; chomp $sz; $sz =~ s/;.*//;
    while (hex $sz) {
        read $S, my($cr), hex $sz;
        $r .= $cr;
        scalar <$S>;
        $sz = <$S>;
        $sz =~ tr/\r//d; chomp $sz; $sz =~ s/;.*//;
    }
    scalar <$S>;
} else { read $S, $r, $cl }
close $S;
my @months = ('января', 'февраля', 'марта', 'апреля', 'мая', 'июня', 'июля', 'августа', 'сентября', 'октября', 'ноября', 'декабря');
$r =~ s|(\d+)([./])(\d+)\2(\d+)|$3 >= 1 && $3 <= 12 ? $1.' '.$months[$3 - 1].' '.(2 == length $4 ? '19' : '').$4.' года' : $1.$2.$3.$2.$4|ge;
open my $F, '>', shift or die $!;
binmode $F;
print $F $r;
close $F;