Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате
Форум программистов > Центр помощи > [Pascal]Двумерный массив


Автор: Alen4ik 19.5.2009, 16:03
Каждый из N посетителей кафе (N-заданное число) выбрал 3 блюда из предложенного списка, содержащего 10 наименований.
Необходимо определить кол-во посетителей, чьи вкусы полностью совпали, напечатать номера выбранных блюд.
Порядок перечисления блюд одним посетителем не важен, но каждый из них не может выбрать одно и то же блюдо несколько раз.

 Вот мои наработки, но работает не совсем так.

Помогите, пожалуйста, исправить ошибку

Код

uses crt;
var mn:array[1..100,1..100] of integer;
n,a,b,c:byte;
d,i,j,k,s,p,t:byte;
begin
clrscr;
write('n=');readln(n);
writeln('‚Vvod nabora blud:');
s:=1;
for i:=1 to n do
for j:=1 to 3 do
begin
Writeln ('Vvedite', j, ' bludo');
Readln (mn[i,j]);
end;
Write ('Ravniy nabor Bludo ');
for i:=1 to 3 do
for u:=2 to n do
begin
k:=0;
for d:=1 to n do
begin
for j:=1 to 3 do
if mn[i,d]=mn[u,j] then begin k:=k+1; write (mn [i,d], ' ');
if k=3 then s:=s+1;
end;
end;
end;
write('zakazali ', s, ' chelovek');
readln;
end.

Автор: likehood 21.5.2009, 09:06
Идея здесь простая: сначала сортируем список блюд в каждом заказе, чтобы их было проще сравнивать, затем сравниваем последовательно заказы 1-2, 1-3, 1-4,..., 2-3, 2-4,... и т. д. Число посетителей задается константой clientCount. Массив с заказами (orderTable) я сделал константным (чтобы не вводить каждый раз кучу чисел), но при желании можно вводить его вручную.

Код

program menu;
const
     clientCount = 6;

type
    TOrderTable = array[1..clientCount, 1..3] of integer;

const
     orderTable: TOrderTable =
     (
        (3, 2, 1),
        (4, 6, 5),
        (1, 3, 2),
        (6, 5, 4),
        (2, 1, 3),
        (8, 2, 3)
     );

var
   i, j: integer;

{ сортировка по возрастанию строки order таблицы tbl }
procedure SortOrder(order: integer; var tbl: TOrderTable);
var
    i, j: integer;
    temp: integer;
begin
    for i:=1 to 2 do
        for j:=2 downto i do
        begin
            if tbl[order][j] > tbl[order][j+1] then
            begin
                temp := tbl[order][j];
                tbl[order][j] := tbl[order][j+1];
                tbl[order][j+1] := temp;
            end;
        end;
end;

{ сравнение двух заказов. возвращает true если заказы совпадают, false иначе }
function CompareOrder(order1, order2: integer; var tbl: TOrderTable): boolean;
begin
    if (tbl[order1][1]=tbl[order2][1]) and
       (tbl[order1][2]=tbl[order2][2]) and
       (tbl[order1][3]=tbl[order2][3])
    then
        CompareOrder := true
    else
        CompareOrder := false;
end;


Begin
    writeln;
    for i:=1 to clientCount do
        SortOrder(i, orderTable);

    for i:=1 to clientCount-1 do
        for j:=i+1 to clientCount do
            if CompareOrder(i, j, orderTable) then
            begin
                Write('Order ', i, ' oncurs with order ', j, ' (dish list: ');
                WriteLn(orderTable[i][1], ' ', orderTable[i][2], ' ', orderTable[i][3], ')');
            end;

    readln;
End.

Powered by Invision Power Board (http://www.invisionboard.com)
© Invision Power Services (http://www.invisionpower.com)