Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате
Форум программистов > Asm для начинающих > резидентная прога, работающая с буквами


Автор: optik 13.11.2006, 23:28
Здраствуйте!
У меня есть прога "Резидентная прога, удаляющая с экрана гласные буквы"
прога состоит из 2х файлов:

Код

.186
INCLUDE IO.ASM

CODE            SEGMENT 'CODE'

                ASSUME  CS:CODE
                ORG     100h

START:          JMP     BEGIN

OLD_2Fh_OFF     DW      0
OLD_2Fh_SEG     DW      0

OLD_08h_OFF     DW      0
OLD_08h_SEG     DW      0

INT2FhHANDLER   PROC    FAR
                CMP     AX, 0FF00h
                JZ      INSTALLED
                JMP     DWORD PTR CS:OLD_2Fh_OFF
INSTALLED:      MOV     AX, 00FFh
                IRET
INT2FhHANDLER   ENDP

Check           MACRO   What
                CMP     AL, What
                JZ      SHORT Glasn
ENDM

DO_MAIN         PROC    FAR
                PUSHF
                PUSH    DS
                PUSH    ES
                PUSHA

                MOV     AX, 0B800h
                MOV     DS, AX
                MOV     ES, AX
                MOV     SI, 0
                MOV     DI, 0

                MOV     CX, 2000
Cycle:
                LODSW
                Check   "a"
                Check   "e"
                Check   "o"
                Check   "u"
                Check   "i"
                Check   "y"

                Check   "A"
                Check   "E"
                Check   "O"
                Check   "U"
                Check   "I"
                Check   "Y"

                JMP     Next
Glasn:
                MOV     AL, " "
Next:
                STOSW
                LOOP  Cycle

                POPA
                POP     ES
                POP     DS
                POPF

                RET
DO_MAIN         ENDP

INT08hHANDLER   PROC    FAR
                CLI
                CALL    DO_MAIN
                JMP     DWORD PTR CS:OLD_08h_OFF
INT08hHANDLER   ENDP

BEGIN:          CLI
                MOV     AX, 0FF00h
                INT     2Fh                     ;Проверка повторной загрузки
                CMP     AX, 00FFh
                JE      EXIT                    ; Придется выйти

                MOV     AX, 352Fh               ; Запомнить старый INT 2Fh
                INT     21h
                MOV     CS:OLD_2Fh_OFF, BX
                MOV     CS:OLD_2Fh_SEG, ES

                PUSH    CS
                POP     DS

                MOV     AX, 3508h               ; Запомнить старый INT 08h
                INT     21h
                MOV     CS:OLD_08h_OFF, BX
                MOV     CS:OLD_08h_SEG, ES

                PUSH    CS
                POP     DS

                MOV     AX, 2508h               ; Поставить новый INT 08h
                PUSH    DS
                MOV     DX, OFFSET INT08hHANDLER
                INT     21h
                POP     DS

                MOV     AX, 252Fh               ; Поставить новый INT 2Fh
                PUSH    DS
                MOV     DX, OFFSET INT2FhHANDLER
                INT     21h
                POP     DS

                STI
                MOV     AX, 3100h
                MOV     DX, 24d
                INT     21h
EXIT:
                STI
                FINISH
STOPPROG:
CODE            ENDS
                END     START


;--------------------------------------------------------------------------------.


.XLIST
EXTRN    MAXB:BYTE,BUF:BYTE,PROCREADBUF:FAR
FINISH    MACRO
    MOV    AH,4Ch
    INT    21h
    ENDM
EXTRN    PROCNL:FAR
NEWLINE    MACRO
    CALL PROCNL
    ENDM
OUTCH    MACRO    C
    PUSH    DX
    PUSH    AX
    MOV    DL,C
    MOV    AH,2
    INT    21h
    POP    AX
    POP    DX
    ENDM
OUTSTR    MACRO
    PUSH    AX
    MOV    AH,9
    INT    21h
    POP    AX
    ENDM
EXTRN    PROCOUTNUM:FAR
OUTINT    MACRO    NUM,LENG
    OUTNUM    <NUM>,<LENG>,1
    ENDM
OUTWORD    MACRO    NUM,LENG
    OUTNUM    <NUM>,<LENG>,0
    ENDM
SAME    MACRO    NAME,VARIANTS,ANS
    ANS=0
    IRP V,<VARIANTS>
        IFIDN <NAME>,<V>
            ANS=1
            EXITM
        ENDIF
    ENDM
    ENDM
OUTNUM    MACRO    NUM,LENG,SIGN
    LOCAL    REGDX?
    PUSH    AX
    PUSH    DX
    SAME    <NUM>,<dx,DX,Dx,dX>,REGDX?
    IF    REGDX?
        IFB    <LENG>
            MOV    AL,0
        ELSE
            MOV    AL,LENG
        ENDIF
        XCHG    AX,DX
    ELSE
        IFB    <LENG>
            MOV    DL,0
        ELSE
            MOV    DL,LENG
        ENDIF
        MOV    AX,NUM
    ENDIF
    MOV    DH,SIGN
    CALL    PROCOUTNUM
    POP    DX
    POP    AX
    ENDM
EXTRN    PROCFLUSH:FAR
FLUSH    MACRO
    CALL    PROCFLUSH
    ENDM
EXTRN    PROCINCH:FAR
INCH    MACRO    X
    LOCAL    REGAX?
    SAME    <X>,<ah,AH,Ah,aH>,REGAX?
    IF    REGAX?
        XCHG    AH,AL
        MOV    AL,0
        CALL    PROCINCH
        XCHG    AH,AL
    ELSE
        SAME    <X>,<al,AL,Al,aL>,REGAX?
        IF    REGAX?
            MOV    AL,0
            CALL    PROCINCH
        ELSE
            PUSH    AX
            MOV    AL,0
            CALL    PROCINCH
            MOV    X,AL
            POP    AX
        ENDIF
    ENDIF
    ENDM
EXTRN    PROCINSTR:FAR
READBUF    MACRO
    CALL    PROCREADBUF
    ENDM
.LIST


Вопрос следущий:
мне нужна чтоб вся прога была на обычном ассеблере( если не ошибаюсь то во 2м файле исп-ся элементы макроассемблера)
и мне многое там непонятно (например такие строки как:
>>  SAME    <X>,<al,AL,Al,aL>,REGAX?
>>  IFB    <LENG>
>>  OUTNUM    <NUM>,<LENG>,1

Могли бы вы помочь переписать эту прожку на "обычный" ассемблер? 
или пояснить эту прожку?
или помочь найти прожу для задания: "резидентная программа, заменяющая буквы a,b,c,d,e на знак "*"(также пойдёт и прожка:удаление гласных, согласных и др. букв, так как её я смогу переделать под свою)?

Автор: dumb 14.11.2006, 01:17
из второго файла использовался только макрос FINISH...
Код

.186
CODE            SEGMENT 'CODE'
                ASSUME  CS:CODE
                ORG     100h
START:          JMP     BEGIN
OLD_2Fh_OFF     DW      0
OLD_2Fh_SEG     DW      0
OLD_08h_OFF     DW      0
OLD_08h_SEG     DW      0
INT2FhHANDLER   PROC    FAR
                CMP     AX, 0FF00h
                JZ      INSTALLED
                JMP     DWORD PTR CS:OLD_2Fh_OFF
INSTALLED:      MOV     AX, 00FFh
                IRET
INT2FhHANDLER   ENDP
Check           MACRO   What
                CMP     AL, What
                JZ      SHORT Glasn
ENDM
DO_MAIN         PROC    FAR
                PUSHF
                PUSH    DS
                PUSH    ES
                PUSHA
                MOV     AX, 0B800h
                MOV     DS, AX
                MOV     ES, AX

                XOR     SI, SI
                MOV     DI, SI
                MOV     CX, 80*25 ;2000
Cycle:
                LODSW
                Check   "a"
                Check   "e"
                Check   "o"
                Check   "u"
                Check   "i"
                Check   "y"
                Check   "A"
                Check   "E"
                Check   "O"
                Check   "U"
                Check   "I"
                Check   "Y"
                JMP     Next
Glasn:
                MOV     AL, " "
Next:
                STOSW
                LOOP  Cycle
                POPA
                POP     ES
                POP     DS
                POPF
                RET
DO_MAIN         ENDP
INT08hHANDLER   PROC    FAR
                CLI
                CALL    DO_MAIN
                JMP     DWORD PTR CS:OLD_08h_OFF
INT08hHANDLER   ENDP
BEGIN:          CLI
                MOV     AX, 0FF00h
                INT     2Fh                     ;Проверка повторной загрузки
                CMP     AX, 00FFh
                JE      EXIT                    ; Придется выйти
                MOV     AX, 352Fh               ; Запомнить старый INT 2Fh
                INT     21h
                MOV     CS:OLD_2Fh_OFF, BX
                MOV     CS:OLD_2Fh_SEG, ES
                PUSH    CS
                POP     DS
                MOV     AX, 3508h               ; Запомнить старый INT 08h
                INT     21h
                MOV     CS:OLD_08h_OFF, BX
                MOV     CS:OLD_08h_SEG, ES
                PUSH    CS
                POP     DS
                MOV     AX, 2508h               ; Поставить новый INT 08h
                PUSH    DS
                MOV     DX, OFFSET INT08hHANDLER
                INT     21h
                POP     DS
                MOV     AX, 252Fh               ; Поставить новый INT 2Fh
                PUSH    DS
                MOV     DX, OFFSET INT2FhHANDLER
                INT     21h
                POP     DS
                STI
; освободим довольно увесистый блок окружения (environment)
                PUSH    ES
                MOV     AX, CS:[2Ch] ; получаем сегмент блока окружения из PSP
                MOV     ES, AX
                MOV     AH, 49h
                INT     21h ; освобождаем
                POP     ES

                MOV     AX, 3100h
; Получаем размер кода в байтах от метки START до STOPPROG, делим на 10h (т.к. в DX - число параграфов)
; +1, т.к. деление целочисленное и остаток отброшен, + 10h - размер PSP в параграфах.
                MOV     DX, ((STOPPROG-START) / 10h + 1) + 10h
                INT     21h
EXIT:
                STI
                MOV     AH,4Ch
                INT     21h
STOPPROG:
CODE            ENDS
                END     START

Автор: optik 19.11.2006, 11:40
dumb, респект! спасибо за помощь!
а как надо запускать эту прожку правильно?
в cmd можно? или придётся создавать загрузочную дискету и грузить комп с неё чтоб в дос попасть? (так как елси не ошибаюсь в Windows XP нет доступа к dos в явном виде..)

Автор: dumb 19.11.2006, 20:33
если в cmd.exe запустить сначала что-нибудь DOS'овское(например, Turbo Debugger[td.exe]), то заработает. ну а с дискетки в дос - там сразу все путем будет... smile

Автор: optik 19.11.2006, 23:03
оО) попробовал в досе с дискетки - сработало!) даже понравилось) тока долго это всё, пока перезагрузишь, опять виндоуз включишь...
а вот про способ с td.exe я не особо понял. Можете пояснить?

p.s. есть ли ещё способы запуска резидентных прог под windows xp?

Автор: dumb 20.11.2006, 04:14
Цитата(optik @  19.11.2006,  23:03 Найти цитируемый пост)
а вот про способ с td.exe я не особо понял. Можете пояснить?

winxp в своем dos-box'е неким образом "замораживает" таймерное прерывание(а может и еще какие-то тоже) до какого-то момента - момент этот наступает, видимо, при вызове какой-то функции dos'а или bios'а (неохота выяснять, от чего именно это зависит).
вобщем, если запустить какое-либо приложение dos'а с интерфейсом(bc.exe/bp.exe/td.exe/итд итп), то прерывания "включаются".

Автор: optik 22.11.2006, 23:57
dumb, спасибо разобрался)

p.s. а ещё по ходу вопрос возник.. есть строчка установки счётчика для цикла loop
Код

MOV     CX, 80*25 ; 2000символов

т.е. мы обрабатываем 2000 символов (хотя на самом деле помоему получается гораздо меньше)
а можно сделать неограниченное кол-во символов для обработки? или предел должен быть?
т.е. чтоб после введёных "2000 символов" обработка не заканчивалась...

Powered by Invision Power Board (http://www.invisionboard.com)
© Invision Power Services (http://www.invisionpower.com)