Форум программистов [Powered by Invision Power Board]

Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате

Форум программистов > Delphi: Для новичков > Зачем нужен virtual – override

Автор: Rohoss 5.7.2008, 10:18

Код


  TMyClassA=class
  procedure Test; virtual;
  end;

  TMyClassB=class(TMyClassA)
  procedure Test; override;
  end;

procedure TMyClassA.Test;
begin
  ShowMessage('A');
end;

procedure TMyClassB.Test;
begin
  ShowMessage('B');
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  TMyClassB.Create.Test;
end;

Видим «В», также как и тут

Код


  TMyClassA=class
  procedure Test; 
  end;

  TMyClassB=class(TMyClassA)
  procedure Test; 
  end;

procedure TMyClassA.Test;
begin
  ShowMessage('A');
end;

procedure TMyClassB.Test;
begin
  ShowMessage('B');
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  TMyClassB.Create.Test;
end;

Автор: kemiisto 5.7.2008, 11:05

Виртуальные методы представляют интерес с такой позиции: что произойдет, если виртуальный метод будет вызван посредством ссылки на базовый класс? Какую именно версию метода нужно вызвать, Delphi определяет по типу объекта, на который указывает эта ссылка, причем решение принимается динамически, во время выполнения программы. Следовательно, если имеются ссылки на различные объекты, будут выполняться различные версии виртуального метода. Другими словами, именно тип объекта, на который указывает ссылка (а не тип ссылки) определяет, какая версия виртуального метода будет выполнена. Таким образом, если базовый класс содержит виртуальный метод и из этого класса выведены производные классы, то при наличии ссылки на различные типы объектов (посредством ссылки на базовый класс) будут выполняться различные версии этого виртуального метода.

На твоём примере. Давай немного подправим твою последнюю процедурку:

Код


procedure TForm1.Button1Click(Sender: TObject);

procedure DoTest(Obj: TMyClassA);
begin
  Obj.Test;
end;

var
  A: TMyClassA;
  B: TMyClassB;
begin
  A := TMyClassA.Create;
  B := TMyClassB.Create;
  DoTest(A);
  DoTest(B);
end;

Теперь попробуй и почуствую разницу! В первом случае, происходит переопределение (overrriding), а во втором сокрытие метода базового класса. Результаты будут различны.

Автор: Alexeis 5.7.2008, 11:15

kemiisto, гм.. виртуальные функции всегда должны перекрываться в наследниках, например директива override в C++ вообще отсутствует, вместе с механизмом введения новой виртуальной функции с тем же именем. В Delphi такой механизм есть, потому для него делема, чего применить по умолчанию директиву override или reintroduce, из-за этого он требует явного указания директивы. Я бы не сказал, что это сильно удобно, reintroduce используется в сотни раз реже, потому было бы лучше если бы компилятор по умолчанию использовал override smile

Автор: Beltar 7.7.2008, 07:31

Я из-за этого override, точнее его отсутствия попадал на утечку памяти и AV, мой деструктор в др. случае обработчик оповещений просто не включались. :( Сейчас бы я с такой ерундой быстро разобрался, тем более, что включенный код в редакторе помечается, но тогда мне потребовалось время.

Автор: Snowy 7.7.2008, 17:17

Beltar, а ты читай варнинги компилятора - не будет таких проблем.
Они для того и сделаны, чтобы их читали, а не игнорировали.

Автор: PsiMagistr 31.12.2009, 11:04

Ребята, у меня такой вопрос, связанный с override.

В общем целом. Объявляем класс cl1 и дочерний от него класс cl2. В классе cl1 Virtual-им какой нить метод, в классе cl2 перекрываем его директивой override. Если мы объявим теперь две переменные

var a1 : cl1; и var a2: cl2;

А потом вызовем конструкторы

a1:=cl1.Create;
a2:= cl2.Create;

Вызванные потом методы будут и без овверрайда пахать. А вот если обе переменные

var a1:cl1; a2:cl1;

А потом вызовем конструкторы

a1:=cl1.Create;
a2:= cl2.Create;

то сработает override.

Т.е. обе переменные принадлежат к одному родительскому классу (только конструкторы разнятся )...
Отсюда вопрос. Зачем этот override, если обе переменные можно разными типами объявить?))))

Автор: Alexeis 31.12.2009, 11:15

Цитата(PsiMagistr @ 31.12.2009, 10:04

)

Отсюда вопрос. Зачем этот override, если обе переменные можно разными типами объявить?))))

Думаю, что вы просто не умеете применять полиморфизм. Приведение наследников к предком позволяет производить групповые операции над объектами разных классов имеющих общего предка.
Кроме того директива virtual без override создает новый виртуальный метод с таким же именем, т.е. фактически при вызове такого метода (из предка) будет вызван метод предка, а не наследника. Такие "финты ушами" имеют смысл, только при длинной цепочке наследования.

Автор: PsiMagistr 31.12.2009, 11:33

Alexeis , спасибо большое. Но дело тут в том, что если обе переменные объявлены,

одна от класса предка другая от класса потомка:

var

a1:cl1; // от предка
a2: cl2; // от потомка.

то директивы Virtual-Override становятся как будто не нужны . Все "как будто " работает и так.

Еще раз простите меня, только вчера коснулся концепции ООП. Может посоветуйте какие нибудь книги специально по этой теме.

С Наступающим Вас!

Автор: CodeMonkey 31.12.2009, 12:58

Цитата(PsiMagistr @ 31.12.2009, 11:33

)

директивы Virtual-Override становятся как будто не нужны

Да.

Но вам об этом и говорят: речь идёт о ситуациях, когда у вас нет переменной конкретного класса, а только более общего. На практике это встречается намного чаще, чем вам сейчас кажется.

Автор: PsiMagistr 31.12.2009, 14:12

Правильно ли я понял, что:

Существует возможность объявлять переменные род. класса, конструируя на их основе объекты всех дочерних классов?

Автор: bems 31.12.2009, 15:07

да.

Добавлено через 5 минут и 46 секунд

Цитата(PsiMagistr @ 31.12.2009, 11:33

)

директивы Virtual-Override становятся как будто не нужны . Все "как будто " работает и так.

Ну это оч. простой случай, тут можно и без виртуальных методов обойтись (никто же не принуждает силой тебя использовать их). Но посмотри на чуит более сложный пример

Код


TMyClassA=class
  procedure Test; virtual;
  procedure DoTest;
  end;

TMyClassB=class(TMyClassA)
  procedure Test; override;
  end;

procedure TMyClassA.Test;
begin
  ShowMessage('A');
end;

procedure TMyClassA.DoTest;
begin
  ShowMessage('TMyClassA.DoTest');  
  Test
end;

procedure TMyClassB.Test;
begin
  ShowMessage('B');
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  TMyClassB.Create.DoTest;
end;

Тут мы вызываем метод, который в TMyClassB вообще не объявлен (он унаследован), но видим черты поведения от обоих классов (первое сообщение от А, второе от В)

Автор: Alexeis 31.12.2009, 15:17

Цитата(PsiMagistr @ 31.12.2009, 13:12

)

Существует возможность объявлять переменные род. класса, конструируя на их основе объекты всех дочерних классов?

Например форма создает компоненты из ресурсов, при этом все объекты помещает в массив Components типа TComponent, кроме того те из них, которые имеют визуальное представление помещает в массив Controls типа TControls. Реальные классы ее не интересуют. Важно, что они как минимум компоненты, тогда у них есть все свойства и методы компонентов, а если они контролы, то их нужно оповещать о необходимости перерисовки и т.д.

Автор: PsiMagistr 31.12.2009, 15:41

Уважаемый bems, большое спасибо! По моему уже что то проясняется. Единственное, что немного непонятно как получается вызов метода без создания переменной-указателя, через некую 3х ступенчатую конструкцию:

ИмяКласса.Конструктор.Метод.

"TMyClassB.Create.DoTest;"

Ваш код вплоне рабочий (проверенно) это просто вопрос от новенького. Я никогда не думал что можно и так вызывать.

Автор: bems 31.12.2009, 16:22

Ну конструктор возвращает объект (как функция). Этот объект можно куда-то присвоить, а можно сразу вызвать его метода, как в примере. Но дело в том что созданные объекты нужно уничтожить, а такой "трехступенчатый" вызов не даёт возможности это сделать, поэтому годится толкьо в качестве примера. Нужно делать так

Код


a := TMyClassA.Create;
try
  a.DoTest
finally
  a.Free
end

или так

Код


with TMyClassA.Create do
  try
    DoTest
  finally
    Free
  end;

Автор: PsiMagistr 31.12.2009, 17:15

Мне интересно, что как бы мы не объявляли эту переменную от предка:

Код


var a:MyClassA;

//или от потомка:

Код


var a:MyClassB;

Без дирректив virtual-override будет вызываться только родительская реализация метода.

А в приведенном мной простом примере (см. выше. самое начало) объявление указателя-переменной от потомка почему то позволяло пользоваться реализацией потомка без директив...

Автор: bems 31.12.2009, 17:21

ну у потомка же нет собственного метода DoTest, поэтому в любом случае вызывается унаследованный от предка. А внутри него вызов Test (если убрать виртуальность) означает вызов из того же класса - остальные там просто не видны.

Автор: PsiMagistr 31.12.2009, 18:34

Таким образом на основании двух примеров формируем след вопрос:

Пример первый. Описание классов от bems

Код



//Родительский

 type TMyClassA=class
  procedure Test; virtual;
  procedure DoTest;
  end;

//Дочерний

type TMyClassB=class(TMyClassA)
  procedure Test; override;
  end;



//Реализация методов


procedure TMyClassA.Test;
begin
  ShowMessage('Вызов родительского метода');
end;

procedure TMyClassA.DoTest;
begin
  ShowMessage('TMyClassA.DoTest');
  Test
end;

procedure TMyClassB.Test;
begin
  ShowMessage('Вызов дочернего метода');
end;



//Обработчик на кнопке

procedure TForm1.Button1Click(Sender: TObject);

var a:TMyClassB; // Обратите внимание как бы мы не объявляли переменную-указатель от предка или от потомка, для замещения родительского метода дочерним требуются директивы virtual-override  


begin
a:=TMyClassB.Create;
a.DoTest;
a.Free;
end;

Пример второй

Код



//Родитель

type TMyClassA=class
  procedure DoTest; Virtual; 
  end;

//Наследник

type TMyClassB=class(TMyClassA)
procedure DoTest; override;
 end;


Реализация


procedure TMyClassA.DoTest;
begin
  ShowMessage(' Работает родительский метод'); 
  end;


procedure TMyClassB.DoTest;
begin
  ShowMessage('Работает дочерний метод');
end;

// Обработчик кнопки

procedure TForm1.Button1Click(Sender: TObject);

var a:TMyClassB; //Если переменная-указатель объявлена от класса потомка, происходит замещение родительского метода дочерним без(!) директив. Если указатель объявлен от класса предка необходимо прописывать virtual-ovrride


begin
a:=TMyClassB.Create;
a.DoTest;
a.Free;
end;

На мой взгляд это рождает некоторую путаницу... Т.е. я полагал, что без этих директив, род. методы не должны перекрываться по любому.

bems, Alexsis спасибо большое за примеры. Bems, Насчет вызова родительского метода у дочернего класса я понял, собственный у него отсутствует, он пользуется тем что есть (унаследованным).

Автор: bems 31.12.2009, 20:29

Цитата(PsiMagistr @ 31.12.2009, 18:34

)

Т.е. я полагал, что без этих директив, род. методы не должны перекрываться по любому

Они и не перекрываются. Но когда ты объявляешь у дочернего класса метод, который уже есть у родителя, то дочерний скрывает родительский. И компилятор честно об этом предупреждает ворнингом. Когда ты видишь этот ворнинг, ты должен подумать что же ты хотел на самом деле. Если забыл указать override, то укажи. Если действительно хочешь скрыть старый метод, то укажи reintroduce

Автор: PsiMagistr 1.1.2010, 11:42

Bems, большое спасибо, вы мне просто глаза открыли, честное слово. smile

Таким образом:

Существует родительский класс "А" и класс-наследник "В"

В классе "А" прописан некоторый метод C-metod, вызывающий в процессе выполнения дополнительно метод D-metod того же класса.

Класс наследник В обладает собственным D-metodom, отличным по исполнению от родительского. Но собственным методом С-metod, класс В не обладает. Этот метод переходит к нему по правам наследования.

Если объекту класса B необходимо исполнить унаследованный С-metod, метод D-metod, вызываемый внутри такого С-metod  необходимо сделать виртуальным (Virtual) в объявлении класса родителя, а затем переопределить (override), в объявлении  потомка, иначе будет выполнен D-metod класса А.

Т.е. пара virtual-override используется, когда когда наследуемому  методу необходимо выполнить чужеродные ему по изначальной природе элементы (методы дочерних классов).

Будь у класса B собственный метод С-metod, он бы просто сокрыл родительский (пропиши rentroduce), чтобы компилятор не ругался.

Автор: bems 1.1.2010, 18:38

Ничего не понял smile

Добавлено через 38 секунд
Не ты. Я ничего не понял в твоём посте

Автор: PsiMagistr 1.1.2010, 18:55

Попробую объяснить на примере твоего же кода, боюсь выйдет некоторый флуд, но я удалю потом:

Существует родительский класс TMyClassA и класс-наследник TMyClassB.

В классе  TMyClassA   прописан некоторый метод DoTest, вызывающий в процессе выполнения, кроме всего прочего свой метод Test.

Класс наследник TMyClassB обладает собственным методом Test отличным по исполнению от родительского Test. Но собственным методом DoTest класс TMyClassB не обладает. Этот метод переходит к нему по правам наследования.

Если объекту класса TMyClassB необходимо исполнить унаследованный  DoTest , метод Test, вызываемый внутри такого DoTest необходимо сделать виртуальным (Virtual) в объявлении класса родителя, а затем переопределить (override), в объявлении  потомка, иначе будет выполнен Test TMyClass.Test, вместо TMyClassB.Test .

Т.е. пара virtual-override используется, когда когда наследуемому методу необходимо выполнить чужеродные ему по изначальной природе элементы (методы дочерних классов).

Будь у класса  TMyClassB  собственный метод DoTest, он бы просто сокрыл родительский (пропиши rentroduce), чтобы компилятор не ругался.

Автор: PsiMagistr 3.1.2010, 13:24

Продолжаю изучать теорию ООП. Изваял микропрограмму, использующую классы и Virtual-override директивы.

Программа направлена на вычисление объема геометрических фигур: призмы с квадратным основанием и призмы с круглым основанием (цилиндр). Согласно математике объем данных фигур можно получить по общей формуле: Объем:= ПлощадьФигуры*ВысотуФигуры. Поэтому метод GetVolume (Получение объема) является общим для всех классов. Однако этот общий метод использует метод GetArea (ПолучениеПлощади), реализация которого является различной для дочерних классов "Круг" (TDisk) и "Квадрат" (TSqr), поэтому метод GetArea объявлен виртуальным.

Переходим в раздел глобальных переменных и опишем класс родоначальник:

Код



 type Figura = class

// Поля

  fName:String; // Поле, отражающее название фигуры.
  fHeigt:Real; //  Поле, отражающее высоту фигуры.
  fRadiusOrSize:real; // Поле, отражающее радиус круга или сторону квадрата.

//Методы

Constructor Create (fn:String; fh:Real; fr:Real); //Трехпараметральный Конструктор. Используется при инициализации полей.
 
  Function GetArea : Real; Virtual;  // Метод получения площади фигуры, разнится для всех классов, однако используется в общем методе GetVolume и поэтому перекрываемый.

 Function GetVolume:Real; // Метод получения объема, одинаков для всех. 

 end; //Конец описания класса

// Опишем класс наследник Квадрат.

type TSqr = class(Figura) //Наследник класса Figura. Наследует поля, конструктор и метод получения объема. 

Function GetArea:real;override; //Метод получения площади перекрывается.

end;


//И класс-наследник Круг.

 type TDisk = class(Figura)   //Наследник класса Figura. Наследует поля, конструктор и метод получения объема. 

 Function GetArea : real;override;//Метод получения площади перекрывается.


end;

//Перейдем в область реализации методов. (inplementation)

Constructor Figura.Create; //Реализация Конструктора класса Figura. Метод служит для выделения памяти и инициализации полей.

begin

fName:=fn;
fHeigt:= fh;
fRadiusOrSize:=fr;

end;


Function Figura.GetArea;  //Реализация метода GetArea класса Figura

Begin

//Обратите внимание что этот метод фактически не имеет реализации, так как является перекрываемым и никогда не будет использован в чистом виде. однако, чтоб компилятор не посылал вам варнинги, можно расскомментировать след строку:

//GetArea:=0;

// В данном случае что именно вернет функция - неважно. (тип Real) Данная реализация никогда не будет использована.

end;

Function Figura.GetVolume;  //Реализация метода GetVolume класса Figura

begin

GetVolume:= GetArea*FHeigt; //Получаем объем призмы. Обратите внимание на использование в расчете метода GetArea.

end;



Function TDisk.GetArea; //Реализация метода GetArea, класса TDisk (Круг)

begin

GetArea := 3.141592 * fRadiusOrSize*fRadiusOrSize; //Получаем площадь круга.

end;


Function TSqr.GetArea; //Реализация метода GetArea,  класса TSqr (Квадрат)

begin

GetArea:= fRadiusOrSize*fRadiusOrSize; //Получаем площадь квадрата.


end;

// Классы подготовлены к использованию. Теперь осталось это дело запустить.


// Добавьте на форму две кнопки (Button1, Button2),  два текстовых поля (Edit1, Edit2) для задания фактических параметров Высоты и РадиусаСтороны и надпись (Label1). Измените Button1.Caption на слово "Квадрат" и запишите  обработчик.


procedure TForm1.Button1Click(Sender: TObject);

var a:TSqr; // Создание переменной типа TSqr "Квадрат"

begin 

 a:= TSqr.Create('Квадрат', StrToFloatDef(Edit1.Text,0), StrToFloatDef(Edit2.Text,0)); // Создание объекта. Ключ на старт.

Label1.Caption := a.FName + ' ' + FloatToStr(a.GetVolume); //Объект в работе.

a.Free; // Прощай объект. 

// и для второй кнопки.


procedure TForm1.Button2Click(Sender: TObject);

var a: TDisk; // Создание переменной типа TDisk "Круг"

begin

a:= TDisk.Create('Круг', StrToFloatDef(Edit1.Text,0), StrToFloatDef(Edit2.Text,0)); //Создание объекта. Ключ на старт.


Label1.Caption := a.FName + ' ' + FloatToStr(a.GetVolume); // //Объект в работе. 

a.Free; // Прощай объект. 

end;

end;

Разработано и тестировано мною в среде Дельфи 6.

Попробуйте убрать Virtual-override, раскомментировать реализацию GetArea для класса Figura и посмотреть, что получится.

smile

Автор: bems 3.1.2010, 15:38

Для случаев вроде Figura.GetArea нужно использовать abstract и убрать пустую реализацию вообще

Автор: PsiMagistr 3.1.2010, 15:55

Bems, а что за команда Abstract, объясни нубику, плиз, а то я только 3 дня, как пытаюсь понять ООП.

Автор: bems 3.1.2010, 16:07

в объявлении класса Figura метод GetArea объявляешь как

Код


Function GetArea : Real; Virtual; abstract;

Его пустую реализацию удаляешь вообще. Дочерние классы не меняются

Автор: PsiMagistr 3.1.2010, 16:24

Bems, благодарю. Ты мне очень-очень сильно помогаешь.

Насколько я понимаю, главное этот абстрактный метод не вызвать где нибудь напрямую, чтоб он о свою несуществующую реализацию не споткнулся. ))).

Насколько теперь я могу понимать, если б классы TDisc и TSqr имели свою реализацию GetVolume, а не наследованную родительскую, это было б не перекрытие (override), а просто сокрытие, так?

А в чем различие между override и overload?

Автор: bems 3.1.2010, 16:34

ну вот тут же ты вызываешь

Код


GetVolume:= GetArea*FHeigt

и оно работает, до тех пор, пока вызвается на объекте дочернего класса (не важно, какого типа ссылка, главное чей конструктор вызывался)
Но да, если вызвать это на самом предке, то будет ошибка EAbstractError
И это очень хорошо smile

Потому что это в обоих случаях ошибка, но при Abstract тебе на нее покричат, а без Abstract прога просто будет работать не так как надо (потому что в лоюбом случае не научена она считать объем какой-то неконкретной абстрактной финуры)

Цитата(PsiMagistr @ 3.1.2010, 16:24

)

А в чем различие между override и overload?

А почти ничего общего. И к ООП не относится. И один топик - один вопрос.

Автор: PsiMagistr 4.1.2010, 13:55

А какова практическая разница между Virtual и Dynemic?

Автор: bems 5.1.2010, 00:02

Практической нет. Dynamic занимает меньше памяти при некоторых условиях, но работает немного медленней. Но это всё не заметно на практике. Используй dynamic там где точно знаешь что без него никак, и virtual во всех остальных случаях.
И еще: методы обработки сообщений (те что с директивой message) на самом деле динамические, хоть объявляются без dynamic

Автор: PsiMagistr 14.1.2010, 12:53

Ребята, я прошу прощения за некоторый оффтоп, столкнулся со следующей задачей:

Есть несколько картинок (класс TImage) с изображениями в них. При нажатии на какую либо картинку, внешний вид ее должен меняться, показывая, что картинка выбрана. Когда же мы нажимаем на след. картинку, выбирается она, а первая возвращается в исходное положение. Таким образом выбрать можно только одну картинку, плитки как бы переключаются между собой.

Как возможно решить данный вопрос поизящнее?

Автор: Демо 14.1.2010, 13:06

Цитата(PsiMagistr @ 14.1.2010, 12:53

)

Как возможно решить данный вопрос поизящнее?

Рамку вокруг TImage делать, положив TImage на подкладку, например.

PS.
Можно и тему отдельную создать было.

Автор: PsiMagistr 14.1.2010, 13:42

Цитата(Демо @ 14.1.2010, 13:06)

Цитата(PsiMagistr @ 14.1.2010, 12:53

)

Как возможно решить данный вопрос поизящнее?

Рамку вокруг TImage делать, положив TImage на подкладку, например.

PS.
Можно и тему отдельную создать было.

Спасибо, Демо.

Рамка рамкой, но вопроса это не решает. Главное, как заставить совершать переключения? Т.е. одна картинка "нажата" , все остальные отжаты.

Вот в чем суть.

Автор: Демо 14.1.2010, 14:19

Цитата(PsiMagistr @ 14.1.2010, 13:42

)

Рамка рамкой, но вопроса это не решает. Главное, как заставить совершать переключения? Т.е. одна картинка "нажата" , все остальные отжаты.

Это разве проблема - пробежаться по объектам, отключить выделение всех, включить тот, на который щёлкнули мышкой?

Автор: bems 14.1.2010, 14:56

Модератор: один топик - один вопрос!