Форум программистов [Powered by Invision Power Board]

Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате

Форум программистов > Delphi: Для новичков > добавление jpg изображений в ресурс

Автор: Violina 10.1.2009, 13:11

Здравствуйте, не подскажите, можно-ли как-то добавить несколько .jpg изображений в один ресурс файл?
спасибо)

Автор: Dobermann 10.1.2009, 13:31

В cmd C:\>copy /b E:\1.jpg+E:\2.jpg+E:\3.jpg E:\123.dat

Автор: Violina 10.1.2009, 13:45

Dobermann, спасибо) - буду пробовать сейчас

Автор: Borland_Delphi_6 10.1.2009, 14:10

Цитата(Dobermann @ 10.1.2009, 14:31

)

В cmd C:\>copy /b E:\1.jpg+E:\2.jpg+E:\3.jpg E:\123.dat

Навскидку совершенно непонятно, причем тут ресурс файл.

Violina, если мне не изменяет память, это делается так:
1. Создать текстовый документ, в него добавить код:

Код


RCDATA img1 filename1.jpg
RCDATA img2 filename2.jpg

2. Сохранить файл с расширением RC
3. Скомпилировать с помощью brcc32.exe из комлпекта delphi: brcc32 test.rc

На выходе получим test.res с секцией RCDATA и двумя картинками, взятыми из filename1 и filename2 соответственно.

Автор: Dobermann 10.1.2009, 14:17

Код


{Грузим ресурс} 
{$R FOO.RES} 

uses Jpeg; 

procedure LoadJPEGFromRes(TheJPEG : string; ThePicture : TPicture); 
var        
 ResHandle : THandle;        
 MemHandle : THandle;        
 MemStream : TMemoryStream;        
 ResPtr   : PByte;        
 ResSize  : Longint;        
 JPEGImage : TJPEGImage; 
begin        
 ResHandle := FindResource(hInstance, PChar(TheJPEG), 'JPEG');        
 MemHandle := LoadResource(hInstance, ResHandle);        
 ResPtr   := LockResource(MemHandle);        
 MemStream := TMemoryStream.Create;        
 JPEGImage := TJPEGImage.Create;        
 ResSize := SizeOfResource(hInstance, ResHandle);         
 MemStream.SetSize(ResSize);        
 MemStream.Write(ResPtr^, ResSize);        
 FreeResource(MemHandle);        
 MemStream.Seek(0, 0);        
 JPEGImage.LoadFromStream(MemStream);         
 ThePicture.Assign(JPEGImage);        
 JPEGImage.Free;        
 MemStream.Free; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
begin        
 LoadJPEGFromRes('MYJPEG', Image1.Picture); 
end;

Автор: THandle 10.1.2009, 14:27

Dobermann, к чему это все?

Вопрос как запихнуть в ресурс несколько картинок.

2ТС: Посмотри вот этот пост:
http://forum.vingrad.ru/index.php?showtopic=225648&view=findpost&p=1624563

Только в файле rc соответственно несколько записей... Так как сказал Borland_Delphi_6 smile

Автор: Violina 10.1.2009, 19:17

спасибо всем огромное за помощь)
Смотрите, вот что с делала - создала image.rc - написала там
RCDATA img1 01.jpg
RCDATA img2 02.jpg
RCDATA img3 03.jpg
потом все это при помощи cmd.exe превратила в image.RES smile

А вот дальше я коды не поняла немного... можно сделать как-то так, что бы эти катртинки из ресурса грузило в image1 там какой-то - сначала 01.jpg автоматом загружало, а потом при нажатии на баттон - 02.jpg грузило, еще раз нажав - 03.jpg уже и т. д. Вот такого принципа хочу добиться...
спасибо)

Автор: AntonN 10.1.2009, 21:07

Violina,

Цитата

потом все это при помощи cmd.exe превратила в image.RES

вот тут надо поподробнее - как конкретно через cmd? smile

нужно через brcc32.exe, в потом в самом проекте программы вписать {$R image.RES} и тогда ресурс будет в программе.

Автор: Violina 10.1.2009, 21:25

AntonN, да - в cmd.exe написала brcc32 C:\image.rc - ну вообщем тоже самое - просто так я умею только делать)) В программу ресурс {$R image.RES} добавила, а вот как из этого ресурса в TImage извлекать картинки толком не понимаю...

Автор: THandle 10.1.2009, 22:38

Violina, пример в аттаче.

Автор: Violina 10.1.2009, 22:58

THandle, спасибо) - это я уже качала в ссылке, что Вы давали до этого). Вот не понимаю как сделать, что бы при нажатии на один и тот же баттон меняло картинки) smile

Автор: THandle 10.1.2009, 23:08

Вот пример. Если нужны другие имена картинок/другое количество, измените константу PICTURES_COUNT на количество картинок и измените данные массива.

Код



unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Image1: TImage;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

const
  PICTURES_COUNT = 3;
  PictureNames: Array [1..PICTURES_COUNT] Of String =
    ('KARTINKO1', 'KARTINKO2', 'KARTINKO3');
var
  Form1: TForm1;
  PictureNumber: Byte = 1;

implementation

{$R *.dfm}

uses Jpeg;

procedure LoadJPEGFromRes(const AJPEGName: string; APicture: TPicture);
var
  ResourceStream: TResourceStream;
  JPEGImage: TJPEGImage;
begin
  ResourceStream := TResourceStream.Create(HInstance, AJPEGName, RT_RCDATA);
  try
    JPEGImage := TJPEGImage.Create;
    try
      JPEGImage.LoadFromStream(ResourceStream);
      APicture.Bitmap.Assign(JPEGImage);
    finally
      JPEGImage.Free;
    end;
  finally
    ResourceStream.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  LoadJPEGFromRes(PictureNames[PictureNumber], Image1.Picture);
  if PictureNumber = PICTURES_COUNT then
    PictureNumber := 1
  else
    Inc(PictureNumber);
end;

end.

Проект в аттаче.

Автор: Violina 10.1.2009, 23:55

огромнейшее спасибо всем ) здорово помогли мне!
а можно еще для batton 2 сделать, что бы он обратно менял - то есть предыдущую показывал - а batton 3 самую первую? smile

Автор: THandle 11.1.2009, 00:03

Можно.

Автор: Данкинг 11.1.2009, 00:03

Цитата(Violina @ 10.1.2009, 23:55

)

а можно еще для batton 2 сделать, что бы он обратно менял - то есть предыдущую показывал - а batton 3 самую первую?

Можно. Для этого стоит подумать над процедурками обработки кликов кнопок 2 и 3. Для 3 я придумал. smile

Код


procedure TForm1.Button3Click(Sender: TObject);
begin
  LoadJPEGFromRes(PictureNames[1], Image1.Picture);
end;

А для 2 - предоставляю возможность подумать самостоятельно! smile

Автор: Violina 11.1.2009, 00:29

THandle, большое спасибо... теперь осталось все это понять)) smile

Данкинг, я так и делала - при этом кнопка 3 живет своей жизнью - т. е. если баттон1 стоял на 2-й картинке - нажимаешь на третий - он показывает 1-ю картинку - потом нажимаешь на первый баттон - он показывает третью - нужно, что бы он обнулялся как-то при нажатии на 3-й баттон и начинал листать со второй картинки при нажатии на него, а не с той, на котором я остановилась...

Автор: Violina 11.1.2009, 14:18

Ребята, ещё раз всем вам огромное спасибо за помощь! Во всём что было непонятно - разобралась!!!!!!! smile