Форум программистов [Powered by Invision Power Board]

Код

procedure LoadHtml(wb: TWebBrowser; html: AnsiString);
{* Вставить html код в браузер *}
var ms: TMemoryStream;
begin
  wb.Navigate('about:blank');
  ms:=TMemoryStream.Create;
  ms.Write(html[1], Length(html));
  ms.Position:=0;
  try
    while wb.ReadyState < READYSTATE_INTERACTIVE do
      Application.HandleMessage;
    (wb.Document as IPersistStreamInit).Load(TStreamAdapter.Create(ms));
  finally
    ms.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject); // OnClick
begin
  LoadHtml(wb1, AnsiString(Memo1.Lines.Text));
end;

procedure TForm1.wb1BeforeNavigate2(ASender: TObject; const pDisp: IDispatch;
  var URL, Flags, TargetFrameName, PostData, Headers: OleVariant;  var Cancel: WordBool);
{* Обработка нажимаемых ссылок *} // OnBeforeNavigate2
var
  s: string;
begin
  s := string(URL);
  if (Copy(s, 1, 6) = 'about:') then s := Copy(s, 7, Length(s));
  if (s[1] = '$') then // можно придумывать свои хитрые ссылки
  begin
    ShowMessage('Вы нажали хитрую ссылку с кодом ' + copy(s, 2, Length(s)-1));
    Cancel := True;
  end;
  // Обычную http ссылку открываем в браузере по умолчанию, остальные прямо тут
  if UpperCase(copy(s,1, 7)) <> 'HTTP://' then Exit;
  ShellExecute(0, nil, PWideChar(string(URL)), nil, nil, SW_SHOWNORMAL);
  Cancel := true;
end;

Код

<body scroll="auto">
<h1>Форум программистов <a href="http://forum.vingrad.ru/">Vingrad</a>!</h1>
<quote>Пишем <i>разные</i> <u>программы</u> на <b>Delphi</b></quote>
<hr><ul>
<li><a href="$1">Хитрая ссылка №1</a></li>
<li><a href="$два">Хитрая ссылка №2</a></li>
<li><a href="$Snowy">Хитрая ссылка №3</a></li>
</ul><hr>
<a href="javascript:alert('Кому говорят не нажимай!!!')">Не нажимай сюда</a>
<hr><a href="ftp://ftp.hp.com/">файлики</a>
</body>