Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате
Форум программистов > Object Pascal: кроссплатформенные технологии > Редактирование строки - как в текстовом поле!


Автор: godsgame 20.4.2007, 14:33
Помогите пожалуйста реализовать такое:

В ф-цию передаем строковую переменную (стринг) и нужно сделать:
1) Вывод этой строки на экран + редактирование
2) Т.е можно передвигать курсор по этой строке стрелками
3) Клавиши Делите и БэкСпейс удаляют символы по сторонам (ну как в обыном текстовом поле)
4) Энтер - подтверждением, т.е выход из цикла (предположительно, там должен быть цикл).
5) Эскейп - отмена всех действий.
6) Если можно отловить Хоме и Энд - то переносится курсор в начало/конец строки.
7) остальные символы считаеются за обычные символы, т.е дописываются на место курсора.

Спрашиваю, потому что не совсем умею работать с символами... вобщем шаблон примерно такой:

Код

function editString ( var str : String );
var
    strBackup : String;
    sim       :  Char;

begin

    strBackup := str;

    write ( str );

    While ( 1 ) do
    begin

        sim := readKey;

        { если ESC }
        if ( ... ) then
        begin
            str := strBackup;
            break;
        end
        { если Delete }
        else if ( ... ) then
        begin
        
        end
        { если Backspace }
        else if ( ... ) then
        begin
        
        end
        { если Home }
        else if ( ... ) then
        begin
        
        end
        { если End }
        else if ( ... ) then
        begin
        
        end
        { если Enter}
        else if ( ... ) then
        begin
            break; {???}
        end
        { drugoj simbol }
        else
        begin
            
        end;
    end;

end;


Помогите, пожалуйста... очень надо

Автор: Fighter 20.4.2007, 23:04
Попробуй такой вариант

Код

Uses crt;

const VK_ENTER = 13;
const VK_ESC   = 27;
const VK_EX_UP = 72;
const VK_EX_DOWN = 80;
const VK_EX_LEFT = 75;
const VK_EX_RIGHT = 77;
const VK_SPACE = 32;
const VK_BACKSPACE = 8;
const VK_EX_INSERT = 82;
const VK_EX_DELETE = 83;
const VK_EX_HOME = 71;
const VK_EX_END = 79;

function EditStr(str: string): string;
var
  stop: boolean;
  key, ex_key: integer;
  oldStr: string;
  x,y: integer;
  insertMode: boolean;
begin
  oldStr := str;
  clrscr;
  write(str);
  x := whereX;
  y := whereY;
  stop := false;
  insertMode := true;
  if insertMode then
  begin
    gotoxy(60, 25);
    write('Insert mode on')
  end
  else
  begin
    gotoxy(60, 25);
    write('Insert mode off')
  end;
  gotoxy(x,y);
  while not stop do
  begin
    if KeyPressed then
    begin
      x := whereX;
      y := whereY;
      key := Ord(ReadKey);
      if key = 0 then
      begin
        ex_key := ord(readkey);
        if ex_key = VK_EX_LEFT then
        begin
          if x > 1 then
            x := x - 1
        end
        else if ex_key = VK_EX_RIGHT then
        begin
          if x <= length(str) then
            x := x + 1;
        end
        else if ex_key = VK_EX_HOME then
        begin
          x := 1;
        end
        else if ex_key = VK_EX_END then
        begin
          x := length(str) + 1;
        end
        else if ex_key = VK_EX_INSERT then
        begin
          insertMode := not InsertMode;
        end
        else if ex_key = VK_EX_DELETE then
        begin
          if x <= length(str) then
            delete(str, x, 1);
        end
      end
      else
      begin
        if key = VK_ENTER then
        begin
          stop := true;
        end
        else if key = VK_ESC then
        begin
          str := oldStr;
          stop := true;
        end
        else if key = VK_BACKSPACE then
        begin
          if x > 1 then
          begin
            delete(str, x-1, 1);
            x := x - 1;
          end;
        end
        else if (key in [ord('a')..ord('z')]) or (key in [ord('A')..ord('Z')]) or
        (key in [128..159]) or (key in [ord(' ')..ord('¯')]) or
        (key in [ord('à')..ord('ï')]) or (key = 32) then
        begin
          if insertMode then
          begin
            insert(chr(key), str, x);
            x := x + 1
          end
          else
          begin
            delete(str, x, 1);
            insert(chr(key), str, x);
            x := x + 1;
          end;
        end;
      end;
      clrscr;
      if insertMode then
      begin
        gotoxy(60, 25);
        write('Insert mode on')
      end
      else
      begin
        gotoxy(60, 25);
        write('Insert mode off')
      end;
      gotoxy(1,1);
      write(str);
      gotoxy(x,y);
    end;
  end;
  EditStr := str;
end;

var
  s: string;


begin
  clrscr;
  write('Enter the string: ');
  readln(s);
  s := EditStr(s);
  writeln;
  writeln('The S = ', s);
  readkey;
end.

Автор: godsgame 21.4.2007, 18:01
Fighter, 

почти то что надо, только там была проблема, что он все стирал и начинал с 1,1... вобщем я покопался и исправил это:

Код

Uses crt;

const VK_ENTER = 13;
const VK_ESC   = 27;
const VK_EX_UP = 72;
const VK_EX_DOWN = 80;
const VK_EX_LEFT = 75;
const VK_EX_RIGHT = 77;
const VK_SPACE = 32;
const VK_BACKSPACE = 8;
const VK_EX_INSERT = 82;
const VK_EX_DELETE = 83;
const VK_EX_HOME = 71;
const VK_EX_END = 79;

function EditStr(str: string): string;
var
    stop: boolean;
    key, ex_key: integer;
    oldStr: string;
    x,y,mx: integer;
    insertMode: boolean;
    start_x : integer;

    procedure myClean ( s1 : string; s2 : string );
    var
        l1 : integer;
        l2 : integer;
        l  : integer;
        i  : integer;

    begin
        l1 := length ( s1 );
        l2 := length ( s2 );

        if ( l1 > l2 ) then
            l := l1
        else
            l := l2;

        for i := 1 to l do
            write(' ');
    end;
begin

    oldStr := str;
    write(str);
    x := whereX;
    y := whereY;
    stop := false;
    insertMode := true;

    start_x := x - length ( str );
    gotoxy(x,y);

    while not stop do
    begin
        if KeyPressed then
        begin
            x := whereX;
            y := whereY;
            key := Ord(ReadKey);

            if key = 0 then
            begin
                ex_key := ord(readkey);
                if ex_key = VK_EX_LEFT then
                begin
                    if x > 1 then
                        x := x - 1
                end
                else if ex_key = VK_EX_RIGHT then
                begin
                    if x <= length(str) then
                        x := x + 1;
                end
                else if ex_key = VK_EX_HOME then
                begin
                    x := 1;
                end
                else if ex_key = VK_EX_END then
                begin
                    x := length(str) + 1;
                end
                else if ex_key = VK_EX_INSERT then
                begin
                    insertMode := not InsertMode;
                end
                else if ex_key = VK_EX_DELETE then
                begin
                    if x <= length(str) then
                        delete(str, x, 1);
                end
            end
            else
            begin
                if key = VK_ENTER then
                begin
                    stop := true;
                end
                else if key = VK_ESC then
                begin
                    str := oldStr;
                    stop := true;
                end
                else if key = VK_BACKSPACE then
                begin
                    if x > 1 then
                    begin
                        delete(str, x-1, 1);
                        x := x - 1;
                    end;
                end
                else if (key in [ord('a')..ord('z')]) or (key in [ord('A')..ord('Z')]) or
                        (key in [128..159]) or (key in [ord(' ')..ord('?')]) or
                        (key in [ord('a')..ord('i')]) or (key = 32) then
                begin
                    if insertMode then
                    begin
                        insert(chr(key), str, x);
                        x := x + 1
                    end
                    else
                    begin
                        delete(str, x, 1);
                        insert(chr(key), str, x);
                        x := x + 1;
                    end;
                end;
            end;

            gotoxy(x,y);
            gotoxy(start_x,y);
            myClean ( str, oldStr );
            gotoxy(start_x,y);
            write(str);
            gotoxy(x,y);
        end;
    end;
    
    EditStr := str;
end;

var
  s: string;


begin
  clrscr;
  write('Enter the string: ');
  readln(s);
  s := EditStr(s);
  writeln;
  writeln('The S = ', s);
  readkey;
end.



огромное тебе спасибо, "+" с меня  smile 

Powered by Invision Power Board (http://www.invisionboard.com)
© Invision Power Services (http://www.invisionpower.com)