Форум программистов [Powered by Invision Power Board]

Код
    .686P
    .model flat,stdcall
    option casemap:none
    include windows.inc
    include user32.inc
    include kernel32.inc
    include gdi32.inc
    include comdlg32.inc
    include shell32.inc
WinMain proto :DWORD,:DWORD,:DWORD,:DWORD


RGB macro red,green,blue
    xor        eax,eax
    mov        ah,blue
    shl        eax,8
    mov        ah,green
    mov        al,red
endm
szText MACRO Name,Text:VARARG
    LOCAL    lbl
    jmp        lbl
    Name    db Text,0
    lbl:
ENDM
.const
TickerID        equ 1
.data?
hwndTicker        HWND ?
hInstance        HINSTANCE ?
CommandLine        LPSTR ?
hFont            dd ?
hBrushBk         dd ?
.data
TextTicker        db "Ticker",0
;_______________
ClassName        db "mbuilder",0
BtnClName        db "button",0
StatClName        db "static",0
EditClName        db "edit",0
LboxClName        db "listbox",0
CboxClName        db "combobox",0
ReditClName        db "richedit",0
RichEditLib        db "riched32.dll",0
FormCaption        db "Form",0
lpFontName1        db "Comic Sans MS",0
TestString        db "TATB",0


;_______________
.code
start:
    invoke    GetModuleHandle,NULL
    mov        hInstance,eax
    invoke    GetCommandLine
    mov CommandLine, eax
    invoke    WinMain,hInstance,NULL,CommandLine,SW_SHOWDEFAULT
    invoke    ExitProcess,eax
WinMain proc hInst:HINSTANCE,hPrevInst:HINSTANCE,CmdLine:LPSTR,CmdShow:DWORD
LOCAL wc    :WNDCLASSEX
LOCAL msg    :MSG
LOCAL hwnd    :HWND
    mov        wc.cbSize,SIZEOF WNDCLASSEX
    mov        wc.style,CS_BYTEALIGNCLIENT
    mov        wc.lpfnWndProc,offset WndProc
    mov        wc.cbClsExtra,NULL
    mov        wc.cbWndExtra,NULL
    push    hInst
    pop        wc.hInstance
    mov        wc.hbrBackground,COLOR_BTNFACE+1
    mov        wc.lpszClassName,OFFSET ClassName
    invoke    LoadIcon,NULL,IDI_APPLICATION
    mov        wc.hIcon,eax
    mov        wc.hIconSm,eax
    invoke    LoadCursor,NULL,IDC_ARROW
    mov        wc.hCursor,eax
    mov wc.lpszMenuName, 0
    invoke    RegisterClassEx,addr wc
invoke CreateWindowEx,0,ADDR ClassName,ADDR FormCaption,WS_SYSMENU or WS_SIZEBOX,200,200,384,291,0,0,hInst,0
    mov        hwnd,eax
    INVOKE    ShowWindow,hwnd,SW_SHOWNORMAL
    INVOKE    UpdateWindow,hwnd
    .WHILE TRUE
        invoke    GetMessage,ADDR msg,0,0,0
        .BREAK .IF (!eax)
        invoke    TranslateMessage,ADDR msg
        invoke    DispatchMessage,ADDR msg
    .ENDW
    mov    eax,msg.wParam
    ret
WinMain endp
WndProc proc hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
    LOCAL hdc:HDC
    LOCAL ps:PAINTSTRUCT

    .IF uMsg == WM_DESTROY
        invoke DeleteObject, hFont
        invoke DeleteObject, hBrushBk
        invoke    PostQuitMessage,NULL
    .ELSEIF uMsg == WM_CREATE
     invoke    CreateWindowEx,WS_EX_CLIENTEDGE,ADDR EditClName,ADDR TextTicker,WS_CHILD or ES_LEFT or ES_AUTOHSCROLL or WS_VISIBLE,48,32,121,48,hWnd,TickerID,hInstance,0
     mov        hwndTicker,eax
     invoke    CreateFontA,18,0,0,0,FW_BOLD,0,0,0, 1,64,0,2,0 + 0, offset [lpFontName1]
     mov        hFont,eax
     invoke    SendMessage, hwndTicker, WM_SETFONT, hFont, 0

     RGB 0,0,255
     invoke CreateSolidBrush, eax
     mov hBrushBk, eax

    .ELSEIF uMsg == WM_CTLCOLOREDIT
     RGB        200,200,50
     invoke    SetTextColor,wParam,eax
     RGB        0,0,255
     invoke    SetBkColor,wParam,eax

     mov eax, hBrushBk
     ret
    .ELSE
        invoke    DefWindowProc,hWnd,uMsg,wParam,lParam
        ret
    .ENDIF
    xor        eax,eax
    ret
WndProc endp
end start