Форум программистов [Powered by Invision Power Board]

Код

unit UOchko;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, jpeg, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Memo1: TMemo;
    Image1: TImage;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

var A: array[0..35] of integer; // колода
    Count: word = 0;            // число взятых карт
    Sum: word = 0;              // сумма очков

function cost(N: integer): integer; // число очков заданной карты
begin
 case N mod 9 of
  0, 1, 2, 3, 4: Result := N mod 9 + 6;
  5, 6, 7:       Result := N mod 9 - 3;
  else Result := 11;
 end;
end;



function card(N: integer): string;  // описание карты в виде строки
const face: array[0..8] of string =
                        ('Шестерка', 'Семерка', 'Восьмерка',
                         'Девятка', 'Деcятка', 'Валет',
                         'Дама', 'Король', 'Туз');
const suit: array[0..3] of string =
                        ('пик', 'треф', 'червей', 'бубен');
begin
 Result := face[N mod 9] + ' ' + suit[N div 9];
end;


procedure TForm1.Button1Click(Sender: TObject); // оператор "Тасовать"
var i, j, Tmp: word;
begin
 for i := 0 to 35 do A[i] := i;
 for i := 0 to 35 do
 begin
  j := Random(36);
  Tmp := A[i];
  A[i] := A[j];
  A[j] := Tmp;
 end;
 Count := 0;
 Sum := cost(A[0]);
 Memo1.Clear;
 Memo1.Lines.Add(card(A[0]) + '. Сумма = ' + IntToStr(Sum));
end;

procedure TForm1.Button2Click(Sender: TObject); // оператор "Еще !"
begin
 Inc(Count);
 Sum := Sum + cost(A[Count]);
 Memo1.Lines.Add(card(A[Count]) + '. Сумма = ' + IntToStr(Sum));
 if Sum > 21
  then begin
   ShowMessage('Перебор !!! Вы проиграли.');
   Button1Click(Sender);
  end;
end;


procedure TForm1.Button3Click(Sender: TObject);
var MySum: word;
begin
 Memo1.Lines.Add('Ваша сумма ' + IntToStr(Sum));
 Memo1.Lines.Add('');
 Memo1.Lines.Add('Карты компьютера:');
 MySum := 0;
 repeat
  Inc(Count);
  MySum := MySum + cost(A[Count]);
  Memo1.Lines.Add(card(A[Count]));
 until 22 - MySum < 7;
 Memo1.Lines.Add('Сумма компьютера ' + IntToStr(MySum));
 if MySum > 21
  then ShowMessage('Перебор !!! Компьютер проиграл !')
  else if MySum > Sum then ShowMessage('Компьютер выиграл.')
  else if Sum = 21 then ShowMessage('У вас ОЧКО !!! Вы выиграли.')
  else if MySum < Sum then ShowMessage(
                       'Компьютер проиграл. Поздравляю !!!')
  else ShowMessage('Ничья !!!');
  Button1click(Sender);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
 Randomize;
 Button1click(Sender);
end;

end.