Форум программистов [Powered by Invision Power Board]

Код

procedure TForm1.Button1Click(Sender: TObject);
var WorkItem, PITask: IUnknown;
    piNewTrigger, tWord: Word;
    ITTrigger: ITaskTrigger;
    TaskTrig: TTaskTRIGGER;
    uname, pass: PWideChar;
begin
tWord:=0;
if Trim(Edit3.Text)='' then begin ShowMessage('Не задано "Имя задания"'); Exit; end;
if Trim(Edit1.Text)='' then begin ShowMessage('Не задано "Запуск прораммы"'); Exit; end;
  // проверяем если задание с таким именем существует тогда удаляем
  Task := nil;
  if SchedulingAgent.Activate(StrToWide(Edit3.Text), IID_ITask, PITask) = S_OK then Task := ITask(PITask);
  if Task <> nil then SchedulingAgent.Delete(StrToWide(Edit3.Text));
  // заносим имя задания
  SchedulingAgent.NewWorkItem(StrToWide(Edit3.Text), CLSID_CTask, IID_IScheduledWorkItem, WorkItem);
  Task := ITask(WorkItem);
  ScheduledWorkItem := IScheduledWorkItem(WorkItem);
  // запуск программы
  Task.SetApplicationName(StrToWide(Edit1.Text));
  // параметры запуска программы
  Task.SetParameters(StrToWide(Edit2.Text));
  // рабочая директория
  Task.SetWorkingDirectory(StrToWide(ExtractFileDir(Edit1.Text)));
  // комментарии
  Task.SetComment(StrToWide(mComment.Text));
  // устанавливаем акаунт юзера (имя, пароль пользователя)
  GetMem(uname, 255);
  GetMem(pass, 255);
  StringToWideChar(edName.Text, uname, Length(edName.Text) + 1);
  StringToWideChar(edPass.Text, pass, Length(edPass.Text) + 1);
  Task.SetAccountInformation(uname, pass);
  FreeMem(uname);
  FreeMem(pass);
  // устанавливаем с какой даты выполнять задание
  Task.CreateTrigger(piNewTrigger, ITTrigger);
  ZeroMemory(@TaskTrig, sizeof(TASK_TRIGGER));
  TaskTrig.cbTriggerSize := sizeof(TASK_TRIGGER);
  TaskTrig.wBeginYear := YearOf(dtDate.Date);
  TaskTrig.wBeginMonth := MonthOf(dtDate.Date);
  TaskTrig.wBeginDay := DayOf(dtDate.Date);
  TaskTrig.wEndYear := 0;
  TaskTrig.wEndMonth := 0;
  TaskTrig.wEndDay := 0;
  // время запуска
  TaskTrig.wStartHour := HourOf(dtTime.Time);
  TaskTrig.wStartMinute := MinuteOf(dtTime.Time);
  // тип запуска
  case ComboBox1.ItemIndex of
    0: begin // если ежедневно
         TaskTrig.TriggerType:=TASK_TIME_TRIGGER_DAILY;
         TaskTrig.Type_.Daily.DaysInterval:=StrToInt(SpinEdit1.Text);
       end;
    1: begin // если еженедельно
         TaskTrig.TriggerType:=TASK_TIME_TRIGGER_WEEKLY;
         TaskTrig.Type_.Weekly.WeeksInterval:=StrToInt(SpinEdit2.Text);
         if chkW1.Checked then tWord:=tWord+TASK_MONDAY;
         if chkW2.Checked then tWord:=tWord+TASK_TUESDAY;
         if chkW3.Checked then tWord:=tWord+TASK_WEDNESDAY;
         if chkW4.Checked then tWord:=tWord+TASK_THURSDAY;
         if chkW5.Checked then tWord:=tWord+TASK_FRIDAY;
         if chkW6.Checked then tWord:=tWord+TASK_SATURDAY;
         if chkW7.Checked then tWord:=tWord+TASK_SUNDAY;
         TaskTrig.Type_.Weekly.rgfDaysOfTheWeek:=tWord;
       end;
    2: begin // если ежемесячно
         if chkMonth1.Checked then tWord:=tWord+TASK_JANUARY;
         if chkMonth2.Checked then tWord:=tWord+TASK_FEBRUARY;
         if chkMonth3.Checked then tWord:=tWord+TASK_MARCH;
         if chkMonth4.Checked then tWord:=tWord+TASK_APRIL;
         if chkMonth5.Checked then tWord:=tWord+TASK_MAY;
         if chkMonth6.Checked then tWord:=tWord+TASK_JUNE;
         if chkMonth7.Checked then tWord:=tWord+TASK_JULY;
         if chkMonth8.Checked then tWord:=tWord+TASK_AUGUST;
         if chkMonth9.Checked then tWord:=tWord+TASK_SEPTEMBER;
         if chkMonth10.Checked then tWord:=tWord+TASK_OCTOBER;
         if chkMonth11.Checked then tWord:=tWord+TASK_NOVEMBER;
         if chkMonth12.Checked then tWord:=tWord+TASK_DECEMBER;
         if RadioButton1.Checked then begin
           TaskTrig.TriggerType:=TASK_TIME_TRIGGER_MONTHLYDATE;
           TaskTrig.Type_.MonthlyDate.rgfDays:=humanDaysToBitField(StrToInt(SpinEdit3.Text));
           TaskTrig.Type_.MonthlyDate.rgfMonths:=tWord;
         end else begin
           TaskTrig.TriggerType:=TASK_TIME_TRIGGER_MONTHLYDOW;
           case ComboBox2.ItemIndex of
             0: TaskTrig.Type_.MonthlyDOW.wWhichWeek:=TASK_FIRST_WEEK;
             1: TaskTrig.Type_.MonthlyDOW.wWhichWeek:=TASK_SECOND_WEEK;
             2: TaskTrig.Type_.MonthlyDOW.wWhichWeek:=TASK_THIRD_WEEK;
             3: TaskTrig.Type_.MonthlyDOW.wWhichWeek:=TASK_FOURTH_WEEK;
             5: TaskTrig.Type_.MonthlyDOW.wWhichWeek:=TASK_LAST_WEEK;
           end;
           case ComboBox3.ItemIndex of
             0: TaskTrig.Type_.MonthlyDOW.rgfDaysOfTheWeek:=TASK_MONDAY;
             1: TaskTrig.Type_.MonthlyDOW.rgfDaysOfTheWeek:=TASK_TUESDAY;
             2: TaskTrig.Type_.MonthlyDOW.rgfDaysOfTheWeek:=TASK_WEDNESDAY;
             3: TaskTrig.Type_.MonthlyDOW.rgfDaysOfTheWeek:=TASK_THURSDAY;
             4: TaskTrig.Type_.MonthlyDOW.rgfDaysOfTheWeek:=TASK_FRIDAY;
             5: TaskTrig.Type_.MonthlyDOW.rgfDaysOfTheWeek:=TASK_SATURDAY;
             6: TaskTrig.Type_.MonthlyDOW.rgfDaysOfTheWeek:=TASK_SUNDAY;
           end;
           TaskTrig.Type_.MonthlyDOW.rgfMonths:=tWord;
         end;
       end;
     // иначе однократно
     else TaskTrig.TriggerType:=TASK_TIME_TRIGGER_ONCE;
  end;
  ITTrigger.SetTrigger(@TaskTrig);
  // сохраняем
  Task.QueryInterface(IID_IPersistFile, pIPersistFile);
  if pIPersistFile <> nil then pIPersistFile.Save(nil, true);
  // показываем список заданий
  Button3Click(self);
end;