Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате
Форум программистов > Delphi: Общие вопросы > Вращение линии вокруг элипса


Автор: MrDmitry 4.9.2015, 18:37
Здравствуйте помогите осуществить вращение линии вокруг элипса. 

Вот что я пытался сделать, но получается хрень какая то


Код

procedure TForm1.FormCreate(Sender: TObject);
begin
DoubleBuffered:=true;
image1.Canvas.Ellipse(50,100,50+24,100+24);
end;

procedure TForm1.Image1MouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
yes:=true;
end;

procedure TForm1.Image1MouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
if yes then
begin
Linex:=x;
liney:=y;
end;
end;

procedure TForm1.Image1MouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
yes:=false;
end;


procedure TForm1.Timer1Timer(Sender: TObject);
var
 x, y, NewX, NewY:integer;
begin
if yes then
begin
  Image1.Picture.Bitmap:=nil;
  image1.Canvas.Ellipse(50,100,50+24,100+24);

  //72 - правый граница элипса
  //50 - левый граница эллипса
  //122- нижняя граница эллипса
  //100- верхняя граница эллипса
  //61 - центральный x эллипса
  //111 - центральный y эллипса

  if linex>72 then
   x:=72;
  if lineX<72 then
   x:=Linex;
  if LineX<50 then
   x:=50;
  if lineY>122 then
   y:=122;
  if lineY<122 then
   Y:=LineY;
  if LineY<100 then
   Y:=100;

  try
   if LineY<100 then
     newy:=y-round((X-61)/2);
   if lineY>122 then
     newy:=y-round((X-61)/2);
  except
   newy:=Y;
  end;


  try
    if LineY<100 then
    newX:=x-round((Y-111)/2)
   else
    newX:=x+round((Y-111)/2);
  except
   newX:=X;
  end;


  image1.Canvas.MoveTo(newX,NewY);
  image1.Canvas.LineTo(LineX,liney);
end;


PS с тригонометрией и геометрией у меня проблемы )))

Автор: bems 5.9.2015, 02:34
опиши толково что тебе нужно какая линия, какой эллипс, что такое вращение. при чем тут мыша.

Автор: MrDmitry 5.9.2015, 15:54
Ну я скинул код и думал будет понятно что я хочу. Есть эллипс, расположенный в каких то координатах. Нужно при нажатии левой кнопки мыши и ее перемещению по канве, от границ эллипса до координат мыши рисовалась линия.

Автор: bems 5.9.2015, 21:45
как-то так?

Код

unit Unit28;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.ExtCtrls;

type
  TForm28 = class(TForm)
    img: TImage;
    procedure FormResize(Sender: TObject);
    procedure imgMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
  strict private
    const
      EllipceBounds: TRect = (Left: 100; Top: 150; Right: 400; Bottom: 600);
  public
    { Public declarations }
  end;

var
  Form28: TForm28;

implementation

uses
  Math;

{$R *.dfm}

procedure TForm28.FormResize(Sender: TObject);
begin
  img.Picture.Bitmap.SetSize(img.Width, img.Height);
  img.Canvas.Ellipse(EllipceBounds)
end;

procedure TForm28.imgMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
var
  pt: TPoint;
  Alpha: Extended;
begin
  if ssLeft in Shift
     then begin
          pt := Point(X, Y) - EllipceBounds.CenterPoint;
          pt.Y := Round(pt.Y * (EllipceBounds.Width / EllipceBounds.Height));
          Alpha := Arctan2(pt.Y, pt.X);
          pt.X := Round(Cos(Alpha) * (EllipceBounds.Width / 2));
          pt.Y := Round(Sin(Alpha) * (EllipceBounds.Height / 2));
          pt := pt + EllipceBounds.CenterPoint;
          img.Canvas.MoveTo(pt.X, pt.Y);
          img.Canvas.LineTo(X, Y);
          end;
end;

end.

Автор: MrDmitry 9.9.2015, 18:39
Цитата(bems @ 5.9.2015,  21:45)
как-то так?

Код

unit Unit28;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.ExtCtrls;

type
  TForm28 = class(TForm)
    img: TImage;
    procedure FormResize(Sender: TObject);
    procedure imgMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
  strict private
    const
      EllipceBounds: TRect = (Left: 100; Top: 150; Right: 400; Bottom: 600);
  public
    { Public declarations }
  end;

var
  Form28: TForm28;

implementation

uses
  Math;

{$R *.dfm}

procedure TForm28.FormResize(Sender: TObject);
begin
  img.Picture.Bitmap.SetSize(img.Width, img.Height);
  img.Canvas.Ellipse(EllipceBounds)
end;

procedure TForm28.imgMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
var
  pt: TPoint;
  Alpha: Extended;
begin
  if ssLeft in Shift
     then begin
          pt := Point(X, Y) - EllipceBounds.CenterPoint;
          pt.Y := Round(pt.Y * (EllipceBounds.Width / EllipceBounds.Height));
          Alpha := Arctan2(pt.Y, pt.X);
          pt.X := Round(Cos(Alpha) * (EllipceBounds.Width / 2));
          pt.Y := Round(Sin(Alpha) * (EllipceBounds.Height / 2));
          pt := pt + EllipceBounds.CenterPoint;
          img.Canvas.MoveTo(pt.X, pt.Y);
          img.Canvas.LineTo(X, Y);
          end;
end;

end.

Мне казалось что можно было все сделать попроще... Но похоже что нет. Спасибо ))

Автор: bems 10.9.2015, 17:45
можно и попроще. рисуешь сначала линию от "центра" эллипса к мыше, а потом поверх неё рисуешь закрашенный эллипс

Powered by Invision Power Board (http://www.invisionboard.com)
© Invision Power Services (http://www.invisionpower.com)