Форум программистов [Powered by Invision Power Board]

Код

procedure DrawGlassText(Canvas: TCanvas; GlowSize: Integer; var Rect: TRect;
  var Text: UnicodeString; Format: DWORD); overload;
var
  DTTOpts: TDTTOpts;
  Color: TColor;
  BMP: TBitMap;
  RectBMP: TRect;
begin
  if GetWinVersion < wvWinVista then
  begin
    DrawTextW(Canvas.Handle, PWideChar(Text), Length(Text), Rect, Format);
    Exit;
  end;
  ZeroMemory(@DTTOpts, SizeOf(DTTOpts));
  DTTOpts.dwSize := SizeOf(DTTOpts);
  DTTOpts.dwFlags := DTT_COMPOSITED or DTT_TEXTCOLOR;
  DTTOpts.iTextShadowType := TST_NONE;
  DTTOpts.iBorderSize := 0;
  DTTOpts.fApplyOverlay := True;
  if Format and DT_CALCRECT = DT_CALCRECT then
    DTTOpts.dwFlags := DTTOpts.dwFlags or DTT_CALCRECT;
  Color := ColorToRGB(Canvas.Font.Color);
  DTTOpts.crText := Color;
  if GlowSize > 0 then
  begin
    DTTOpts.dwFlags := DTTOpts.dwFlags or DTT_GLOWSIZE;
    DTTOpts.iGlowSize := GlowSize;
  end;
  BMP := TBitMap.Create;
  BMP.PixelFormat := pf32bit;
  BMP.Width := Rect.Right - Rect.Left;
  BMP.Height := Rect.Bottom - Rect.Top;
  RectBMP := Classes.Rect(0, 0, BMP.Width, BMP.Height);
  BMP.Canvas.Brush := Canvas.Brush;
  BMP.Canvas.FillRect(RectBMP);
  with ThemeServices.GetElementDetails(teEditTextNormal) do
    DrawThemeTextEx(ThemeServices.Theme[teEdit], BMP.Canvas.Handle, Part,
      State, PWideChar(Text), Length(Text), Format, @RectBMP, DTTOpts);
  RectBMP := Classes.Rect(0, BMP.Height, BMP.Width, 0);
  Canvas.CopyRect(Rect, BMP.Canvas, RectBMP);
  BMP.Free;
end;