Форум программистов [Powered by Invision Power Board]

Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате

Форум программистов > Delphi: WinAPI и системное программирование > Запустить приложние и изнать как оно завершилось??

Автор: Nicholas 5.1.2005, 08:49

Мне требуется следующее: Моя программа запускает внешний SFX-архив WinRar и ждет пока
архив распакуется, после завершения работы архива мне необходимо знать как он был завершен,
т.е. был ли он полностью распакован или в окне SFX-архива была нажата клавиша "Отмена" или
даны другие команды прерывающие его работу.

Если можно дайте рабочую процедурку.
smile

Затея возникла после того как поставил пару игр, в которых программы установки
запускает SFX-архив - ждет его завершения да еще умудряется записывать в лог все
распакованные из архива файлы!!!

Автор: Akella 5.1.2005, 10:33

задавай такие вопросы в теме "Системное программирование/WinAPI"

а тебе нужно исп. функцю типа WaitForSingleObject

Код


function ExecAndWait(const FileName, Params: ShortString; const WinState: Word): boolean; export;
var
  StartInfo: TStartupInfo;
  ProcInfo: TProcessInformation;
  CmdLine: ShortString;
begin
  { Помещаем имя файла между кавычками, с соблюдением всех пробелов в именах Win9x }
  CmdLine := '"' + Filename + '" ' + Params;
  FillChar(StartInfo, SizeOf(StartInfo), #0);
  with StartInfo do
  begin
    cb := SizeOf(StartInfo);
    dwFlags := STARTF_USESHOWWINDOW;
    wShowWindow := WinState;
  end;
  Result := CreateProcess(nil, PChar( String( CmdLine ) ), nil, nil, false,
                          CREATE_NEW_CONSOLE or NORMAL_PRIORITY_CLASS, nil,
                          PChar(ExtractFilePath(Filename)),StartInfo,ProcInfo);
  { Ожидаем завершения приложения }
  if Result then
  begin
    WaitForSingleObject(ProcInfo.hProcess, INFINITE);
    { Free the Handles }
    CloseHandle(ProcInfo.hProcess);
    CloseHandle(ProcInfo.hThread);
  end;
end;

А еще есть такие функции как
WaitForMultipleObjects
WaitForMultipleObjectsEx

Автор: Snowy 5.1.2005, 10:34

В инете и факах куча примеров на тему "Запуск программы и ожидание ее завершения". Поиск тебе в руки. Вопрос настолько затасканный, что повторяться не имеет смысла.

Автор: Alex 5.1.2005, 10:52

http://vingrad.ru/VF-DLP-000765

Автор: <Spawn> 5.1.2005, 12:13

Помоему вы его немножко не поняли:

Цитата

мне необходимо знать как он был завершен,
т.е. был ли он полностью распакован или в окне SFX-архива была нажата клавиша "Отмена" или
даны другие команды прерывающие его работу.

Автор: Alex 5.1.2005, 14:32

Да нет, поняли мы его правильно:

Код


function FileExecuteWait(const FileName, Params, StartDir: string;
  InitialState: Word): Integer;
var
  Info: TShellExecuteInfo;
  ExitCode: DWORD;
begin
  FillChar(Info, SizeOf(Info), 0);
  Info.cbSize := SizeOf(TShellExecuteInfo);
  with Info do begin
    fMask := SEE_MASK_NOCLOSEPROCESS;
    Wnd := Application.Handle;
    lpFile := PChar(FileName);
    lpParameters := PChar(Params);
    lpDirectory := PChar(StartDir);
    nShow := InitialState;
  end;
  if ShellExecuteEx(@Info) then begin
    repeat
      Application.ProcessMessages;
      GetExitCodeProcess(Info.hProcess, ExitCode);
    until (ExitCode <> STILL_ACTIVE) or Application.Terminated;
    Result := ExitCode;
  end
  else Result := -1;
end;

А если еще внимательно почитать описания к консольной версии WinRar, то можно найти такие строки:

Цитата

Коды возврата
~~~~~~~~~~~~~

В случае успешного завершения операции RAR выходит с нулевым (0) кодом
возврата. Если операция прервана из-за ошибки, то код возврата будет
ненулевым. (Коды возврата можно, например, использовать в пакетных
файлах с помощью переменной ERRORLEVEL.)

   255   ПРЕРВАНО    Операция была прервана пользователем.
   ПОЛЬЗОВАТЕЛЕМ

   9   ОШИБКА СОЗДАНИЯ Ошибка при создании файла

   8   ОШИБКА ПАМЯТИ Недостаточно памяти для выполнения операции.

   7   ОШИБКА    Ошибка при указании команды/параметра в
   ПОЛЬЗОВАТЕЛЯ    командной строке.

   6   ОШИБКА ОТКРЫТИЯ Произошла ошибка открытия файла.

   5   ОШИБКА ЗАПИСИ Произошла ошибка записи на диск.

   4   ЗАБЛОКИРОВАННЫЙ Попытка изменения архива, заблокированного
   АРХИВ ранее командой 'k' или ключом '-k'.

   3   ОШИБКА CRC    Во время распаковки обнаружена ошибка CRC.

   2   ФАТАЛЬНАЯ Произошла критическая ошибка.
   ОШИБКА

   1   ПРЕДУПРЕЖДЕНИЕ   Произошла некритическая ошибка.

   0   УСПЕШНОЕ    Работа завершена без ошибок.
   ЗАВЕРШЕНИЕ

Приведенная мной функция взята из RxLib и в FAQ об этом сказано.

Автор: <Spawn> 5.1.2005, 15:02

Цитата

А если еще внимательно почитать описания к консольной версии WinRar, то можно найти такие строки: ...

Вот это уже другое дело. Я же имел ввиду то, что человеку не нужен код ожидания завершения стороннего процесса, так как у него это есть. Его же интересовала возможность узнать причину завершения, чего до этого поста не было сказано.