Это не бизон - это жуть в полоску 
В бизоне есть понятие приоритетов операций, не надо все расписывать поэлементно. И откуда у вас там пробелы взялись (spc) - они еще на этапе выделения лексем должны были быть удалены.
Вот, кусок реального файла:
| Код |
%token vID
%token vSTR
%token vINT
%left ','
%right '=' tASSIGN
%right '?'
%left tOR
%left tAND
%left '|'
%left '^'
%left '&'
%left tEQ tNE
%left tGE '>' tLE '<'
%left tSHR tSHL tSRA
%left '+' '-'
%left '*' '/' '%'
%left tIN
%right tPP tMM
%right UNOP
%left '.'
%left STR_CAT
%%
expression:
_expression
| '(' '{' script_body1 '}' ')' {$$=$3;}
;
un_expr:
vINT {$$=new IntConst($1);}
| vID {$$=get_op_by_id($1);}
| str_const {$$=new StrConst($1);}
| '(' expression ')' {$$=$2;}
;
_expression:
un_expr
| expression '*' expression {$$=newBinOp(COP_mul, $1,$3);}
| expression '/' expression {$$=newBinOp(COP_div, $1,$3);}
| expression '%' expression {$$=newBinOp(COP_mod, $1,$3);}
| expression '+' expression {$$=newBinOp(COP_add, $1,$3);}
| expression '-' expression {$$=newBinOp(COP_sub, $1,$3);}
| expression '>' expression {$$=newBinOp(COP_gt, $1,$3);}
| expression '<' expression {$$=newBinOp(COP_lt, $1,$3);}
| expression tEQ expression {$$=newBinOp(COP_eq, $1,$3);}
| expression '&' expression {$$=newBinOp(COP_and, $1,$3);}
| expression '^' expression {$$=newBinOp(COP_xor, $1,$3);}
| expression '|' expression {$$=newBinOp(COP_or, $1,$3);}
| expression tSHR expression {$$=newBinOp(COP_shr, $1,$3);}
| expression tSHL expression {$$=newBinOp(COP_shl, $1,$3);}
| expression tGE expression {$$=newBinOp(COP_ge, $1,$3);}
| expression tLE expression {$$=newBinOp(COP_le, $1,$3);}
| expression tNE expression {$$=newBinOp(COP_ne, $1,$3);}
| expression tOR expression {$$=newBinOp(COP_lor, $1,$3);}
| expression tAND expression {$$=newBinOp(COP_land, $1,$3);}
| expression ',' expression {$$=$1->append($3);}
| '!' un_expr %prec UNOP {$$=newUnOp(COP_linv,$2);}
| '~' un_expr %prec UNOP {$$=newUnOp(COP_not,$2);}
| '-' un_expr %prec UNOP {$$=newUnOp(COP_neg,$2);}
| '+' un_expr %prec UNOP {$$=$2;}
| tPP vID %prec tPP {$$=newUnOp(COP_ppv,get_op_by_id($2));}
| vID tPP %prec tPP {$$=newUnOp(COP_vpp,get_op_by_id($1));}
| tMM vID %prec tMM {$$=newUnOp(COP_mmv,get_op_by_id($2));}
| vID tMM %prec tMM {$$=newUnOp(COP_vmm,get_op_by_id($1));}
| vID '(' param_list ')' {$$=newCall($1,$3);}
| expression '.' vID '(' param_list ')' %prec '.'
{$$=newCall($3,(new ParamDef($1))->append($5));}
| vID tASSIGN expression {$$=new AssignOp($2,$1,$3);}
| vID '=' expression {$$=new AssignOp(COP_ass,$1,$3);}
| expression tIN '[' param_list ']' {$$=new InOp($1,$4);}
| expression '?' expression ':' expression %prec '?'
{$$=new IfStmt($1,$3,$5);}
;
|
|
Нафига бизону знать какими пробелами были разделены значащие лексемы?
