Форум программистов [Powered by Invision Power Board]

Код

'********************************************************************
'* Модуль, организующий работу с объектом RegExp.
'* Организованы несколько глобальных переменных,
'* хранящих все режимы работы приведённых здесь функций и процедур.
'*
'********************************************************************

Option Explicit



Global MyRegExpPattern As String
Global MyRegExpMultiLine As Boolean
Global MyRegExpGlobal As Boolean
Global MyRegExpIgnoreCase As Boolean


'********************************************************************
'*
'* Процедура : SetRegExpProperties
'* Описание  : Устанавливает начальные значения объекта MyRegExp
'*  Вход     :
'*  Выход    : Нет
'********************************************************************
Private Sub SetRegExpProperties(ByRef MyRegExp As Object)

    MyRegExp.Pattern = MyRegExpPattern
    MyRegExp.MultiLine = MyRegExpMultiLine
    MyRegExp.Global = MyRegExpGlobal
    MyRegExp.IgnoreCase = MyRegExpIgnoreCase
    
End Sub


'********************************************************************
'*
'* Функция  : blnTestString (приватная)
'* Описание : Определяет соответствует ли строка шаблону
'* Вход     : strString - строка
'*            strPath   - шаблон (регулярное выражение)
'* Выход    : true - соответствует шаблону; false - не соответствует шаблону
'*
'********************************************************************
Private Function blnTestString(ByVal strString As String, ByVal strPath As String) As Boolean

Dim RegEx As Object

' Создаём экземпляр объекта RegExp
    Set RegEx = CreateObject("VBScript.RegExp")

' Настраиваем режимы работы регулярного выражения
    RegEx.IgnoreCase = True ' Осуществляем поиск игнорируя размер букв
    RegEx.Global = False    ' Ищем до первого совпадения
    RegEx.MultiLine = False ' Текст не является многострочным
    RegEx.Pattern = strPath ' Устанавливаем шаблон регулярного выражения
  
' Тестируем строку на соответствие шаблону
    blnTestString = RegEx.Test(strString)

' Уничтожаем экземпляр объекта RegExp
    Set RegEx = Nothing

End Function

'********************************************************************
'*
'* Функция  : strExtractString (приватная)
'* Описание : Выделяет из строки подстроку, удовлетворяющую шаблону
'* Вход     : strString - строка
'*            strPath   - шаблон
'* Выход    : строка соответствущая шаблону
'*
'********************************************************************
Private Function strExtractString(ByVal strString As String, ByVal strPath As String) As String
Dim RegEx As Object         ' Экземпляр регулярного выражения
Dim colMatches  As Object   ' Коллекция совпадений
Dim aMatch As Object        ' один из совпавших образцов

' Создаём экземпляр объекта RegExp
    Set RegEx = CreateObject("VBScript.RegExp")

' Настраиваем режимы работы регулярного выражения
    RegEx.IgnoreCase = True ' Осуществляем поиск игнорируя размер букв
    RegEx.Global = False    ' Ищем до первого совпадения
    RegEx.MultiLine = False ' Текст не является многострочным
    RegEx.Pattern = strPath ' Устанавливаем шаблон регулярного выражения
  
' Тестируем строку на соответствие шаблону
    Set colMatches = RegEx.Execute(strString)
    For Each aMatch In colMatches
        strExtractString = aMatch.Value
        Exit For
    Next

' Уничтожаем экземпляры объектов
    Set colMatches = Nothing
    Set RegEx = Nothing

End Function