Форум программистов [Powered by Invision Power Board]

Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате

Форум программистов > Центр помощи > [Pascal]обьясн. поч. прога не удал. все пробелы

Автор: CppDevelopeR 15.4.2008, 19:01

Задача: из строки удалить все пробельные символы. Решение:

Код


procedure delspace(var s:string);
var i:integer;
begin
  for i:=1 to length(s) do
    if s[i]=' ' then delete(s,i,1);
end;

Постройте пример, на котором данная процедура будет удалять не все пробелы. Объясните, почему так происходит. Приведите правильное решение поставленной задачи.

Автор: Rodman 15.4.2008, 19:07

Код


procedure delspace(var s:string);
var i:integer;
begin
  for i:=length(s) downto 1 do
    if s[i]=' ' then 
             delete(s,i,1);
end;

Автор: CppDevelopeR 15.4.2008, 19:08

а мона обьяснит, пасему тот код не работает? мне ето нуна!

Автор: CppDevelopeR 15.4.2008, 20:02

Прав ли я, что тут удаляюца пробелы тока в 1 строке в файле?

Автор: ama_kid 15.4.2008, 21:38

Цитата(CppDevelopeR @ 15.4.2008, 19:08

)

а мона обьяснит, пасему тот код не работает?

Потому что удаляя один символ, ты сдвигаешь остальные символы влево, следовательно если будут два подряд пробела - то первый удалится, а следующий пропустится, т.к. перейдет на место уже проверенного символа и на следующем шаге цикл пойдет через один символ...

Автор: THandle 15.4.2008, 21:41

Цитата(CppDevelopeR @ 15.4.2008, 21:02

)

Прав ли я, что тут удаляюца пробелы тока в 1 строке в файле?

Файлов я тут не вижу smile

Вся проблема в том, что в данном коде:

Код


procedure delspace(var s:string);
var i:integer;
begin
  for i:=1 to length(s) do
    if s[i]=' ' then delete(s,i,1);
end;

после удаления символа длина строки уменьшается и соответственно в следующий раз будет проверяться не тот символ который должен бы проверяться, а следующий. То есть при парных пробелах будет удалятся только один из них.

Вот пример:

Код


program Project1;

procedure delspace(var s:string);
var
  i:integer;
begin
  for i:=1 to length(s) do
    if s[i]=' ' then
      delete(s,i,1);
end;

var
  s : string = 'a n v  a';
begin
  delspace(s);
  writeln(s);
  readln;
end.

идет наш цикл:

   i       длина строки        проверяемый символ              удаляем?

  1                 8                                a                                    нет
  2                 8                           пробел                               да
  3                 7                пробел(см. объяснение 1)            да
  4                 6                пробел(см. объяснение 2)            да
  5                 5                               a                                     нет

Объяснение 1. Так как мы удалили пробел стоящий перед символом n, на позицию s[2] встал символ n, а позицию s[3] занял идущий за ним пробел.

Объяснение 2. То же самое, только другой символ.

На 5 итерации пробел уже пропускается, так как смещается на уже пройденную циклом позицию.
Далее, так как значение от и до цикла for рассчитываются только один раз при запуске цикла, наш цикл прогоняет уже не существующие элементы строки. Тут как раз спасает цикл for x downto y do...

Я бы лично оформил данный код вообще без delete.

Код


program Project1;

function Delspace(s : string) : string;
var
  i : integer;
begin
  for i := 1 to length(s) do
    if s[i] <> ' ' then
      result := result + s[i];
end;

var
  s : string = 'a n v  a';
begin
  s := delspace(s);
  writeln(s);
  readln;
end.