Форум программистов [Powered by Invision Power Board]

Код
PROGRAM Pas_026b;
CONST
  N     = 10;
TYPE
  TRec  = RECORD
    Number : Word;
    HexStr : String[4];
  END;
  TArrInt = array [1..N] of Word;
  TArrRec = array [1..N] of TRec;
FUNCTION HexStr( VAR Num; ByteCount : Byte) : String;assembler;
asm
        les di,@Result     {get address of function result}
        mov dx,ds          {save Turbo's DS in DX         }
        lds si,num         {get number address            }
        mov al,ByteCount   {how many bytes?               }
        xor ah,ah          {make a word                   }
        mov cx,ax          {keep track of bytes in CX     }
        add si,ax          {start from MS byte of number  }
        dec si
        shl ax,1           {how many digits? (2/byte)     }
        cld                {store # digits (going forward)}
        stosb              {in destination string's length byte}
@@HexLoop:
        std                {scan number from MSB to LSB   }
        lodsb              {get next byte                 }
        mov ah,al          {save it                       }
        shr al,1           {extract high nibble           }
        shr al,1
        shr al,1
        shr al,1
        add al,90h         {special hex conversion sequence}
        daa                {using ADDs and DAA's           }
        adc al,40h
        daa                {nibble now converted to ASCII  }
        cld                {store ASCII going up           }
        stosb
        mov al,ah          {repeat conversion for low nibble}
        and al,0Fh
        add al,90h
        daa
        adc al,40h
        daa
        stosb
        loop  @@HexLoop       {keep going until done           }
        mov  ds,dx            {restore Turbo's DS              }
END;

PROCEDURE FillArrInt(VAR a : TArrInt);
VAR
  i : Integer;
BEGIN
  for i:=1 to N do begin
    a[i]:=Random($FFFF);
  end;
END;

PROCEDURE MakeArrRec(VAR a : TArrInt; VAR b : TArrRec);
VAR
  i : Integer;
BEGIN
  for i:=1 to N do begin
    b[i].Number:=a[i];
    b[i].HexStr:=HexStr(b[i].Number, SizeOf(b[i].Number));
  end;
END;

VAR
  B : TArrInt;
  C : TArrRec;
  i : Integer;
BEGIN
  Randomize;
  FillArrInt(B);
  MakeArrRec(B, C);
  WriteLn('    B[i]    c[i]   HexStr');
  for i:=1 to N do begin
    WriteLn(b[i]:8, c[i].Number:8, c[i].HexStr:8);
  end;
END.