Цитата(PsiMagistr @ 11.6.2010, 07:10  ) | | Если вам не жалко будет посмотреть на это жалкое зрелище. |
На самом деле всё не так уж плохо... Вы избежали очень многих характерных ошибок. В частности, вы очень правильно делаете, формируя в рантайме полный путь к картинкам.
| Цитата(PsiMagistr @ 11.6.2010, 14:19 ) | | Там правда почти не реализовано ничего. |
"Спокойствие, только спокойствие!" Я найду, до чего докопаться...
По поводу стиля оформления кода
Настоятельно рекомендую поработать над стилем оформления кода.
В качестве основы я бы рекомендовал статью http://www.delphikingdom.com/asp/viewitem.asp?catalogid=802
Посмотрите также её http://www.delphikingdom.com/asp/articles_forum.asp?ArticleID=802
Рекомендую, в частности, обратить внимание на сообщение в обсуждении от 15-02-2007 00:37
По поводу пользовательского интерфейса
1. На мой взгляд, достаточно неудачной идеей является использование радиогруппы в форме запуска игры, поскольку любое действие становится двухэтапным, даже просто закрытие формы. Я бы в данном случае использовал обычные кнопки для всех пунктов. Кроме того, надписи на пунктах вводят в заблуждение, поскольку в них речь идёт только о персонаже. На самом деле, речь должна идти о персонаже и запуске игры с ним (поскольку именно так у вас сейчас реализовано). Так что, если что-то менять в рамках заданной вами модели, то в этой форме я бы сделал кнопки (названия условны):
Запуск игры с новым персонажем
Запуск игры с существующим персонажем
Выход
2. Окно с персонажами должно иметь кнопку "Отмена".
3. Запрос на подтверждение выхода в ситуции, когда выход не приводит к потере чего-либо (настроек, игры и т.д.), не имеет смысла и только раздражает.
4. Ситауция, когда после нажатия на что-то, появляется череда окон, каждое из которых является единственным отображаемым, лично мной воспринимается как некомфортная. На мой взгляд, гораздо лучше, когда есть некая "опорная" (она-же главная) форма, которая маячит на заднем плане, а всё, что происходит на переднем плане, относится именно к ней, например, выбор персонажа для игры где? Првильно, на главной форме... Поэтому на мой взгляд, логичнее было бы главной сделать именно форму с игровым полем, а уже там - меню или кнопки "Выбрать персонаж", "Начать новую игру" и т.д. В принципе, вы писали, что у вас есть мысль сделать главной формой именно игровую форму. Мысль вполне здравая. Причём я бы не стал предлагать выбор персонажа при открытии игровой формы. Пусть человек спокойно зайдёт, посмотрит на пустую игровую форму, осмотрится, и уже когда сам захочет, нажмёт кнопку "Начать новую игру" или "Выход".
По поводу алгоритмов и реализации
1. Сейчас у вас реализовано так: из главного меню открывается форма создания/выбора персонажа, а в обработчике закрытия этой формы открывается игровая форма. Это крайне неудачное решение, поскольку при просмотре обработчика главного меню эта логика полностью скрыта. Гораздо логичнее было бы в обработчике главного меню сначала показать форму выбора персонажа, после её закрытия проанализировать код возврата, и если было подтверждение, а не отмена, открыть игровую форму. Но для этого форма выбора персонажа должна отображаться в модальном режиме. Немодальные формы должны применяться только в случаях, когда небходим параллельный доступ к нескольким окнам. В случае окна выбора персонажа такой необходимости нет. Недостатком модального режима является нестандартное поведение при сворачивании, поэтому желательно, чтобы основная рабочая форма не была модальной. Большинство же вспомогательных форм логично делать модальными. Не забудьте у ваших форм в дизайнере вернуть Visible в False.
2. Рекомендации по коду на примере TFrmCreate.RGenderClick
а) Если имеется несколько блоков кода, различающихся только небольшой частью, логично оставить только один блок, а разичающуюся часть обработать отдельно, возможно, заранее (но не обязательно), а в основном блоке использовать уже вычисленный результат.
б) Если в коде много раз встречается одинаковая длинная конструкция (GBX.Controls[i] as TPanel), то логично завести отдельную переменную нужного типа, поместить в неё результат и далее использовать только её.
в) Если один раз проверили тип объекта через оператор is (if GBX.Controls[i] is TPanel), то в дальнейшем нет необходимости использовать приведение типа с проверкой (GBX.Controls[i] as TPanel). Вместо этого логичнее применять приведение типа без проверки (TPanel(GBX.Controls[i])).
г) При формировании сложных строк удобно использовать функцию Format. Это значительно облегчает воприятие кода.
д) При формировании длинных строк, различающихся только в одном месте, бывает очень удобна функция IfThen из модуля StrUtil (есть варианты для числовых типов, см. справку). Поскольку при этом вычисляются оба значения, следует использовать эту функцию только для случаев, когда имеются оба готовых значения, в данном случае - литералы.
| Код |
// Исходный вариант (отформатирован)
procedure TFrmCreate.RGenderClick(Sender: TObject);
var
i : Integer;
begin
if RGender.ItemIndex = 1 then
begin
for i := 0 to GBx.ControlCount - 1 do
if GBX.Controls[i] is TPanel then
begin
((GBX.Controls[i] as TPanel).Controls[0] as TImage).Picture.LoadFromFile(
ExtractFilePath(Application.ExeName)+ 'Avatars/Female/'+
IntToStr((GBX.Controls[i] as TPanel).Tag) +'.jpg' );
(GBX.Controls[i] as TPanel).Color := clSilver;
end;
end
else
begin
for i := 0 to GBx.ControlCount - 1 do
if GBX.Controls[i] is TPanel then
begin
((GBX.Controls[i] as TPanel).Controls[0] as TImage).Picture.LoadFromFile(
ExtractFilePath(Application.ExeName)+ 'Avatars/Male/'+
IntToStr((GBX.Controls[i] as TPanel).Tag) +'.jpg' );
(GBX.Controls[i] as TPanel).Color := clSilver;
end;
end;
end;
|
| Код |
// Доработанный вариант
procedure TFrmCreate.RGenderClick(Sender: TObject);
var
i : Integer;
FileName: String;
Panel: TPanel;
begin
FileName := ExtractFilePath(Application.ExeName) +
IfThen(RGender.ItemIndex = 1, 'Avatars\Female\', 'Avatars\Male\') + '%d.jpg';
for i := 0 to GBx.ControlCount - 1 do
if GBX.Controls[i] is TPanel then
begin
Panel := TPanel(GBX.Controls[i]);
(Panel.Controls[0] as TImage).Picture.LoadFromFile(
Format(FileName, [Panel.Tag]));
Panel.Color := clSilver;
end;
end;
|
|
). Правда, если они изложены сухим языком, то начинать (именно начинать) учиться по ним - скучно. В этом случае, действительно уж лучше кто-нибудь типа Фленова, только при прочтении не стоит принимать всё за аксиому.