Форум программистов [Powered by Invision Power Board]

Код

unit Unit1;

interface

uses
 Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
 Dialogs, StdCtrls, Buttons,

 Contnrs;

type
 TForm1 = class(TForm)
   ComboBox1: TComboBox;
   ComboBox2: TComboBox;
   ComboBox3: TComboBox;
   procedure FormCreate(Sender: TObject);
   procedure FormDestroy(Sender: TObject);
   procedure ComboBoxesChange(Sender: TObject);
 private
   { Private declarations }
 public
   { Public declarations }
   FAvailableValues: TStringList;
   FComboBoxes: TObjectList;
 end;

var
 Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var
 I: Integer;
begin
 FAvailableValues := TStringList.Create;
 FAvailableValues.Add('-');
 FAvailableValues.Add('1');
 FAvailableValues.Add('2');
 FAvailableValues.Add('3');

 FComboBoxes := TObjectList.Create;
 FComboBoxes.Add(ComboBox1); // Tag = 0
 FComboBoxes.Add(ComboBox2); // Tag = 1
 FComboBoxes.Add(ComboBox3); // Tag = 2

 for I := 0 to FComboBoxes.Count - 1 do
 begin
   TComboBox(FComboBoxes[I]).Items.AddStrings(FAvailableValues);
   TComboBox(FComboBoxes[I]).ItemIndex := 0;
 end;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
 FAvailableValues.Free;
 FComboBoxes.Free;
end;

procedure TForm1.ComboBoxesChange(Sender: TObject);
var
 FilteredValues: TStringList;
 I, J: Integer;
 SelectedValue: string;
begin
 FilteredValues := TStringList.Create;
 try
   for I := 0 to FComboBoxes.Count - 1 do
   begin
     with TComboBox(FComboBoxes[I]) do
       // Сохраняем значение ComboBox'а
       SelectedValue := Items[ItemIndex];

     // Создаем список значений ComboBox'а исключая значения
       // выбранные в других ComboBox'ах
     FilteredValues.AddStrings(FAvailableValues);
     for J := 0 to FComboBoxes.Count - 1 do
     begin

       if J = I then
         Continue;

       with TComboBox(FComboBoxes[J]) do
         if (Items[ItemIndex] <> '-') then
           FilteredValues.Delete(FilteredValues.IndexOf(Items[ItemIndex]));
     end;

     with TComboBox(FComboBoxes[I]) do
     begin
       Items.Clear;
       Items.AddStrings(FilteredValues);
       ItemIndex := Items.IndexOf(SelectedValue);
     end;

     FilteredValues.Clear;
   end;
 finally
   FilteredValues.Free;
 end;

end;

end.