vasjon,
Привет.
Недавно писал на VB.NET программку работающую с БД.
Для хранения настроек программы использовал новую фичу от MS - My.Settings.
Т.е. настройки программы хранятся в файле user.config для каждого пользователя.
Редактировать их пользователь может через PropertyGrid который я выводил в отдельной форме.
Код формы:
| Код |
Public Class frmSettings
Private Sub frmSettings_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
grdSettings.SelectedObject = My.Settings
End Sub
Private Sub frmSettings_FormClosing(ByVal sender As System.Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles MyBase.FormClosing
My.Settings.Save()
End Sub
End Class
|
Чтобы получить нужные настройки программы идем во вкладку Settings свойств проекта. Там прописываем нужные настройки, но значения не указываем. Их укажет пользователь при старте программы.
Далее нужно подредактировать сгенерированный студией файл Settings.Designer.vb.
Используя аттрибуты свойств указывает к какой группе они относятся, коментарии, отображать или нет.
Выглядит это примерно так
| Код |
Option Strict On
Option Explicit On
Namespace My
<Global.System.Runtime.CompilerServices.CompilerGeneratedAttribute(), _
Global.System.CodeDom.Compiler.GeneratedCodeAttribute("Microsoft.VisualStudio.Editors.SettingsDesigner.SettingsSingleFileGenerator", "8.0.0.0"), _
Global.System.ComponentModel.EditorBrowsableAttribute(Global.System.ComponentModel.EditorBrowsableState.Advanced)> _
Partial Friend NotInheritable Class MySettings
Inherits Global.System.Configuration.ApplicationSettingsBase
Private Shared defaultInstance As MySettings = CType(Global.System.Configuration.ApplicationSettingsBase.Synchronized(New MySettings), MySettings)
#Region "My.Settings Auto-Save Functionality"
#If _MyType = "WindowsForms" Then
Private Shared addedHandler As Boolean
Private Shared addedHandlerLockObject As New Object
<Global.System.Diagnostics.DebuggerNonUserCodeAttribute(), Global.System.ComponentModel.EditorBrowsableAttribute(Global.System.ComponentModel.EditorBrowsableState.Advanced)> _
Private Shared Sub AutoSaveSettings(ByVal sender As Global.System.Object, ByVal e As Global.System.EventArgs)
If My.Application.SaveMySettingsOnExit Then
My.Settings.Save()
End If
End Sub
#End If
#End Region
Public Shared ReadOnly Property [Default]() As MySettings
Get
#If _MyType = "WindowsForms" Then
If Not addedHandler Then
SyncLock addedHandlerLockObject
If Not addedHandler Then
AddHandler My.Application.Shutdown, AddressOf AutoSaveSettings
addedHandler = True
End If
End SyncLock
End If
#End If
Return defaultInstance
End Get
End Property
'то что между "<" ">" это аттрибуты, дописывал сам
<Global.System.ComponentModel.CategoryAttribute("Application"), _
Global.System.Configuration.ApplicationScopedSettingAttribute(), _
Global.System.Diagnostics.DebuggerNonUserCodeAttribute(), _
Global.System.Configuration.SpecialSettingAttribute(Global.System.Configuration.SpecialSetting.ConnectionString), _
Global.System.Configuration.DefaultSettingValueAttribute("Provider=Microsoft.Jet.OLEDB.4.0;Data Source=""D:\MyProjects\MAIL ID\Mailing1\Mail" & _
"ing.mdb""")> _
Public ReadOnly Property MailingConnectionString() As String
Get
Return CType(Me("MailingConnectionString"), String)
End Get
End Property
'то что между "<" ">" это аттрибуты, дописывал сам
<Global.System.ComponentModel.CategoryAttribute("Application"), _
Global.System.ComponentModel.DescriptionAttribute("Naam van database bestand die zal gebruikt worden in dit programma."), _
Global.System.Configuration.UserScopedSettingAttribute(), _
Global.System.Diagnostics.DebuggerNonUserCodeAttribute(), _
Global.System.Configuration.DefaultSettingValueAttribute(""), _
Global.System.ComponentModel.EditorAttribute(GetType(clsFileNameEditor), GetType(System.Drawing.Design.UITypeEditor))> _
Public Property DataBase() As String
Get
Return CType(Me("DataBase"), String)
End Get
Set(ByVal value As String)
Me("DataBase") = Value
End Set
End Property
'эту функцию дописал сам, она переписывает значение свойства connectionString используя редактируемое пользователем свойство DataBase().
Public Function SetUserOverride() As String
Me("MailingConnectionString") = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Chr(34) & Me.DataBase & Chr(34)
Return Me("MailingConnectionString").ToString()
End Function
End Class
End Namespace
|
В моем случае, использовался TypedDataSet которому студия задает соединение в designermode и оно прописывается в app.config и во время работы программы изменению не подлежит.
Вот чтобы это обойти и дать возможность пользователю самому указывать где лежит его база данных и сохранить это в его настройках(user.config) и забить болт на app.config, я и дописал функцию SetUserOverride(). Она берет значение указанное пользователем и переписывает значение connectionString, подставляя туда путь к БД(runtime) вместо прописанного в designermode.
А чтобы пользователь не писал путь в БД и ее имя в ручную добавляем в PropertuGrid кнопочку с точечками, которая откроет OpenFileDialog для выбора файла БД.
Для этого свойству DataBase() добавим аттрибут
| Код |
Global.System.ComponentModel.EditorAttribute(GetType(clsFileNameEditor), GetType(System.Drawing.Design.UITypeEditor))
|
Для которого напишем следующий класс Editor
| Код |
Public Class clsFileNameEditor
Inherits Global.System.Drawing.Design.UITypeEditor
Public Overrides Function GetEditStyle(ByVal context As System.ComponentModel.ITypeDescriptorContext) As Global.System.Drawing.Design.UITypeEditorEditStyle
Return Global.System.Drawing.Design.UITypeEditorEditStyle.Modal
End Function
Public Overrides Function EditValue(ByVal context As System.ComponentModel.ITypeDescriptorContext, ByVal provider As System.IServiceProvider, ByVal value As Object) As Object
Dim f As New OpenFileDialog()
f.Filter = "Access File(*.mdb)|*.mdb"
f.ShowDialog()
Return f.FileName
End Function
End Class
|
Вот таким образом я решил эту проблемку.
Да маленькое замечание.
Класс Settings.Designer.vb сгенерирован студией, и если вы после всех внесенных в него изменений за каким то лядом полезете во вкладку Settings свойств проекта и что-то там поменяете, то студия сгенерит этот класс по новой и все ваши труды пропадут.
А по сему сначала думаем, а потом делаем. Или пишем добавки в этому классу в класс Settings.vb это Partial класс - вторая половинка класса Settings.Designer.vb.
Успехов. 
Надеюсь инфа пригодиться в том или ином случае. 
|
)