Что именно? Телефонная книга?
При старте программы программа выводит в STDOUT приветствие и возможные команды.
При вводе команды add, программа запрашивает имя, телефон, затем сохраняет данные в DBM файл где телефон - это ключь, а имя - это значение.
При вводе команды all показывает все телефоны в отсортированном порядке по именам.
При вводе search ....., где точки это искомое слово или часть слова или часть номера телефона. После программа находит все соответствия и выводит их в STDOUT, опять же в отсортированном порядке.
При вводе команды quit, программа прощается с пользователем и завершает свою работу.
Вот код:
| Код |
#!/usr/bin/perl -w
use strict;
# Имя файла, в котором будут сохраняться данные
my $file = "phone_data";
# Этот хеш будет связан с DBM файлом
my %dbm = ();
# Открываем DBM файл
dbmopen(%dbm, "$file", 0644) or die "Can't open data file: $!\n";
# Эта подпрограмма будет создавать нужный заголовок
sub print_title {
# Генерирует заголовок
my $check = shift;
my $title = " $check of " . localtime() . " ";
print "\n";
# Выводим заголовок
print "=" x 3;
print $title;
print "=" x (79 - 3 - length($title)), "\n";
}
# Эта подпрограмма будет выводить отсортированные
# список всех данных из телефонной книги. Здесь я немного усложнил сортировку,
# если имена одинаковые, тогда сортировка будет по номеру телефона.
sub show_all {
foreach my $phone ( sort { $dbm{$a} cmp $dbm{$b} || $a cmp $b } keys %dbm ) {
print "$dbm{ $phone }\t$phone\n";
}
}
# Эта подпрограмма будет искать пользователя по имени или по номеру телефона
# и в отсортированном порядке выводить данные в STDOUT, причём найденные части
# будут захвачены в треугольные скобки.
sub print_search {
my $s = shift;
foreach my $phone ( sort { $dbm{$a} cmp $dbm{$b} || $a cmp $b } keys %dbm ) {
my( $ph, $nm ) = ($phone, $dbm{$phone});
if ( $ph =~ s/($s)/<$1>/ or $nm =~ s/($s)/<$1>/i ) {
print "$nm\t$ph\n";
}
}
}
# Подпрограмма запрашивает имя пользователя и телефон, затем сохраняет их в базу
sub add_item {
my( $name, $phone ) = ();
while (1) {
print "Please enter user name or \"back\" for return to general menu: ";
chomp($name = <STDIN>);
return if $name =~ /^back$/i;
last if $name =~ /\w+/;
}
while (1) {
print "Please enter phone number of $name or \"back\" for return to general menu: ";
chomp($phone = <STDIN>);
return if $phone =~ /^back$/i;
last if $phone =~ /^\d+$/;
}
if ( exists $dbm{ $phone } ) {
print "This phone number is exists in data base\n";
} else {
print "Phon number $phone of $name was success added in data base\n";
$dbm{ $phone } = $name;
}
}
# Подпрограмма удаляет запись из файла с заданным телефонным номером
sub remove_item {
my $phone = shift;
if ( exists $dbm{ $phone } ) {
delete $dbm{ $phone };
print "\nNumber $phone was successful removed from data base.\n";
} else {
print "\nNumber $phone is not exists.\n";
}
}
# Начинаем бесконечный цикл, для запроса команд
while (1) {
print "\nPlease enter command \"add\", \"all\", \"search ...\", \"delete\" or \"quit\"\n";
print "add - for add new number in data base\n";
print "all - for get list of all numbers from data base\n";
print "search [substring] - for search user or phone info\n";
print "delete [phone num] - for delete phone number from data base\n";
print "quit - for exit\n";
chomp(my $cmd = <STDIN>);
# Если введена команда quit, завершаем бесконечный цикл
last if ($cmd =~ /^quit$/i);
# Если введена команда all выводи соответствуюший заголовок и
# запускаем соответствующую подпрограмму.
if ( $cmd =~ /^all$/ ) {
print_title("All phonebook");
show_all();
}
# Если введена команда search и за ней искомая часть, выводим
# заголовок и выводим отсортированные искомые данные
if ( $cmd =~ /^search/ ) {
if ( my($search) = $cmd =~ /^search\s+(\w+|\d+)$/ ) {
print_search($search);
} else {
print "\nFor search must by search substring\n";
print "Forexample so: search 0497\nor so: search Pupk\n";
}
}
# Если была получена команда delete [phone num], вызываем соответствующую
# подпрограмму
if ( $cmd =~ /^delete/ ) {
if ( my($ph) = $cmd =~ /^delete\s+(\d+)$/ ) {
remove_item($ph);
} else {
print "\nFor delete must by phone number after delete\n";
print "Forexample so: delete 3545512\n";
}
}
# Если получена команда add, запускаем соответствующую подпрограмму
add_item if $cmd =~ /^add$/i;
}
# Прощаемся с пользователем и завершаем выполнение программы
dbmclose(%dbm);
print "\nBye bye...\n";
exit 0;
|
Код получился очень большой из-за коментариев, а так же я всё в нём разбил на подпрограммы для более лёгкого чтения программы. Некоторые моменты, такие как блокировка, форматирование я не стал добавлять, так как это просто пример, который я не хотел загромождать.
Ничего сложного здесь нет, главное быть немного знакомым с работой с хешами, условными операторами и регулярными выражениями, ну ещё и циклами. |
0