Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате
Форум программистов > Perl: Общие вопросы > ООП в perl


Автор: DEER 16.11.2005, 12:23
Народ, я слышал что в perl можно создавать классы,
хотелось бы узнать как?
если можно маленький пример, класса
скажем с двумя полями, и одним методом, который складывает эти поля и возвращает сумму

smile
Заранее спасибо

Автор: arto 16.11.2005, 13:00
perldoc perltoot

Автор: korob2001 16.11.2005, 13:08
Вобщем написал тебе такой вот тестовый класс. Сохрание его под именем Sum.pm
Код

package Sum;

# Конструктор класса
sub new {
    my $check = shift;
    my $class = ref( $check ) || $check;
    my $self  = [@_];
    return bless( $self, $class );
}

# Метод принимает любое кол-во цифр и сохраняет их
sub addNumbers {
    my $self = shift;
    # Проверяем параметры, что они действительно являются числами
    for ( @_ ) {
          if ( /^\d+(?:\.\d+)?$/ ) {
               # Если число сохраним его как член класса
               push( @$self, $_ );
          }
    }
}

# Метод возвращает сумму всех чисел
sub getSum {
    my $self = shift;
    my $sum = 0;
    foreach (@$self) {
          $sum += $_;
    }
  return $sum;
}

# Метод возвращает общее кол-во чисел
sub getColNumbers {
    my $self = shift;
    return scalar @$self;
}

# Метод возвращает все числа в виде строки разделённой запятыми
sub toString {
    my $self = shift;
    my $str = "";
    $str .= "$_, " for ( @$self );
    $str =~ s/\D+$//;
    return $str;
}

# Метод возвращает среднее значение всех чисел
sub getAverage {
    my $self = shift;
    my $sum = 0;
    map { $sum += $_ } @$self;
    $sum /= @$self;
    return $sum;
}

# Мтод очищает члены класса
sub clearMemory {
    my $self = shift;
    @$self = ();
}

# Классы всегда должны возвращать истену, как и модули.
1;

Тепрь в тот же каталог, сохрани следующую программу, под любым именем лишь бы расширение было как у выполняемого файла, как правило это .pl или .cgi. Я назвал его test.pl
Код

#!/usr/bin/perl -w
use strict;

# Укажим Perl, что модули нужно искать и в текущем каталоге
use lib qw(.);
# Подключаем класс
use Sum;

# Создаём объект и сразу добавляем 3 числа
my $sum = Sum->new(10,20,30);

# выводим сумму чисел
print "Sum of numbers (" . $sum->toString() . ") is: " . $sum->getSum() . "\n";

# Добавим ещё пару чисел
$sum->addNumbers(40,10);

# Выводим общее кол-во имеющихся чисел
print "Total numbers: " . $sum->getColNumbers() . "\n";

# Выводим ещё раз сумму чисел
print "Sum of numbers (" . $sum->toString() . ") is: " . $sum->getSum() . "\n";

# Выводим среднее значение
print "Average of numbers (" . $sum->toString() .  ") is: " . $sum->getAverage() . "\n";

# Удалим все цифры
$sum->clearMemory();

# Проверим, что мы действительно всё очистили
print "Total numbers is: " . $sum->getColNumbers();

Ну и читай коментарии, там всё пояснено. Если чего-то не поймёшь, спрашивай.

Автор: DEER 16.11.2005, 13:33
Спасибо!
Я так понял, что внутри каждого метода мы получаем доступ к классу(его методам и всойствам) через shift. Так?
Тогда можно сделать так? то есть внутри класса вызывать его методы?
Код

# Метод возвращает сумму всех чисел    
sub getSum {    
    my $self = shift;    
    my $sum = 0;    
    foreach (@$self) {    
          $sum += $_;    
    }    
  return $sum;    
}
# Метод возвращает среднее значение всех чисел    
sub some_func {    
    my $self = shift;    
    self->getSum();
}

также можно объявить именованное свойство в конструкторе
Код

$self->{NAME}   = undef;

и тогда для этого свойства нужно описать функцию
Код

        sub name {
            my $self = shift;
            if (@_) { $self->{NAME} = shift }
            return $self->{NAME};
        }

Так?

Автор: korob2001 16.11.2005, 14:03
Ты почти всё верно понял, но shift всеголишь вытаскивает первый елемент массива и возвращает его.
Код

my @color = qw( red green blue );
my $color = shift @color;

Теперь переменная $color содержит строку "red", а массив @color содержит теперь 2 елемента "green" и "blue". Вобщем игра со стёком.

В нашем случае, мы не указываем имени массива из которого нужно извлекать первый елемент, если массив не указан и shift находится внутри подпрограммы, то будет извлечён первый елемент массива @_, если shift вне подпрограммы и не указан явно массив, то будет извлечён первый елемент массива @ARGV.

Т.е. когда ты вызываешь метод, первым параметром всегда является объект. Это легко проверить. Добавь такой метод в класс Sum.pm
Код

# Метод возвращает пакет в котором он находится
sub getInfo  {
       return shift;
}

Ну и конечно же вызови его из основной программы. Увидишь примерно такую строку:
Sum=ARRAY(0x2252f8)
где Sum имя пакета, а ARRAY(0x2252f8) ссылка на анонимный массив, в нашем случае в нём сохраняются члены класса. Мы его создаём в конструкторе.

Внутри класса можно обращаться к методам и напрямую, указав его имя, но всё же рекомендуется обращаться через обьект, потому мы сначала извлекаем объект с помощью shift, ну а затем через него обращаемся к методам. Кстати можно создавать закрытые методы, для этого нужно, что бы имя метода начиналось с символа _ :
Код

# Этот метод нельзя вызвать из вне, только внутри класса, это примерно то же, если бы
# мы в Java создали метод с доступом private
sub _closedMethod {
       return "Hello";
}

Можно так же реализовать закрытость ещё более надёжную, если заключить члены в блок (т.е. в фигурные скобки ) и объявить их как локальные, через my.

Автор: DEER 16.11.2005, 14:14
Угу почти понятно smile
Спасибо!

Автор: korob2001 16.11.2005, 14:25
Ну вообще-то ООП, тема довольно не маленькая, но очень затягивающая. Очень хорошо она описана в книге "Программирование на Perl" Ларри Уолл, Том Кристеасон, Джон Орвант. Она помоему есть в нашей библиотеке, посмотри. Ну а так же поищи через поисковик, здесь уже много раз поднимались подобные темы.

Автор: korob2001 16.11.2005, 15:30
Гость_Nick - главное спокойствие.

Отрываем "Perl - специальный справочник" Стивен Холзнер (страница 357) и читаем.

Создание приватных методов и данных

Хотя многие объектно-ориентированные языки программирования поддерживают приватные методы и переменные ( то есть внутренние методы и переменные, не достижимые вне класса или объекта ), Perl не позволяет делать этого явно.

Вы всегда можете использовать переменные с лексической областью видимости (ключевое слово my), что бы ограничить область видимости переменных текущим пакетом.

Что бы создать приватные переменные, надо воспользоваться следующим соглашением Perl: приватные имена начинаются с символа подчёркивания. В отличии от языков типа C++, Java или Delphi, это не значит, что вы не може получить доступ к приватным переменным и методам объекта. Идея состоит в том, что если имя начинается с символа подчёркивания, его не следует использовать, поскольку оно считается приватным. В следующем примере публичный ( открытый ) метод sum исплользует приватный ( закрытый ) метод _add для сложения двух велечин:
Код

package Class1;
sub new {
       my $type = {};
       $type->{OPERAND1} = 2;
       $type->{OPERAND2} = 2;
       bless( $self );
       return $self;
}

sub sum {
       my $self = shift;
       my $tem = _add( $self->{OPERAND1}, $self->{OPERAND2});
       return $temp;
}

sub _add { return shift() + shift(); }

return 1;

Вот результат использования метода sum:
Код

use Class1;
my $object1 = Class1->new();
print "Here is the sum: ", $object1->sum;

Собственно это я и имел ввиду.

Ну а так, можно создать истенно закрытый метод:
Код

my $closed = sub {
      # Тело метода
};


Или даже так, ещё больше закрытый:
Код

{
    my $closed = sub {
          # Тело метода
    };
     
    # Метод который будет использовать закрытый метод
    sub useClosed {
           my $self = shift;
           $self->$closed();
    }
}

Я так и не понял твоего сорказма, будь добр поясни.

Автор: Гость_Nick 16.11.2005, 16:17
А почему я своего сообщения не вижу?
И язык у меня не козлиный...
Я только после того как отправил сообщение увидел, что ты модератор smile
Вообще в конце того сообщения хотел извиниться, но передумал,
т.к. ну не перевариваю я когда люди толком не знают неких вещей а сообщают об этом как большие знатоки, ну сори... smile И вообще я сегодня злой какой-то... smile

А что касается закрытых методов, ты пишешь
Цитата
Кстати можно создавать закрытые методы, для этого нужно, что бы имя метода начиналось с символа _ :


Прочитай внимательнее ту цитату, которую приводишь в качестве контр аргумента:
Цитата

Хотя многие объектно-ориентированные языки программирования поддерживают приватные методы и переменные ( то есть внутренние методы и переменные, не достижимые вне класса или объекта ), Perl не позволяет делать этого явно.


Но по твоему выходит, что позволяет: ибо использование "_" для закрытия метода есть не что иное, как явное указание Perl'у на то что метод закрыт.

Цитата

Что бы создать приватные переменные, надо воспользоваться следующим соглашением Perl: приватные имена начинаются с символа подчёркивания.


Это просто соглашение и не более. Т.е. на самом деле метод не является закрытым.

Хочешь сделать закрытый метод, можно, например, так:
Код

package Foo;
my $private = sub { print "Hi,\t"; };
sub new
{
  my $prop = shift;
  return bless {}, ref $prop || $prop;
}

sub Public
{
  $private->();
  print " All!\n";
}
1;


Использование:
Код


use strict;
use foo;

my $f = new Foo();

$f->Public; # OK. Напечатает: Hi,             All!
$f->$Foo::private->(); # Can't locate object method "" via package "Foo"
$Foo::private->(); # Can't use string ("") as a subroutine ref while "strict refs" in use


Но опять же это не будет в полной мере приватный метод в понимании C++.
Т.к. С++ компилятор будет ругаться на неправильное использование методов на стадии компиляции, а Perl это все проглотит и будет ругаться только на стадии исполниния, что чревато.

Автор: korob2001 16.11.2005, 16:33
Гость_Nick - ты меня тоже извини, я тоже какой-то злой сегодня. Может погода влияет?
Вобщем каждый из нас обратил внимание на то, что ему хотелось. Я собственно назвал этот метод приватным потому что раздел в книге называется:
Создание приватных методов и данных, с другой стороны я так же сказал:
Цитата

Можно так же реализовать закрытость ещё более надёжную, если заключить члены в блок (т.е. в фигурные скобки ) и объявить их как локальные, через my.

Пример этого способа привёл постом выше.

Зы: ты случайно NICK не с perl.ru, я имею ввиду 2001 год?

Автор: Гость_Nick 16.11.2005, 16:48
Ну разобрались и ладно. smile

ЗЫ: Я не с perl.ru и вообще ниоткуда smile
ЗЗЫ: Я вообще очень редко бываю на каких-либо форумах, сегодня случайно забрел и не удержался от ответа. ;)

Автор: Kiber_rat 18.11.2005, 14:50
Может кому пригодится... Я тут читаю книжку "Perl best practices" by Damian Conway (есть у меня в виде html) там есть много полезного, в частности и по поводу ООП в perl. Так что рекомендую. Язык - родной англицкий smile

Автор: DEER 30.11.2005, 11:55
Господа, а нет тонкостей(или разностей) написания классов под windows\linux?

просто написал класс, отлаживал под винды, а сейчас пытаюсь запустить всё это дело под linux'ом, он говорит
Цитата
Can't locate object method "new" via package "Analisyst" at /var/www/vhosts/...../deer.cgi


соответственно deer.cgi и Analisyst.pm лежат в одной директории

smile

Автор: Kiber_rat 30.11.2005, 17:11
В *nix имеет значение регистр символов, т.е. Analisyst и analisyst - разные файлы, прежде всего проверь это smile

Автор: sharq 30.11.2005, 17:43
DEER а ты в deer.cgi указал
Код

use lib '.';
use Analisyst;


Проверь это!

smile

Автор: DEER 30.11.2005, 17:58
спасибо что ответили, с десятого раза всё заработало..... как то странно, но ничего в коде не менял....

sharq
нет не написал. так работает, причем ошибка только с этим модулем была.. там ещё мои модули есть, с ними было всё в порядке
А кстати если так написать, он будет видеть другие модули, которые не мои, которые лежат в /usr/perl/bin ??

Автор: sharq 30.11.2005, 18:25
DEER
Цитата(DEER @ 30.11.2005, 18:58)
А кстати если так написать, он будет видеть другие модули, которые не мои, которые лежат в /usr/perl/bin ??

Код

use lib '.';

означает, что модули будут искаться в текущей директории.
Хотя по умолчанию в массиве @INC , указана текущая директория, это пишется для уверенности. smile

Массив @INC содержит все пути к модулям, чтобы узнать какие именно, можешь сделать следующее:
Код

perl -e"print join \"\n\", @INC;"

И как видишь пути
Цитата
/usr/perl/bin
там нет, как ты думал smile

Чтобы добавить новый путь к данному массиву, можно написать
Код

use lib 'путь/к/модулям';

или
явно
Код

BEGIN {
 push @INC, 'путь/к/модулям';
}


smile

Автор: DEER 1.12.2005, 09:38
Спасибо

Автор: gcc 29.8.2008, 14:27
perl в режиме cgi/fcgi
есть код в который нужно вносить изменения и оптимизацию, класс должен заканчиваться на
Код

1;

если ошибка в коде, и если он заканчиваеться не верно, то вебсервер возвращает ошибку 500

use CGI::Carp qw(fatalsToBrowser); не помогает

вожно сделать чтобы он писать ошибку в браузер, а то очень не удобно ходит через ftp и смотреть smile  smile 

может mod_perl нужен, но ставить его не хочеться...

Автор: nitr 29.8.2008, 14:31
gcc, при чем тут эта тема? Что вы этим хотели сделать?

На первое время достаточно use CGI::Carp qw(fatalsToBrowser);
Или что-то свое сделать, хотя на спане есть готовые.

Автор: gcc 29.8.2008, 14:35
написал в .pm 
Код

use CGI::Carp qw(fatalsToBrowser); 

работает!

это было только в пусковом

Powered by Invision Power Board (http://www.invisionboard.com)
© Invision Power Services (http://www.invisionpower.com)