Форум программистов [Powered by Invision Power Board]

Код

program MaskStr;
procedure CreateMaskFile(strSrcFileName,strResFileName,strMask:string);
{Процедура берет слова из файла с именем strSrcFileName, сравнивает каждое слово с маской и если слово удовлетворяет маске то записывает его в файл с именем strResFileName.
Примечание:
если символ маски не входит в константу UsedSymbols, то он считается символом любого символа, также любой символ не входящий в UsedSymbols считается разделителем в файле.
}
const
  UsedSymbols=['0'..'9'];{список нужных символов}
var
  bolResult:boolean;{флаг}
  ch:char;{считываемый символ}
  i,len:integer;{i-счетчик, len-длина строки}
  strTemp:string;{считываемое слово}
  FIn,FOut:textfile;{FIn-входной файл, FOut-выходной}
begin
  AssignFile(FIn,strSrcFileName);{связывание переменной}
  AssignFile(FOut,strResFileName);{связывание переменной}
  reset(FIn);{открытие для чтения}
  rewrite(FOut);{открытие для перезаписи}
  while not eof(FIn) do{пока не конец файла}
  begin
    strTemp:='';{инициализация}
    read(FIn,ch);{чтение символа}
    while not(eof(FIn) or (ch in UsedSymbols)) do {пока символа ch нет в списке нужных}
      read(FIn,ch);{чтение след. символа}
    while not eof(FIn) and (ch in UsedSymbols) do{пока символ нам подходит}
    begin
      strTemp:=strTemp+ch;{добавляем символ}
      read(FIn,ch);{читаем следующий}
    end;
    len:=Length(strTemp);{узнаем длину считанного слова}
    if len=Length(strMask) then{если длина слова совпадает с длиной файла}
    begin
      bolResult:=true;{инициализация}
      i:=1;{инициализация счетчика}
      while (i<=len) and bolResult do{перебираем все символы слова}
      begin
        if strMask[i] in UsedSymbols then{если символ в UsedSymbols, то смотрим символ маски}
          bolResult:=strMask[i]=strTemp[i];
        inc(i);
      end;
    {выход из цикла произошел при i>len либо при bolResult=false}
      if (i>len) and bolResult then writeln(FOut,strTemp);{проверили все символы и не нашли ошибок}
    end;
  end;
  CloseFile(FOut);{закрытие файла}
  CloseFile(FIn);{закрытие файла}
end;
var
  strSrcFileName,strResFileName,strMask:string;
begin
  writeln('Please enter source file name:');
  readln(strSrcFileName);
  writeln('Please enter result file name:');
  readln(strResFileName);
  writeln('Please enter a mask:');
  readln(strMask);
  CreateMaskFile(strSrcFileName,strResFileName,strMask);
  writeln('ok');
  readln;
end.