Форум программистов [Powered by Invision Power Board]

Код

use16
org 100h
jmp start

fname    db  '1.bmp',0        ; картинка
width    dw  ?                ; её ширина
heigh    dw  ?                ;    ..и высота.
buff     dw  2000h dup(0)     ; буфер для хранения картинки
wcoun    db  0                ; счётчик столбцов
hcoun    db  0                ; счётчик строк

start:
   mov   al,12h
   int   10h                  ; ставим EGA 640x480x16

;--- читаем картинку в буфер --------------------------//
   mov   ax,3d00h             ; открыть файл!
   mov   dx,fname
   int   21h
   push  ax                   ; сохраняем хэндл файла

   mov   bx,ax                ; отправляем его в BX (для чтения)
   mov   ah,3Fh               ; читать файл!
   mov   dx,buff              ; куда..,
   mov   cx,2000h             ;   и сколько
   int   21h                  ; файл в буфере!

   pop   ax                   ; закрыть файл!
   mov   bx,ax
   mov   ah,3Eh
   int   21h

;--- сохраняем инфу о картинке в переменных -----------//
   mov   ax,word[buff+12h]    ; ширина
   mov   [width],ax
   mov   ax,word[buff+16h]    ; высота
   mov   [heigh],ax

;--- выводим её на экран ------------------------------//
   xor   bx,bx                ; страница(0)
   mov   dx,70                ; начальная позиция строки
   mov   cx,10                ;    ..и столбца.
   mov   si,36h               ; пропускаем заголовок в BMP
next:
   call  bitmap               ; зовём (fn) конвертирования 
   mov   ah,0Ch               ; функция вывода точки на экран
   int   10h
   inc   cx                   ; следующая точка в строке
   inc   byte[wcoun]          ; увеличим счётчик столбцов
   cmp   [wcoun],64           ; все столбцы вывели? (ширина картинки)
   jnz   next                 ; если нет - мотаем цикл.

   dec   dx                   ; одну строку вывели! перемещаемся выше
   mov   cx,10                ; сброс позиции столбца
   mov   [wcoun],0            ;    ..и счётчика столбцов 
   inc   byte[hcoun]          ; увеличим счётчик строк
   cmp   [hcoun],64           ; все строки вывели? (высота картинки)
   jnz   next                 ; если нет - мотаем цикл.

exit:
   xor   ax,ax
   int   16h
   mov   ax,4C00h             ; на выход!
   int   21h

;--- главная процедура ------------------------------------------//
; конвертирует - 24-разрядный BMP в 4-битную палитру.
; результат сохраняется в регистре al.
bitmap:
   xor   al,al                ; здесь будет результат  
   mov   ah,byte[buff+si]     ; берём цвет(B). читаем сколько синего
   shr   ah,7                 ; сдвигаем вправо на 7 разрядов
   and   ah,0001b             ; бит(0) маски отвечает за синий цвет
   or    al,ah                ; если имеется, то выставляем в маске синий

   inc   si                   ; берём цвет(G) (в BMP цвета идут BGR)
   mov   ah,byte[buff+si]     ; тоже/самое, только со сдвигом на 1 левее
   shr   ah,6                 ; сдвигаем вправо на 6 разрядов
   and   ah,0010b             ; бит(1) маски - зелёный цвет
   or    al,ah                ; выставляем зеленый

   inc   si                   ; берём цвет(R). читаем кол-во красного
   mov   ah,byte[buff+si]     ; всё/тоже,
   shr   ah,5                 ;   ..только со-сдвигом вправо на 5
   and   ah,0100b             ; бит(2) маски - красный
   or    al,ah                ; имеется? выставляем красный
   inc   si
   or    al,1000b             ; бит(3) маски - интенсивность.
ret