Форум программистов [Powered by Invision Power Board]

Код

    org    80h
CmdLineLength:
    org    $+1
CmdLine:
    org    256
    mov    al,byte [CmdLineLength]
    cmp    al,1
    jbe    CmdLineEmpty
GetCmdLoop:
    mov    al,20h
    mov    cx,80h
    mov    di,CmdLine
    repe    scasb
    je    CmdLineEmpty
    dec    di
    cmp    byte [di],0dh
    je    CmdLineEmpty
    mov    dx,di
    mov    al,0dh
    repne    scasb
    jne    CmdLineEmpty
    dec    di
    mov    byte [di],0
    jmp    OpenFile
CmdLineEmpty:
    mov    ah,9
    mov    dx,PromptStr
    int    21h
    mov    ah,0ah
    mov    dx,FileNameStr
    mov    si,dx
    inc    si
    int    21h
    mov    ah,9
    mov    dx,CrLf
    int    21h
    mov    bl,byte [si]
    test    bl,bl
    jz    FileReadError
    mov    bh,0
    inc    si
    cmp    byte [bx+si],0dh
    jne    FileReadError
    mov    byte [bx+si],0
    mov    dx,FileName
OpenFile:
    mov    ax,3d00h
    int    21h
    jc    FileReadError
    mov    bx,ax
    mov    word [FileHandler],ax
    mov    ah,3fh
    mov    cx,24h
    mov    dx,FileBuffer
    mov    si,dx
    int    21h
    jc    FileReadError
    cmp    dword [si],"RIFF"
    jne    FormatError
    cmp    dword [si+8],"WAVE"
    jne    FormatError
    cmp    dword [si+0ch],"fmt "
    jne    FormatError
    cmp    word [si+14h],1
    jne    FormatError
    mov    edi,dword [si+18h]
    mov    cx,word [si+22h]
    cmp    cx,8
    jne    Is16Bit
    dec    byte [Instruction0ToMod]
    dec    byte [Instruction1ToMod]
    jmp    DoneSelfModifying
Is16Bit:
    cmp    cx,16
    jne    FormatError
DoneSelfModifying:
    mov    ax,word [si+20h]
    mov    word [BXIncrement],ax
    mov    ah,3fh
    mov    dx,FileBuffer
    mov    cx,8
    int    21h
    jc    FileReadError
    cmp    dword [si],"data"
    je    ParsingEnded
    mov    dx,word [si+4]
    mov    cx,word [si+6]
ReReadFile:
    mov    ax,4201h
    int    21h
    jc    FormatError
    mov    ah,3fh
    mov    cx,8
    mov    dx,FileBuffer
    int    21h
    jc    FileReadError
    cmp    dword [si],"data"
    je    ParsingEnded
    mov    dx,word [si+4]
    mov    cx,word [si+6]
    jmp    ReReadFile
ParsingEnded:
    push    0
    pop    ds
    mov    eax,dword [8*4]
    mov    word [8*4],IRQ0Handler
    mov    word [8*4+2],cs
    mov    ds,word [8*4+2]
    mov    dword [OldHandler],eax
LP:
    cmp    byte [Flag],1
    jne    LP
    mov    eax,dword [Freq]
    mov    edx,dword [Freq+4]
    mov    ecx,596590
    mov    ebx,32768
    mul    ecx
    div    ebx
    xor    edx,edx
    div    edi
    mov    ebp,eax
    mov    ah,9
    mov    dx,TipStr
    int    21h
    jmp    NewPart
MainLoop:
    mov    al,byte [temp]
    out    61h,al
EnterMainLoop:
    rdtsc
    mov    esi,eax
    mov    edi,edx
Instruction0ToMod:
    mov    dx,word [bx] ;8bh -> 8ah = word -> byte
    cmp    bx,cx
    ja    NewPart
    add    bx,word [BXIncrement]
    in    al,61h
    or    al,2
Instruction1ToMod:
    test    dx,dx ;85h -> 84h = word -> byte
    sets    ah
    add    ah,ah
    or    al,ah
    sub    ah,3
    and    al,ah
    mov    byte [temp],al
    mov    ah,1
    int    16h
    jnz    OutOfMainLoop
LP0:
    rdtsc
    sub    eax,esi
    sbb    edx,edi
    test    edx,edx
    jnz    MainLoop
    cmp    eax,ebp
    jb    LP0
    jmp    MainLoop
OutOfMainLoop:
    mov    ah,0
    int    16h
    retn
NewPart:
    mov    ah,3fh
    mov    bx,word [FileHandler]
    mov    cx,7ffch
    mov    dx,FileBuffer
    int    21h
    jc    FileReadError
    test    ax,ax
    jz    Exit
    mov    cx,ax
    add    cx,FileBuffer
    mov    bx,FileBuffer
    jmp    EnterMainLoop
FileReadError:
    mov    dx,FileReadErrorMessage
    jmp    CommonError
FormatError:
    mov    dx,FormatErrorMessage
CommonError:
    mov    ah,9
    push    cs
    pop    ds
    int    21h
Exit:
    retn
IRQ0Handler:
    pushad
    rdtsc
    push    ds
    push    cs
    pop    ds
    cmp    byte [Flag],0ffh
    jne    NotFF
    mov    byte [Flag],0
    jmp    IntRet
NotFF:
    sub    eax,dword [Freq]
    sbb    edx,dword [Freq+4]
    mov    byte [Flag],1
    mov    ecx,[OldHandler]
    push    0
    pop    ds
    mov    dword [8*4],ecx
IntRet:
    mov    dword [cs:Freq],eax
    mov    dword [cs:Freq+4],edx
    pop    ds
    mov    al,20h
    out    20h,al
    popad
    iret
FileReadErrorMessage:
    db    "Error reading file",13,10,24h
FormatErrorMessage:
    db    "Error parsing file"
CrLf:
    db    0dh,0ah,24h
PromptStr:
    db    "Enter file name (PCM WAV format)",13,10,24h
TipStr:
    db    "Press any key to stop playback & quit",13,10,24h
Flag:
    db    0ffh
FileNameStr:
    dw    254
FileName:
    org    $+255
temp:
    org    $+1
BXIncrement:
    org    $+2
Freq:
    org    $+8
OldHandler:
    org    $+4
FileHandler:
    org    $+2
FileBuffer: