Форум программистов [Powered by Invision Power Board]

Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате

Форум программистов > Delphi: Общие вопросы > передача массива в процедуру DLL

Автор: fantomba 2.5.2010, 19:57

использую Delphi7.
проблема с передачей массива в основную программу. Ошибка Access violation at address 00000.... Read of address 000...
собственно код основной программы:

Код


type
nw=array [0..100] of integer;
nameprocedure=procedure(Handle:Thandle; ci:integer;  nomerq:nw);stdcall;

...................


procedure TMainform.SpeedButton1Click(Sender: TObject);
var
p1,i:integer;
sa2:nameprocedure;
DLLHandle:Thandle;
nomera:nw;
begin

  DLLHandle:=LoadLibrary('namedll.dll');
  @sa2:=GetProcAddress(DllHandle,'nameprocedure');
  p1:=dbgrid2.DataSource.DataSet.RecordCount;
  dbgrid2.DataSource.DataSet.First;
  for i:=0 to p1 do 
begin
  nomera[i]:=strtoint(dbgrid2.DataSource.DataSet.fieldbyname('CODE').AsString);
  dbgrid2.DataSource.DataSet.Next;
  end;
sa2(handle,p1,nomera);

код библиотеки:

Код


type
mass=array [0..100] of integer;
  Taizegrof = class(TForm)
 ............................
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  aizegrof: Taizegrof;
procedure nameprocedure (handle:Thandle; k:integer; ncod:mass);export;stdcall;
implementation

{$R *.dfm}
procedure nameprocedure (handle:Thandle; k:integer; ncod:mass);
.......

использую sharemem.
В основной программе делаю отладку по точкам. ошибка вылетает именно при вызове процедуры из библиотеки и передачи в неё параметров.

Сижу второй день. Подскажите PLEASE!!!!

Автор: Crw 3.5.2010, 18:39

Попробуй использовать безразмерный массив типа array of integer (или просто указатель на integer) + еще один параметр для размера массива.

Автор: Демо 3.5.2010, 19:15

Код


unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TIntArray=array[0..100] of Integer;

  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  TSum=function(Arr: TIntArray; CountElement: Integer): Integer; stdcall;

var
  Form1: TForm1;
  Sum: TSum;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  H: THandle;
  A: TIntArray;
  i: Integer;
begin
  for i := 0 to 10 do A[i] := i*100+1;
  H := LoadLibrary('Project2.dll');
  if H=0 then Exit;
  try
    @Sum := GetProcAddress(H,'Sum');
    if Assigned(Sum) then ShowMessage(IntToStr(Sum(A,11)));
  finally
    FreeLibrary(H);
  end;
end;

end.

Код


library Project2;
uses
  SysUtils,
  Classes;

type
  TIntArray=array[0..100] of Integer;

function Sum(Arr: TIntArray; CountElement: Integer): Integer; stdcall;
var
  i: Integer;
begin
  Result := 0;
  for i := 0 to CountElement-1 do Inc(Result,Arr[i]);
end;

exports
  Sum;
end.

Добавлено @ 19:22
А теперь сравни с тем, что у тебя есть.

1.

Код


DLLHandle:=LoadLibrary('namedll.dll');
  @sa2:=GetProcAddress(DllHandle,'nameprocedure');

Нет ни одной проверки.

2. Из DLL не экспортировано ни одной функции.

Добавлено @ 19:28
PS.

Ключевое слово export в функции не используется в 32-битных приложениях.

Для экспорта функция должна быть секция exports.

Автор: fantomba 7.5.2010, 21:11

Демо, СПАСИБО ЗА ПОДСКАЗКУ! Сел еще раз и просмотрел код. Вывод ошибка в названии процедуры...
Тема закрыта. Но для тех у кого подобные трудности возникнут, не ленитесь лишний раз прописать проверку! Спасибо за внимание!

Добавлено через 3 минуты и 1 секунду
вопрос решён