Форум программистов [Powered by Invision Power Board]

Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате

Форум программистов > Delphi: Общие вопросы > Свой компонент, база TMemo: проблемы в деструкторе

Автор: VinniPuhh 7.9.2011, 18:13

Столкнулся с интересным поведением своего компонента, сделанного на основе TMemo.
Для иллюстрации вопроса создал отдельный компонент с минимумом кода, вот такой

Код


unit MyMemo;

interface

uses
  SysUtils, Classes, Controls, StdCtrls, Forms;

type
  TMyMemo = class(TMemo)
  private
  protected
  public
    destructor Destroy; override;
  published
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Samples', [TMyMemo]);
end;

destructor TMyMemo.Destroy;
var
  x: String;
begin
  x := Lines.GetText;
  Application.MessageBox(PChar(x), 'Test');
  inherited;
end;

end.

Так вот, если сделать кнопку, по нажатию на которую удалять компонент - все работает как и ожидается. В сообщении выводится содержимое MyMemo.
А если закрывать приложение, то содержимое x всегда оказывается пустым, что бы не было написано в MyMemo.
Расскажите пожалуйста кто знает, с чем это связано, очевидно я недостаточно хорошо понимаю как удаляются формы и компоненты.
Как избежать такого эффекта? Мне например надо чтобы по закрытию мой компонент автосохранял содержимое :(

Автор: VinniPuhh 8.9.2011, 12:05

Значится так.
Проблема решена, и была она как мне кажется весьма хитрой smile

Идея в том, что (в отличие например от TStringGrid) содержимое окна TMemo - это стандартный зарегистрированный в системе класс текстового редактора.
Компонент TMemo (ну если быть точным, его предок TCustomMemo) обменивается с ним сообщениями, создавая для пользователя компонента иллюзию, что мы доступаемся к конкретной переменной (например содержимому строк редактора).
Так вот, при уничтожении формы хэндл этого окна уже оказывается удален или сам экземпляр виндовс-класса в состоянии удаления (не разобрался что именно, ну оно и не важно), и сообщения-запросы от TCustomMemo к содержимому не работают.
Вопрос осложняется еще тем, что может быть подменен стандартный текстовый редактор системы (Notepad++, AkelPad и так далее), и поведение экземпляра такого класса может несколько разнится.

Вопрос решается перегрузкой функции обработки сообщения WM_NCDESTROY, которая есть у TCustomMemo и похоже вообще предназначенна именно для таких случаев.
То есть решением моего вопроса будет следующий код:

Код


unit MyMemo;

interface

uses
  SysUtils, Classes, Controls, StdCtrls, Forms, Messages;

type
  TMyMemo = class(TMemo)
  private
  protected
  public
    procedure WMNCDestroy(var Message: TWMNCDestroy); message WM_NCDESTROY;
  published
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Samples', [TMyMemo]);
end;

procedure TMyMemo.WMNCDestroy(var Message: TWMNCDestroy);
var
  x: String;
begin
  x := Lines.Text; // Вот здесь значение x всегда верно!
  inherited;
end;

end.

Я рад, если мои пол дня рабирательств с этим помогут кому-нибудь в дальнейшем.

Автор: bems 11.9.2011, 14:41

Цитата(VinniPuhh @ 8.9.2011, 12:05

)

Вопрос осложняется еще тем, что может быть подменен стандартный текстовый редактор системы (Notepad++, AkelPad и так далее)

ненене. Это не влияет на системный multiline edit control