Форум программистов [Powered by Invision Power Board]

Код

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type

  TTimeThread =  class(TThread)
  protected
    procedure Execute; override;
    procedure UpdateTime;

  end;


  TForm1 = class(TForm)
    Panel1: TPanel;
    Panel2: TPanel;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
    CanContinue : boolean;
    TimeThread : TTimeThread;
    
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//Заморозка
procedure TForm1.Button1Click(Sender: TObject);
var
  k : Integer;

begin
  Button1.Enabled := false;
  Button2.Enabled := false;
  Button3.Enabled := false;
  Button4.Enabled := false;

  TimeThread := nil;

  for k := 0 to 9999999 do
  begin
    //Конечно, Caption обновится только после выхода из цикла
    Panel1.Caption := DateTimeToStr(Now);
  end;

  Button1.Enabled := true;
  Button2.Enabled := true;
  Button3.Enabled := true;
  Button4.Enabled := true;
end;

//ProcessMessages
procedure TForm1.Button2Click(Sender: TObject);
begin
  Button1.Enabled := false;
  Button2.Enabled := false;
  Button3.Enabled := false;

  TimeThread := nil;

  CanContinue := true;

  while CanContinue do 
  begin
    Panel1.Caption := DateTimeToStr(Now);
    Application.ProcessMessages;
  end;

  Button1.Enabled := true;
  Button2.Enabled := true;
  Button3.Enabled := true;
end;

//Поток
procedure TForm1.Button3Click(Sender: TObject);
begin
  Button1.Enabled := false;
  Button2.Enabled := false;
  Button3.Enabled := false;

  TimeThread := TTimeThread.Create(true);
  TimeThread.FreeOnTerminate := true;
  TimeThread.Resume;
end;

procedure TForm1.Button4Click(Sender: TObject);
begin
  CanContinue := false;

  if (TimeThread <> nil) then
  begin
    TimeThread.Terminate;
    TimeThread := nil;

    Button1.Enabled := true;
    Button2.Enabled := true;
    Button3.Enabled := true;
  end;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  if (TimeThread <> nil) then
  begin
    TimeThread.Terminate;
  end;
end;

procedure TTimeThread.Execute;
begin
  while not Terminated do 
  begin
    Synchronize(UpdateTime);
  end;
end;

procedure TTimeThread.UpdateTime;
begin
  Form1.Panel1.Caption := DateTimeToStr(Now);
end;

end.