Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате
Форум программистов > Delphi: Общие вопросы > Цвет различного Отбора в TMENU


Автор: Deiv 11.2.2006, 17:05
Привет,
Я участвую впервые в Форуме и Я не хорошо разговариваю Русский язык, Я начинающий в Delphi. У меня вопрос:
Как я могу создать градиент 3 цветов СВЕРХУ ДОНИЗУ выбирая (двигаясь Мышь) пункт TMenu? (Fixed ряд), Это возможнo в Delphi?.
Взгляд, У меня код что это выполняет градиент 2 цветов из оставленной стороны направо (см ниже), но я нуждаюсь в том, чтобы показать градиент 3 цветов и что это идет из ПРЕВОСХОДЯЩЕГО сектора (область) к НИЗШАЯ (сверху донизу), это Я посмотрел в Menu Программа Super Utilities (http://www.superlogix.net/):
Код

procedure TForm1.MenuItemDrawItem(Sender: TObject; ACanvas: TCanvas; ARect: TRect; Selected: Boolean);
var
  Item: TMenuItem;
  Flags: Integer;

begin
  if Selected then
    GradientRect(
      ACanvas.Handle,
      ARect,
      GetSysColor(COLOR_ACTIVECAPTION),
      GetSysColor(COLOR_GRADIENTACTIVECAPTION)
    )
  else
    ACanvas.FillRect(ARect);

  Item := Sender as TMenuItem;
  Flags := DT_SINGLELINE or DT_VCENTER;
  Inc(ARect.Left, 6);

  ACanvas.Brush.Style := bsClear;
  DrawText(ACanvas.Handle, PChar(Item.Caption), Length(Item.Caption), ARect, Flags);
end;

Спасибо

Автор: Yanis 11.2.2006, 17:13
Какой ужас smile Тоже самое получилось бы если я перевёл XTranslyator'ом свой вопрос и запостил его на забугорном форуме smile
Добавлено @ 17:16
Цитата(Deiv @ 11.2.2006, 17:05 Найти цитируемый пост)
это Я посмотрел в Menu Программа Super Utilities

Я в приципе понял, что имелось ввиду, но не все знаю программу Super Utilities. Короче, ScreenShot в студию!

Автор: Snowy 12.2.2006, 13:17
Вот. Нарисовал код, который делает градиентные пункты меню.
Можно делать любое количество градиентов.
Вот, например 4 цвета:
Код
procedure MultiGradientRect(Canvas: TCanvas; Rect:TRect; const col: array of TColor); // рисует градиент
var
  i, cl, dy, gk: integer;
  cy1, cy2, ci:  integer;
begin
  gk := Length(col)-1; dy := Rect.Bottom - Rect.Top;
  for i := Rect.Top to Rect.Bottom-1 do
  begin
    ci := (i-Rect.Top) * gk div dy;
    cy1 := ci * dy div gk;
    cy2 := (ci+1) * dy div gk - cy1;
    cl := (i - Rect.Top - cy1);
    cl := RGB((((cy2-cl)*GetRValue(col[ci]) + cl*GetRValue(col[ci+1])) div cy2),
              (((cy2-cl)*GetGValue(col[ci]) + cl*GetGValue(col[ci+1])) div cy2),
              (((cy2-cl)*GetBValue(col[ci]) + cl*GetBValue(col[ci+1])) div cy2));
    Canvas.Pen.Color := cl;
    Canvas.PenPos := Point(Rect.Left, i);
    Canvas.LineTo(Rect.Right, i);
  end;
end;

procedure TForm1.MenuItemDrawItem(Sender: TObject; ACanvas: TCanvas; ARect: TRect; Selected: Boolean);
begin
  if Selected then
    MultiGradientRect(ACanvas, ARect, [clRed, clYellow, clLime, clBlue]) // в [] - цвета. кол-во любое
  else
    ACanvas.FillRect(ARect);
  Inc(ARect.Left, 6);
  ACanvas.Brush.Style := bsClear;
  ACanvas.Font.Color := clBlack; // цвет текста
  ACanvas.TextOut(ARect.Left,ARect.Top,TMenuItem(Sender).Caption);
end;
Естественно, чтобы все это работало, нужно у меню выставить OwnerDraw в true и всем пунктам меню назначить OnDrawItem = MenuItemDrawItem

Powered by Invision Power Board (http://www.invisionboard.com)
© Invision Power Services (http://www.invisionpower.com)