Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате
Форум программистов > Delphi: WinAPI и системное программирование > определение активного окна приложения


Автор: Fedia 6.9.2006, 07:23
Получаю структуру PROCESSENTRY32, относящуюся с запущенному приложению с определенным именем:
Код

function GetProcessID(const AProcessName: string): PROCESSENTRY32;
var    
  lSnapHandle: THandle;
  lProcStruct: PROCESSENTRY32;
  lProcessName, lSnapProcessName: string;    
  lOSVerInfo: TOSVersionInfo;
begin    
  Result.th32ProcessID := INVALID_HANDLE_VALUE;
  lSnapHandle := CreateToolhelp32Snapshot(TH32CS_SNAPALL, 0);
  if lSnapHandle = INVALID_HANDLE_VALUE then    
    Exit;
  lProcStruct.dwSize := SizeOf(PROCESSENTRY32);
  lOSVerInfo.dwOSVersionInfoSize := SizeOf(TOSVersionInfo);
  GetVersionEx(lOSVerInfo);    
  case lOSVerInfo.dwPlatformId of
    VER_PLATFORM_WIN32_WINDOWS: lProcessName := AProcessName;
    VER_PLATFORM_WIN32_NT: lProcessName := ExtractFileName(AProcessName);    
  end;    
  if Process32First(lSnapHandle, lProcStruct) then
  begin    
    try    
      repeat
        lSnapProcessName := lProcStruct.szExeFile;    
        if AnsiUpperCase(lSnapProcessName) = AnsiUpperCase(lProcessName) then
        begin
          Result := lProcStruct;
          Break;    
        end;
      until not Process32Next(lSnapHandle, lProcStruct);    
    finally
      CloseHandle(lSnapHandle);    
    end;
  end;
end;

var
  PID: PROCESSENTRY32;
begin
  PID:=GetProcessID('test.exe');
  //.....

Необходимо по данным переменной PID найти активное окно приложения, информацию по которому эта переменная содержит.

Пробовал через:
Код

EnumThreadWindows(PID.th32ModuleID, @EnumProc, 0);
, но раз EnumThreadWindows перечисляет не дочерние окна, то почему я получаю такой объемный список хендлов окон по приложению 'test.exe', содержащему только одну форму ? Скорее всего я не прав в том, что передаю PID.th32ModuleID в функцию EnumThreadWindows. Но что тогда нужно в нее передавать в качестве параметра, если я располагаю только данными, содержащимися в переменной PID.

И еще вопрос: из перечня хендлов окон, которое передает функция EnumThreadWindows, как мне найти активное окно приложения ?

Автор: Rennigth 6.9.2006, 08:56
ничего поутру (с похмелья smile ) более умного в голову не пришло:
Код

function GetProcessID(const AProcessName: string): DWord;
var
  lSnapHandle: THandle;
  lProcStruct: PROCESSENTRY32;
  lProcessName, lSnapProcessName: string;
  lOSVerInfo: TOSVersionInfo;
begin
  Result := INVALID_HANDLE_VALUE;
  lSnapHandle := CreateToolhelp32Snapshot(TH32CS_SNAPALL, 0);
  if lSnapHandle = INVALID_HANDLE_VALUE then
    Exit;

  lProcStruct.dwSize := SizeOf(PROCESSENTRY32);

  lOSVerInfo.dwOSVersionInfoSize := SizeOf(TOSVersionInfo);
  GetVersionEx(lOSVerInfo);
  case lOSVerInfo.dwPlatformId of
    VER_PLATFORM_WIN32_WINDOWS: lProcessName := AProcessName;
    VER_PLATFORM_WIN32_NT: lProcessName := ExtractFileName(AProcessName);
  end;

  if Process32First(lSnapHandle, lProcStruct) then
  begin
    try
      repeat
        lSnapProcessName := lProcStruct.szExeFile;
        if AnsiUpperCase(lSnapProcessName) = AnsiUpperCase(lProcessName) then
        begin
          Result := lProcStruct.th32ProcessID;
          Break;
        end;
      until not Process32Next(lSnapHandle, lProcStruct);
    finally
      CloseHandle(lSnapHandle);
    end;
  end;
end;

function GetThreadsOfProcess(APID: Cardinal): TIntegerDynArray;
var
 lSnap: DWord;
 lThread: TThreadEntry32;
begin
  Result := nil;
  if APID <> INVALID_HANDLE_VALUE then
  begin
    lSnap := CreateToolhelp32Snapshot(TH32CS_SNAPTHREAD, 0);
    if (lSnap <> INVALID_HANDLE_VALUE) then
    begin
      lThread.dwSize := SizeOf(TThreadEntry32);
      if Thread32First(lSnap, lThread) then
      repeat
        if lThread.th32OwnerProcessID = APID then
        begin
          SetLength(Result, Length(Result) + 1);
          Result[High(Result)] := lThread.th32ThreadID;
        end;
      until not Thread32Next(lSnap, lThread);
      CloseHandle(lSnap);
    end;
  end;
end;



Код

procedure EnumThreadWndProc(hWindow: THandle; lParam: Integer); stdcall;
begin
  ShowMessage(IntToStr(hWindow));
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  lPID: Cardinal;
  lThreads: TIntegerDynArray;
  i: Integer;
begin
  lPID := GetProcessID('SearchHelp.exe');
  lThreads := GetThreadsOfProcess(lPID);
  for i := Low(lThreads) to High(lThreads) do
    EnumThreadWindows(lThreads[i], @EnumThreadWndProc, 0);
end;



по хендлам окон уже думаю определишь какое активно...

Автор: Fedia 6.9.2006, 09:33
Цитата(Rennigth @  6.9.2006,  08:56 Найти цитируемый пост)
ничего поутру (с похмелья  ) более умного в голову не пришло:

Мне интересно, что тебе в голову приходит, когда ты не с похмелья smile Не знаю, оптимален этот вариант или нет, но он работает ! Большое спасибо ! +
Цитата(Rennigth @  6.9.2006,  08:56 Найти цитируемый пост)
по хендлам окон уже думаю определишь какое активно...

Сегодня у меня с этим тоже были проблемы. 
Цитата(Fedia @  6.9.2006,  07:23 Найти цитируемый пост)
И еще вопрос: из перечня хендлов окон, которое передает функция EnumThreadWindows, как мне найти активное окно приложения ?

Возможно, завтра, на свежую голову, получиться реализовать.

Автор: gonzales 7.9.2006, 15:37
Цитата(Fedia @  6.9.2006,  09:33 Найти цитируемый пост)
Сегодня у меня с этим тоже были проблемы. 


не нашлось ли решение данной задачи, меня оно тоже интересует

Автор: Fedia 8.9.2006, 08:55
Цитата(gonzales @  7.9.2006,  15:37 Найти цитируемый пост)
не нашлось ли решение данной задачи, меня оно тоже интересует

Решил задачу "в лоб", перебором всех окон в порядке Z последовательности:
Код

function GetActiveWindows(ArApWin: TCardinalDynArray): HWND;
var
  i, n, m: Integer;
  NextW: HWND;
  NumZW: TIntegerDynArray;

  procedure CheckArApWin;
  var
    WL, i: Integer;
  begin
    for i:=0 to High(ArApWin) do
    if ArApWin[i] = NextW then
    begin
      WL:=GetWindowLong(HWin[i], GWL_STYLE);
      if WL and WS_VISIBLE = WS_VISIBLE then
      begin
        Inc(m);
        NumZW[i]:=m;
      end;
      Break;
    end;
  end;
begin
  Result:=0;
  if Length(ArApWin) = 0 then
  Exit;
  m:=0;
  SetLength(NumZW, Length(ArApWin));
  NextW:=GetWindow(ArApWin[0], GW_HWNDLAST);
  CheckArApWin;

  repeat
    NextW:=GetNextWindow(NextW, GW_HWNDPREV);
    if NextW<>0 then
    CheckArApWin;
  until NextW=0;

  i:=-1; m:=-1;
  for n:=0 to High(NumZW) do
  if (NumZW[n]>i) and (NumZW[n]>0) then
  begin
    i:=NumZW[n];
    m:=n;
  end;
  if m>-1 then
  Result:=ArApWin[m];

  NumZW:=nil;
end;

Если кто-то найдет способ попроще (думаю что он должен быть), то очень интересно на этот способ будет посмотреть.
gonzales, передаем в функцию массив не дочерних окон приложения и в качестве результата получаем самое верхнее из их числа.

Автор: gonzales 8.9.2006, 09:40
Цитата

передаем в функцию массив не дочерних окон приложения и в качестве результата получаем самое верхнее из их числа


а если оно в данный момент свернуто?

Автор: Fedia 8.9.2006, 11:15
Цитата(gonzales @  8.9.2006,  09:40 Найти цитируемый пост)
а если оно в данный момент свернуто?

Можно попробовать так:
Код

function GetActiveWindows(ArApWin: TCardinalDynArray): HWND;
var
  i, n, m: Integer;
  NextW: HWND;
  NumZW: TIntegerDynArray;

  procedure CheckArApWin;
  var    
    WL, i: Integer;
    WP: PWINDOWPLACEMENT;
  begin    
    for i:=0 to High(ArApWin) do
    if ArApWin[i] = NextW then
    begin
      New(WP);
      GetWindowPlacement(ArApWin[i], WP);
      if WP.showCmd and SW_SHOWNORMAL = SW_SHOWNORMAL then
      begin
        Inc(m);
        NumZW[i]:=m;
      end;
      Dispose(WP);
      Break;    
    end;    
  end;
begin
  Result:=0;    
  if Length(ArApWin) = 0 then
  Exit;
  m:=0;    
  SetLength(NumZW, Length(ArApWin));    
  NextW:=GetWindow(ArApWin[0], GW_HWNDLAST);
  CheckArApWin;
  repeat
    NextW:=GetNextWindow(NextW, GW_HWNDPREV);
    if NextW<>0 then    
    CheckArApWin;    
  until NextW=0;    
  i:=-1; m:=-1;    
  for n:=0 to High(NumZW) do    
  if (NumZW[n]>i) and (NumZW[n]>0) then    
  begin    
    i:=NumZW[n];    
    m:=n;    
  end;    
  if m>-1 then    
  Result:=ArApWin[m];    
  NumZW:=nil;    
end;

Автор: Fedia 8.9.2006, 11:32
А лучше наверное проверять и видимость и WindowsState одновременно:
Код

function GetActiveWindows(ArApWin: TCardinalDynArray): HWND;
//....
  procedure CheckArApWin;
  var    
    WL, i: Integer;
    WP: PWINDOWPLACEMENT;
  begin    
    for i:=0 to High(ArApWin) do
    if ArApWin[i] = NextW then
    begin
      WL:=GetWindowLong(ArApWin[i], GWL_STYLE);
      New(WP);
      GetWindowPlacement(ArApWin[i], WP);
      if (WP.showCmd and SW_SHOWNORMAL = SW_SHOWNORMAL) and
        (WL and WS_VISIBLE = WS_VISIBLE) then
      begin
        Inc(m);
        NumZW[i]:=m;
      end;
      Dispose(WP);
      Break;    
    end;    
  end;
//....

Автор: gonzales 8.9.2006, 11:43
мне кажется можно проще, по крайней мере с винампом канает
делаем проверку каждого окна на  IsWindowVisible=true or IsIconic=true, отсекается все, кроме формы и верхнего уровня - application, далее делаем проверку GetClientRect на ненулевую ширину и высоту формы (у Application - форма имеет 0,0)

Автор: Fedia 8.9.2006, 12:03
Цитата(gonzales @  8.9.2006,  11:43 Найти цитируемый пост)
делаем проверку каждого окна на  IsWindowVisible=true or IsIconic=true

Да, так на самом деле попроще. Только тогда проверка должна быть на IsIconic=false.

Автор: gonzales 8.9.2006, 12:08
Цитата(Fedia @  8.9.2006,  12:03 Найти цитируемый пост)
Да, так на самом деле попроще. Только тогда проверка должна быть на IsIconic=false


тогда свернутая форма не пройдет проверку (но если форма открыта, то да)

Автор: Romikgy 8.9.2006, 14:44
имхо можно , чуть хакерским способом smile
внедрится в нужный процесс и внутри него вызвать GetActiveWindow и забрать значение активного окна smile

Автор: gonzales 8.9.2006, 15:32
Цитата(Romikgy @  8.9.2006,  14:44 Найти цитируемый пост)
внедрится в нужный процесс


а как это сделать?

то есть, если мы имеем только имя исполняемого файла, то что мы можем сделать:
1. по имени файла определяем ID работающего процесса
2. по ID процесса мы находим дискрипторы всех недочерних окон данного процесса

а как реализовать Ваше предложение - не совсем понятно 

Автор: Romikgy 8.9.2006, 15:43
Цитата(gonzales @  8.9.2006,  14:32 Найти цитируемый пост)
а как это сделать?

inject главное слово
Цитата(gonzales @  8.9.2006,  14:32 Найти цитируемый пост)
1. по имени файла определяем ID работающего процесса

тоже
Цитата(gonzales @  8.9.2006,  14:32 Найти цитируемый пост)
2. по ID процесса мы находим дискрипторы всех недочерних окон данного процесса

внедряемся в процесс и спрашиваем кто активный

Добавлено @ 15:43 
про инжект по форуму поищи много чего написано

Powered by Invision Power Board (http://www.invisionboard.com)
© Invision Power Services (http://www.invisionpower.com)