Форум программистов [Powered by Invision Power Board]

Цитата(guest20060 @ 1.11.2006, 20:08

)

Надеюсь на вашу помощь...

Цитата(guest20060 @ 1.11.2006, 21:00

)

Будешь смеяться, но я не нашел здесь рабочего поиска.

Цитата(guest20060 @ 2.11.2006, 00:10

)

Блин, ребята, хорош острить

Цитата(guest20060 @ 2.11.2006, 00:10

)

как кодировать средствами WinAPI

Цитата(guest20060 @ 2.11.2006, 00:10

)

подойдет и функция, не использующая другие модули и не сильно утяжеляющая размер исполнимого файла.

Цитата(guest20060 @ 1.11.2006, 23:10

)

Подключаемый модуль к программе только Windows и только Winsock

Цитата(guest20060 @ 1.11.2006, 23:10

)

подойдет и функция, не использующая другие модули и не сильно утяжеляющая размер исполнимого файла

Цитата(dumb @ 2.11.2006, 00:43

)

CryptStringToBinary
CryptBinaryToString

Цитата(dumb @ 2.11.2006, 00:43

)

хотя windows - это ж солянка... там может и есть cryptoapi...

Цитата(Snowy @ 2.11.2006, 00:08

)

Правда юзать их ещё рано - есть только в XP и 2003

Цитата(Snowy @ 2.11.2006, 00:08

)

CryptoAPI естественно есть. advapi32.dll

Цитата(Snowy @ 2.11.2006, 00:08

)

Но мне совершенно непонятно, как можно Base64 называть Crypt.
Кокой это нафиг крипт, когда банальный конверт.

Цитата(dumb @ 2.11.2006, 02:35

)

эм. я имел ввиду юнит дельфевый... (btw: таки Crypt32.dll)

Цитата(dumb @ 2.11.2006, 02:35

)

в составе криптографических функций imho она действительно необходима(как утилитарная), ибо достаточно часто используется передача именно кодированных base64 данных.

Код


unit XPBase64;

interface

uses Windows;

const
  crypt32 = 'crypt32.dll';

  // Flags:
  CRYPT_STRING_BASE64HEADER = 0;
  // Base64, with certificate beginning and ending headers
  CRYPT_STRING_BASE64 = 1;
  // Base64, without headers
  CRYPT_STRING_BINARY = 2;
  // Pure binary copy
  CRYPT_STRING_BASE64REQUESTHEADER = 3;
  // Base64, with request beginning and ending headers
  CRYPT_STRING_HEX = 4;
  // Hexadecimal only
  CRYPT_STRING_HEXASCII= 5;
  // Hexadecimal, with ASCII character display
  CRYPT_STRING_BASE64X509CRLHEADER = 9;
  // Base64, with X.509 CRL beginning and ending headers
  CRYPT_STRING_HEXADDR = 10;
  // Hexadecimal, with address display
  CRYPT_STRING_HEXASCIIADDR = 11;
  // Hexadecimal, with ASCII character and address display
  CRYPT_STRING_HEXRAW = 12;
  // A raw hex string.

function ToBase64(s: string; Flags: dword = CRYPT_STRING_BASE64REQUESTHEADER): string;
function FromBase64(s: string; Flags: dword = CRYPT_STRING_BASE64REQUESTHEADER): string;

function CryptStringToBinary(pszString: PChar; cchString: dword; dwFlags: dword;
         pbBinary: pointer; var pcbBinary: dword; var pdwSkip: dword;
         var pdwFlags: dword): boolean; stdcall;

function CryptBinaryToString(pbBinary: pointer; cbBinary: dword; dwFlags: dword;
         pszString: PChar; var pcchString: dword): boolean; stdcall;

function CryptStringToBinaryA(pszString: PChar; cchString: dword; dwFlags: dword;
         pbBinary: pointer; var pcbBinary: dword; var pdwSkip: dword;
         var pdwFlags: dword): boolean; stdcall;

function CryptBinaryToStringA(pbBinary: pointer; cbBinary: dword; dwFlags: dword;
         pszString: PChar; var pcchString: dword): boolean; stdcall;

function CryptStringToBinaryW(pszString: PWideChar; cchString: dword; dwFlags: dword;
         pbBinary: pointer; var pcbBinary: dword; var pdwSkip: dword;
         var pdwFlags: dword): boolean; stdcall;

function CryptBinaryToStringW(pbBinary: pointer; cbBinary: dword; dwFlags: dword;
         pszString: PWideChar; var pcchString: dword): boolean; stdcall;

implementation

function CryptStringToBinary; external crypt32 name 'CryptStringToBinaryA';
function CryptBinaryToString; external crypt32 name 'CryptBinaryToStringA';
function CryptStringToBinaryA; external crypt32 name 'CryptStringToBinaryA';
function CryptBinaryToStringA; external crypt32 name 'CryptBinaryToStringA';
function CryptStringToBinaryW; external crypt32 name 'CryptStringToBinaryW';
function CryptBinaryToStringW; external crypt32 name 'CryptBinaryToStringW';

function ToBase64(s: string; Flags: dword = CRYPT_STRING_BASE64REQUESTHEADER): string;
var sz: dword;
begin
  CryptBinaryToString(pointer(s), Length(s), Flags, nil, sz);
  SetLength(result, sz);
  CryptBinaryToString(pointer(s), Length(s), Flags, pointer(result), sz);
end;

function FromBase64(s: string; Flags: dword = CRYPT_STRING_BASE64REQUESTHEADER): string;
var sz, skip: dword;
begin
  CryptStringToBinary(pointer(s), Length(s), Flags, nil, sz, skip, Flags);
  SetLength(result, sz);
  CryptStringToBinary(pointer(s), Length(s), Flags, pointer(result), sz, skip, Flags);
end;

end.

Код


uses XPBase64;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo2.Text := ToBase64(Memo1.Text);
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  Memo3.Text := FromBase64(Memo2.Text);
end;