Форум программистов [Powered by Invision Power Board]

Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате

Форум программистов > Delphi: WinAPI и системное программирование > Нужна срочная помощь с реестром

Автор: Vasilisk03263 31.8.2014, 19:35

Подскажите пожалуйста почему не выводятся в листбокс имена подключей:

Код


procedure TForm1.Button1Click(Sender: TObject);
begin
reg:=tregistry.Create;
reg.RootKey:=HKEY_LOCAL_MACHINE;
reg.OpenKey('\SYSTEM\ControlSet001\Enum\USBSTOR', false);
if reg.KeyExists('USBSTOR') then
listbox1.Items.Add('найдено');

for i:=0 to 20 do
begin
reg.GetKeyNames(listbox1.Items);
end;
reg.Free;
end;

а вот так выводит:

Код


procedure TForm1.Button1Click(Sender: TObject);
begin
reg:=tregistry.Create;
reg.RootKey:=HKEY_LOCAL_MACHINE;
reg.OpenKey('\SYSTEM\ControlSet001\', false);
if reg.KeyExists('USBSTOR') then
listbox1.Items.Add('найдено');

for i:=0 to 20 do
begin
reg.GetKeyNames(listbox1.Items);
listbox1.Items.Add('gyjv');
end;
reg.Free;
end;

Такое ощущение что после второго "ответвления" реестра идут уже не ключи.

Автор: Poseidon 2.9.2014, 10:31

А в \SYSTEM\ControlSet001\Enum\USBSTOR точно есть ключи? Потому как во втором коде проход идет по ветке \SYSTEM\ControlSet001\

Добавлено @ 10:44
Кстати, у меня первый вариант вполне себе нормально отработал. Тольк не понятно зачем там организован цикл, а так же не ясно, зачем там строка 7, если GetKeyNames все-равно зачищает listbox.

Код


procedure TRegistry.GetKeyNames(Strings: TStrings);
var
  Len: DWORD;
  I: Integer;
  Info: TRegKeyInfo;
  S: string;
begin
  Strings.Clear;  { <-- очищение!!! }
  if GetKeyInfo(Info) then
  begin
    SetString(S, nil, Info.MaxSubKeyLen + 1);
    for I := 0 to Info.NumSubKeys - 1 do
    begin
      Len := Info.MaxSubKeyLen + 1;
      RegEnumKeyEx(CurrentKey, I, PChar(S), Len, nil, nil, nil, nil);
      Strings.Add(PChar(S));
    end;
  end;
end;

Не понятно зачем проверка KeyExists, если OpenKey возвращает найден ли ключ или нет.
Плюс оформление кода ужасное. В общем, вот так будет лучше (и работает).

Код


uses Registry;

procedure TForm1.Button1Click(Sender: TObject);
var
  Reg: TRegistry;
begin
  Reg := TRegistry.Create;
  try
    Reg.RootKey := HKEY_LOCAL_MACHINE;

    if Reg.OpenKey('\SYSTEM\ControlSet001\Enum\USBSTOR', False) then
      Reg.GetKeyNames(ListBox1.Items);
  finally
    Reg.Free;
  end;
end;

Автор: Vasilisk03263 3.9.2014, 19:25

Спасибо большое, просто учился лет пять назад, и с этим в принципе вот щас столкнулся, пытаюсь вспомнить и понять)))

Автор: Vasilisk03263 4.9.2014, 20:15

Еще косяк был в том, что операционка походу не давала читать реестр-указал открытие ключа-OpenKeyReadOnly и все отлично прочитало