Версия для печати темы
Нажмите сюда для просмотра этой темы в оригинальном формате
Форум программистов > Delphi: WinAPI и системное программирование > Задержка потока


Автор: NoliX 18.1.2006, 19:56
Товарищи, подскажите, как сделать задержку в потоке, я весь форум перерыл, подходящего ничего не нашел...

Сразу оговорюсь такой цикл мне не подходит....

Код

FirstTickCount := GetTickCount64;
  repeat
    Application.ProcessMessages;
//     allowing access to other controls, etc.
    Now := GetTickCount64;
  until (Now - FirstTickCount >= MSecs);


Ttimer тоже не подходит, и sleep не подходит...

В общем суть задачи состоит в том, что необходимо приостановить работу потока из самого потока на n секунд, при этом основное приложение должно нормально работать... (sleep был бы идеален если бы не тормозил всю программу...)

В общем скажите кто, что знает...
Добавлено @ 20:00
ага, так, sleep тормозит поток если у него нету синхронизации, а с синхронизацией как задержку поставить?

Автор: Демо 18.1.2006, 20:08
NoliX

Если у тебя несколько потоков, то Sleep приостанавливает выполнение только того потока, в котором выполняется Sleep.
Опиши понятнее, что ты хочешь сделать.
Добавлено @ 20:10
PS. Не понял, зачем в WINAPI тему? smile

Автор: NoliX 18.1.2006, 20:17
упс, пардон, темой промахнулся....
Итак есть 2 формы, есть поток, поток вызывается с первой формы и выполняет действия с периодичность в несколько секунд, после того как поток закончил свое черное дело первая форма прячется и появляется вторая форма

Тут 2 подводных камня:
1. Если вызвать поток без синхронизации, то вторая форма не открывается, пишет ошибку, что не верный дескриптор окна
2.Если использовать синхронизацию, то sleep находящийся в потоке подвешивает программу


Вопрос: Что делать?

Автор: _hunter 18.1.2006, 20:33
а почему бы не открывать вторую форму из потока?
+ стандартные методы извещения никто не отменял: после завершения работы потока шли главной форме сообщение, по которому она будет показывать вторую форму.
можно еще и событие прикрутить ( но с сообщением будет по-проще )

Автор: NoliX 18.1.2006, 20:37
ну вот и хочу открыть вторую форму из потока, а она не хочет открываться без синхронизации, а сообщения программе слать я не умею, можно пример?
Добавлено @ 20:43
мне нужно провести вот такие операции
Код

form5.label4.Caption:=IntToStr(z);
form5.label5.Caption:=IntToStr(z1);
form5.label6.Caption:=IntToStr(k1);
form5.label8.Caption:=PChar(TimeToStr(Now));
form5.label9.Caption:=TimeToStr(DateTimeToUnix(now) - pk);
Form4.label7.Caption:='Все сообщения отправлены';
Form4.Memo1.Lines.Add(DateTimeToStr(Now) + ': Все сообщения отправлены');
Form5.Memo1.Text:=Form4.Memo1.Text;
Form5.Show;
Form4.Hide;


первой формой является form4 второй form5
Добавлено @ 20:43
PS это не весь поток =)

Автор: Демо 18.1.2006, 21:00
Из дополнительного потока не создавай формы.

Метод может быть таким:

Код

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type

  TMyThread=class(TThread)
  private
    procedure Display;
  protected
    procedure Execute; override;
  end;

  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

uses Unit2;

{$R *.dfm}

{ TMyThread }

procedure TMyThread.Display;
begin
  Form1.Hide;
  Form2.Show;
end;

procedure TMyThread.Execute;
begin
  //Что-то делаем
  Sleep(3000);  //эмуляция работы
  Synchronize(Display);
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Thr: TMyThread;
begin
  Thr := TMyThread.Create(True);
  Thr.FreeOnTerminate := True;
  Thr.Resume;
end;

end.




Код

unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm2 = class(TForm)
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form2: TForm2;

implementation

uses Unit1;

{$R *.dfm}

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Form1.Show;
end;

end.

Автор: NoliX 18.1.2006, 21:08
Демо, все бы хорошо, так я уже пробывал делать, но вот низадача, данные которые мне нужно передать являются локальми переменными процедуры, если выносить в отдельную процедуру вывод в форму2 то нужно это процеду с параметрами объявлять, а он отказывается синхронизировать такую процедуру или я туплю просто...
Добавлено @ 21:12
просто в этом случае приходится переменные глобализировать, а этого не хотелось бы, кстати понравилась идея с извещениями, но как ее реализовать?

Автор: Демо 18.1.2006, 21:17
Цитата(NoliX @ 18.1.2006, 22:08 Найти цитируемый пост)

анные которые мне нужно передать являются локальми переменными процедуры


Какой процедуры? Где она выполняется?

Автор: NoliX 18.1.2006, 21:32
у меня поток отдельным юнитом создан, в этом потоке процедура поток.Execute, в ней все и происходит

Автор: Демо 18.1.2006, 22:03
Цитата(NoliX @ 18.1.2006, 22:32 Найти цитируемый пост)

у меня поток отдельным юнитом создан, в этом потоке процедура поток.Execute, в ней все и происходит


Так процедура у тебя выполняется в потоке? Почему не используешь переменные потока?

Вот как раз сейчас пишу для себя задачу, посмотри пример. Спецю для тебя добавил временно поле в поток - FTestCounter

Код

unit ufMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, uThreads;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  Thr: TCountThread;

implementation

{$R *.dfm}

procedure Exec(Sender: TObject);
var
  Th: TCountThread;
  dt: TDateTime;
begin
    
  Th := TCountThread(Sender);
//Здесь работаем с любыми параметрами потока.
//Но в этой процедуре нельзя обращаться без синхронизации к раздельным ресурсам без Synchronize
  Th.Counter := 0;
  dt := Now;

  while Now-dt<0.00002 do
  begin
    Th.Counter := Th.Counter + 1;
  end;
end;

procedure OnEnd(Sender: TObject; var FreeThr: Boolean);
begin
//Снова работаем с полями
//Но эта процедура уже потокобезопасна. Здесь можно работать с VCL(например, как ты хотел, с формами)
  ShowMessage(IntToStr(TCountThread(Sender).Counter));
  FreeThr := True;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Thr := TCountThread.Create;
  Thr.ThrProc := Exec;
  Thr.OnComplete := OnEnd;
  Thr.Resume;
end;

end.



Код

unit uThreads;

interface

uses
  Classes, SysUtils;

type

  TCompleteProc=procedure(Sender: TObject; var FreeThr: Boolean);
  TThrProc=procedure(Sender: Tobject);

  TCountThread=class(Tthread)
  private
    FTestCounter: Integer;
    FOnComplete: TCompleteProc;
    FThrProc: TThrProc;
    procedure FComplete;
  protected
    procedure Execute; override;
  public
    constructor Create;
    destructor Destroy; override;

    property ThrProc: TThrProc read FThrProc write FThrProc;
    property OnComplete: TCompleteProc read FOnComplete write FOnComplete;
    property Counter: Integer read FTestCounter write FTestCounter;
  end;


implementation

{ TCountThread }

constructor TCountThread.Create;
begin
  inherited Create(True);
end;

destructor TCountThread.Destroy;
begin
  inherited;
end;

procedure TCountThread.Execute;
begin
  if Assigned(FThrProc) then FThrProc(Self);
  Synchronize(FComplete);
end;

procedure TCountThread.FComplete;
var
  FreeThr: Boolean;
begin
  FreeThr := False;
  if Assigned(FOnComplete) then FOnComplete(Self,FreeThr);
  if FreeThr then FreeOnTerminate := True;
end;

end.

Автор: NoliX 18.1.2006, 22:10
так щас посмотрю подходил ли мне такая штука, спасибо
в общем и целом содержимое потока (по порядку)

Подсчет данных (создание массивов их заполнение вычисление чисел)
Начало цикла
всякие операции
ЗАДЕРЖКА
вывод информации на форму 2 (с использованием переменных потока)
операции опять
конец цикла
вывод информации на форму 2 (с использованием переменных потока)

Автор: Демо 18.1.2006, 22:15
вывод информации на форму 2 (с использованием переменных потока) - Synchronyze(Procedure1)
операции опять
конец цикла
вывод информации на форму 2 (с использованием переменных потока) - Synchronyze(Procedure2) или снова Synchronyze(Procedure1)

Автор: NoliX 18.1.2006, 22:41
на синхронизации зависает теперь и все хмм, буду думать дальше...
и все таки, можно програмно попросить из потока программу выполнить некоторые функции

Автор: Демо 18.1.2006, 22:48
Цитата(NoliX @ 18.1.2006, 23:41 Найти цитируемый пост)

и все таки, можно програмно попросить из потока программу выполнить некоторые функции


Из потока, как и из любой другой функции, можно вызвать на выполнение любую функцию или процедуру...

Автор: NoliX 18.1.2006, 23:14
да нет, я не об этом, я вот об этом
Код

+ стандартные методы извещения никто не отменял:
 после завершения работы потока шли главной форме сообщение,
 по которому она будет показывать вторую форму.

Автор: Poseidon 19.1.2006, 01:34
Елы-палы. Ну и развели димагогию. Поток останавливается методом Suspend. Обратно возобновляется методом Resume. Пример нужен?

Автор: NoliX 19.1.2006, 13:21
Poseidon не пойдет мне suspend!
нужно остановить поток не из приложения, а приостановить его из самого себя в цикле, в нужном месте!

Автор: Alexeis 19.1.2006, 13:31
Цитата

приостановить его из самого себя в цикле, в нужном месте!

а откуда он будет возобновлятся??

Автор: Poseidon 19.1.2006, 13:42
Цитата(NoliX @ 19.1.2006, 12:21 Найти цитируемый пост)

приостановить его из самого себя в цикле, в нужном месте
Тогда sleep, что тут думать. Если это не основной поток программы, то зависания не будет, но поток "уснет" на указанное время.

Автор: AntonSaburov 19.1.2006, 13:42
А объекты синхронизации Винды чем не нравятся ?

Вот тут можно посмотреть - http://msdn.microsoft.com/library/default.asp?url=/library/en-us/dllproc/base/using_event_objects.asp

Автор: NoliX 19.1.2006, 13:48
alexeis1, он будет приостановлен на несколько секунд, в общем мне нужен аналог sleep который при синхронизации не будет тормозить основную программу, либо каким-то образом
передавать

Код

+ стандартные методы извещения никто не отменял: 
после завершения работы потока шли главной форме 
сообщение, по которому она будет показывать вторую форму.

Автор: Poseidon 19.1.2006, 13:51
Цитата(NoliX @ 19.1.2006, 12:48 Найти цитируемый пост)

либо каким-то образом
передавать
"Какой-то образ" - это SendMesage (или PostMessage)

Автор: _hunter 19.1.2006, 13:53
и опять мы возвращаемся к началу...
Sleep() торможит только текущий поток ( остальные не тормозятся )
поэтому если наблюдается торможение -- где0то в логике ошибка.
а что не понятно с сообщениями?

Автор: Alexeis 19.1.2006, 13:55
Poseidon прав
регистрируется сообщение
У формы делается обработчик
В нужный момент поток отправляет сообщение первой
форме.
обработчик запускает вторую форму - только так

Автор: NoliX 19.1.2006, 13:56
Poseidon, кажется то что надо, а как с помощью этого выполнить допустим

Код

form5.label4.Caption:=IntToStr(z);    

Form4.Memo1.Lines.Add(DateTimeToStr(Now) + ': Все сообщения отправлены');    

Form4.Hide;

тоесть какими параметрами вызывать, или где их подглядеть?

Автор: Poseidon 19.1.2006, 14:08
Цитата(NoliX @ 19.1.2006, 12:56 Найти цитируемый пост)

тоесть какими параметрами вызывать, или где их подглядеть?
Какие параметры ты имеешь ввиду?

В обще виде где-то так
Код
SendMessage (MainForm.Handle, WM_User+101, 0, 0);


В главной форме пишешь обработчик сообщения WM_User+101, а в нем то, что нужно сделать при получении этого сообщения.

Автор: NoliX 19.1.2006, 14:11
так, кажется начинаю понимать, осталось ознать, как написать обработчик сообщения =(

Автор: Alexeis 19.1.2006, 14:13
вот пример drkb
Код

Один из способов - создать пользовательское сообщение и использовать метод preform чтобы разослать его всем формам из массива Screen.Forms. 

{Code for Unit1} 

const 
  UM_MyGlobalMessage = WM_USER + 1; 

type 
  TForm1 = class(TForm) 
    Label1: TLabel; 
    Button1: TButton; 
    procedure FormShow(Sender: TObject); 
    procedure Button1Click(Sender: TObject); 
  private 
  {Private declarations} 
    procedure UMMyGlobalMessage(var AMessage: TMessage); message 
      UM_MyGlobalMessage; 
  public 
  {Public declarations} 
  end; 

var 
  Form1: TForm1; 

implementation 

{$R *.DFM} 

uses Unit2; 

procedure TForm1.FormShow(Sender: TObject); 
begin 
  Form2.Show; 
end; 

procedure TForm1.UMMyGlobalMessage(var AMessage: TMessage); 
begin 
  Label1.Left := AMessage.WParam; 
  Label1.Top := AMessage.LParam; 
  Form1.Caption := 'Got It!'; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
  f: integer; 
begin 
  for f := 0 to Screen.FormCount - 1 do 
    Screen.Forms[f].Perform(UM_MyGlobalMessage, 42, 42); 
end; 

{Code for Unit2} 

const 
  UM_MyGlobalMessage = WM_USER + 1; 
type 
  TForm2 = class(TForm) 
    Label1: TLabel; 
  private 
  {Private declarations} 
    procedure UMMyGlobalMessage(var AMessage: TMessage); 
      message UM_MyGlobalMessage; 
  public 
  {Public declarations} 
  end; 

var 
  Form2: TForm2; 

implementation 

{$R *.DFM} 

procedure TForm2.UMMyGlobalMessage(var AMessage: TMessage); 
begin 
  Label1.Left := AMessage.WParam; 
  Label1.Top := AMessage.LParam; 
  Form2.Caption := 'Got It!'; 
end; 

Автор: NoliX 19.1.2006, 14:16
alexeis1, спасибо большое, сейчас попытаюсь разобраться, скорее всего это то, что нужно...

Автор: Poseidon 19.1.2006, 14:33
Цитата(NoliX @ 19.1.2006, 13:11 Найти цитируемый пост)

так, кажется начинаю понимать, осталось ознать, как написать обработчик сообщения =(


Да на самом деле все очень просто. Вот как обработать наше WM_User+101

Код
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TMainForm = class(TForm)
  private
    //сюда добавляем обьявление
    procedure WMUser101(var Msg: TMessage); message WM_User+101;
  public
    { Public declarations }
  end;

var
  MainForm: TMainForm;

implementation

{$R *.dfm}

{ TForm1 }

procedure TMainForm.WMUser101(var Msg: TMessage);
begin
// тут пишем что будем делать при получении WM_User+101
end;

end.

Автор: NoliX 19.1.2006, 14:41
Poseidon, все замечательно, это действительно то что надо, спасибо, mjkmrj вот последний вопрос, мне нужно в этом сообщении передать больше 2-х переменных, это возмжно?
и как тогда их вызвать в процедуре обработки события, первые 2 как я понят вызываются
WParam
LParam

Автор: _hunter 19.1.2006, 14:48
больше параметров передать нельзя.
но никто не мешает создать структуру и передать одним из параметров указатель на нее

Автор: NoliX 19.1.2006, 14:49
Все ясно, всем принимавшим участие огромное спасибо, в том числе и за терпение, дальше разберусь сам...

Powered by Invision Power Board (http://www.invisionboard.com)
© Invision Power Services (http://www.invisionpower.com)