Нарисовал код получения информации по адаптерам:
| Код | unit Unit1;
interface
uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls;
type
TForm1 = class(TForm)
ComboBox1: TComboBox;
Memo1: TMemo;
procedure FormCreate(Sender: TObject); // при запуске составляем список адаптеров
procedure ComboBox1Select(Sender: TObject); // При выборе, показываем инфу
private
procedure FindNetInt; // поиск адаптеров
procedure GetIntInfo(Id: dword); // получить информацию об адаптере
end;
var Form1: TForm1;
implementation
{$R *.dfm}
uses IPHLPAPI, IPHelper, WinSock;
procedure TForm1.FindNetInt;
var
MibArr: IpHlpAPI.TMIBIfArray;
i: integer;
begin
Get_IfTableMIB(MibArr);
if Length(MibArr)>0 then
for i := Low(MIBArr) to High(MIBArr) do
ComboBox1.Items.AddObject(MibArr[i].bDescr, Pointer(MibArr[i].dwIndex));
end;
procedure TForm1.GetIntInfo(Id: dword);
var
MibArr: IpHlpAPI.TMIBIfArray;
IPArr: TMibIPAddrArray;
i,a: integer;
s: string;
begin
Memo1.Clear;
Get_IfTableMIB(MibArr);
Get_IPAddrTableMIB(IPArr);
if Length(MibArr)>0 then
for i:=Low(MIBArr) to High(MIBArr) do
if MibArr[i].dwIndex = Id then
with Memo1.Lines do begin
Add('Name: ' + MibArr[i].bDescr);
Add('Speed: ' + IntToStr(MibArr[i].dwSpeed div 1000000) + 'Mbit/s');
case MibArr[i].dwType of
6: s := 'ETHERNET';
23: s := 'PPP';
24: s := 'LOOPBACK';
9: s := 'TOKENRING';
15: s := 'FDDI';
28: s := 'SLIP';
else s := 'OTHER';
end;
Add('Type: ' + s);
s := 'Mac: ';
for a := 0 to 7 do s := s + IntToHex(MibArr[i].bPhysAddr[a], 2) + '-';
Add(Copy(s, 1, Length(s)-1));
case MibArr[i].dwOperStatus of
1: s := 'UNREACHABLE';
2: s := 'DISCONNECTED';
3: s := 'CONNECTING';
4: s := 'CONNECTED';
5: s := 'OPERATIONAL';
else s := 'NON_OPERATIONAL';
end;
Add('Status: ' + s);
for a := Low(IPArr) to High(IPArr) do
if IPArr[a].dwIndex = MibArr[i].dwIndex then
Add('IP:' + inet_ntoa(in_addr(IPArr[a].dwAddr)));
end;
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
FindNetInt;
end;
procedure TForm1.ComboBox1Select(Sender: TObject);
var i: integer;
begin
Memo1.Clear;
i := ComboBox1.ItemIndex;
if i >= 0 then
GetIntInfo(integer(ComboBox1.Items.Objects[i]));
end;
end. |
Для работы потребуются модули IPHLPAPI и IPHelper.
Пришиваю к посту |
!
