ну блин.... ну дурные проблемы ведь.
гляди. открой пустой проект. кинь на форму обычный Query (в DatabaseName поставь "DBDEMOS"), DataSource, привязанный к этому квери, DBGrid, привязанный к датасорсу, кинь на форму четыре TEdit и одну педаль сиречь TButton. в Query1.SQL напиши 'select * from biolife'. вот код всего проекта:
| Код |
unit Unit1;
interface
uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, ComCtrls, DBTables, DB, StdCtrls, Grids, DBGrids;
const
// количество полей, по которым мы будем фильтровать
FilterNum = 4;
// имена этих полей
FieldNames: array [1..FilterNum] of string =
('SpeciesNo', 'Category', 'Common_Name', 'Species Name');
// основной запрос, к которому будет добавляться динамический сформированный фильтр
SelectClause: string =
'select * from biolife';
type
TForm1 = class(TForm)
Query1: TQuery;
DataSource1: TDataSource;
DBGrid1: TDBGrid;
Button1: TButton;
Edit1: TEdit;
Edit2: TEdit;
Edit3: TEdit;
Edit4: TEdit;
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;
var
Form1: TForm1;
implementation
{$R *.dfm}
procedure TForm1.Button1Click(Sender: TObject);
var
// собственно, будущий фильтр
WhereClause: string;
i: integer;
Edit: TEdit;
begin
WhereClause := '';
// перебираем фильтрумые поля, см (1) в конце.
for i := 1 to FilterNum do begin
// находим Edit для i-го поля, подразумевая что все едиты названы стандартно
Edit := (FindComponent ('Edit' + IntToStr (i)) as TEdit);
// обязательная проверка на nil - т.е. мы убеждаемся, что мы свой едит нашли
if (Edit <> nil) and (Edit.Text <> '') then begin
// если фильтр не пустой, то надо добавить OR к предыдущему условию
if WhereClause <> '' then
WhereClause := WhereClause + ' OR ';
// добавляем к фильтру слеюующее условие
WhereClause := WhereClause + '(' + FieldNames [i] + ' like ''%' + Edit.Text + '%'')';
end;
end;
// если фильтр пустой, ничего не введено, то тупое присвоение
// ему "WHERE" - даст ошибку. поэтому опять проверям.
if WhereClause <> '' then
WhereClause := ' WHERE ' + WhereClause;
// при изменении SQL квери закрывается автоматом, поэтому закрывать
// её руками - смысла нет. сразу присваиваем то, что нам надо
Query1.SQL.Text := SelectClause + WhereClause;
// БАНЗАЙ!!!
Query1.Active := TRUE;
end;
end. |
(1) на самом деле, это сляпано на глазок, и это не лучший способ. лучше, если выставить TEdit'ам свойство Tag равным нужному индексу в массиве полей, и делать перебор всех контролов, проверять, что это едит, брать его тэг, и по тэгу получать имя поля.
единственный возможный глюк в этом коде - Багланд умудрились засунуть в таблицу поле с пробелом (!) в его имени. у меня лично не работает фильтр по Species Name, даже по "Sepices Name" не работает, я фиг его знает, как эти дятлы додумались до такого. так делать нельзя никогда 
второй момент, у меня используется OR - т.е. если хоть одно из введённых юзверем значений совпадёт с нужным полем - то запись с этим полем отобразиться. но могут быть и другие условия, AND, например
успехов разберись с этим кодом и сделай по аналогии. |
((((
