VPF::Как создать массив контролов? - Форум программистов

Exception

Дата 29.12.2004, 11:25 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 4525
Регистрация: 26.12.2004

Репутация: 18
Всего: 186

В VB.NET исключили возможность создания массива контролов в режиме создания формы. Но на самом деле, это только к лучшему! Потому что теперь, это стало более наглядно, и значит более гибко smile

Короче посмотрим, как можно создать массив контролов, на примере массива PictureBox'ов.

Идея состоит в том, чтобы динамически(во время выполнения) создать нужное количество контролов, и присвоить каждому индексу обыкновенного массива, ссылку на созданный объект, а также добавить процедуры обработки события(в VB6 этого сделать было нельзя, из-за этого, было бесполезно создавать контролы во время выполнения)

Код

'Объявим простую переменную-массив типа PictureBox
  Dim pics() As System.Windows.Forms.PictureBox

  Private Sub InitPictureBoxArray(ByVal Count As Integer)
      Dim i As Integer

      'Нижний индекс массива равен 0, поэтому, если мы хотим создать например
      'пять контролов, то должны иметь размер массива от 0 до 4
      Count-=1

      'Изменяем размерность массива
      ReDim Preserve pics(Count)

      For i = 0 To Count
          'Создаем новый экземпляр объекта, типа PictureBox
          pics(i) = New System.Windows.Forms.PictureBox()

          With pics(i)
              'Ради примера, чтобы было видно все наши контролы,
              'Задаем каждому следующему PictureBox, разную Х координату (i*150)
              .Location = New System.Drawing.Point(i * 150, 0)
              'Задаем цвет
              .BackColor = System.Drawing.Color.AliceBlue

              'Здесь пишем любую нужную вам инициализацию экземпляров PictureBox
          End With

          'Далее задаем функции для обработки событий 
          'MouseEnter, MouseLeave и Click соответственно
          AddHandler pics(i).MouseEnter, AddressOf picMEnter
          AddHandler pics(i).MouseLeave, AddressOf picMLeave
          AddHandler pics(i).Click, AddressOf picClick
      Next i

      'Добавляем весь массив в коллекцию контролов формы
      Me.Controls.AddRange(Me.pics)
  End Sub


  Private Sub picMEnter(ByVal sender As System.Object, ByVal e As System.EventArgs)
      sender.BorderStyle = BorderStyle.Fixed3D
  End Sub

  Private Sub picMLeave(ByVal sender As System.Object, ByVal e As System.EventArgs)
      sender.BorderStyle = BorderStyle.None
  End Sub

  Private Sub picClick(ByVal sender As System.Object, ByVal e As System.EventArgs)
      Dim i As Integer
      'Если надо узнать именно индекс в массиве, 
      'то ищем объект sender
      i = Array.IndexOf(pics, sender)
      MsgBox("   Кликнули по " & i & " PictureBox'у   ")
  End Sub

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| VB .NET \| Следующая тема »