VPF::Refactoring, что это и для чего это нужно

korob2001

Дата 30.5.2005, 02:58 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Комодератор
Сообщений: 2871
Регистрация: 29.12.2002

Репутация: 31
Всего: 61

Возможно кому то будет интересно пообщаться на эту тему. Начнем с того, что синтаксис perl позволяет писать весьма лаконичный и хорошочитаемый код. Рефакторинг кода это по сути приведение кода программы к лаконичности и удобочитаемости, избавлению от лишних переменных, убиранию глобальных пременных, включению обработки исключительных ситуаций и т.д. и т.п.
Например, есть такой скрипт, который принимает два параметра и распечатывает файл, заданый вторым параметром, с нумерацией строк:

Код


#!/usr/bin/perl -w
@arr = @ARGV;
$i=1;
if (@arr and $arr[0] eq 'l') {
  open (FH, $arr[1]);
  while ($str = <FH>) {
    chomp($str);
    print $i.$str."\n";
    $i++;
  }
  close FH;
} else {
  print "Using:\n";
  print "printfile.pl l <filename>\n";
}

Для того что бы предотвратить использование глобальных переменных и для большей "секьюрности", добавим use strict; в начало кода. Наш код примет такой вид:

Код


#!/usr/bin/perl -w
use strict;
my @arr = @ARGV;
my $i=1;
if (@arr and $arr[0] eq 'l') {
    open (FH, $arr[1]);
    my $str;
    while ($str = <FH>) {
        chomp($str);
        print $i.$str."\n";
        $i++;
    }
    close FH;
} else {
    print "Using:\n";
    print "printfile.pl l <filename>\n";
}

Теперь вспомним о "переменной по умолчанию" и вобще критически просмотрим код на наличие лишних переменных:

Код


#!/usr/bin/perl -w
use strict;
my $i=1;
if (@ARGV and $ARGV[0] eq 'l') {
    open (FH, $ARGV[1]);
    while (<FH>) {
        chomp;
        print $i.$_."\n";
        $i++;
    }
    close FH;
} else {
    print "Using:\n";
    print "printfile.pl l <filename>\n";
}

Есть хорошее правило, более короткий код в конструкции if {} else стоит ставить первым, плюс добавим обработку исключительных ситуаций:

Код


#!/usr/bin/perl -w
use strict;
my $i=1;
if (@ARGV < 2 or $ARGV[0] ne 'l' or not (-f $ARGV[1])) {
    print "Using:\nprintfile.pl l <filename>\n";
} else {
    open (FH, $ARGV[1]) or die "Can't open file $ARGV[1], $!\n";
    while (<FH>) {
        chomp;
        print $i.$_."\n";
        $i++;
    }
    close FH;
}

Теперь попробуем еще свернуть код:

Код


#!/usr/bin/perl -w
use strict;
if (@ARGV < 2 or $ARGV[0] ne 'l' or not (-f $ARGV[1])) {
    print "Using:\nprintfile.pl l <filename>\n";
} else {
    my $i=1;
    open (FH, $ARGV[1]) or die "Can't open file $ARGV[1], $!\n";
    chomp,print $i++."$_\n" while (<FH>);
}

Если же для нас некритична платформонезависимость кода, то можно его еще "ужать":

Код


#!/usr/bin/perl -w
use strict;
my $i=1;
(@ARGV < 2 or $ARGV[0] ne 'l' or not (-f $ARGV[1])) ?  print "Using:\nprintfile.pl l <filename>\n" :  
            print $i++."$_\n" for split /\n/, `cat $ARGV[1]`;

Свернуть все это можно к "однострочнику":

Код


perl -ne 'print ++$i."$_"' <filename>

Главное не слишком увлекаться, что бы красота кода не повлияла на его стабильность и работу
Надеюсь это кому то пригодится.

--------------------

"Время проходит", - привыкли говорить вы по неверному пониманию.
"Время стоит - проходите вы".

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Perl: Общие вопросы \| Следующая тема »