VPF::Запуск внешнего приложения - Форум программистов

deadsy

Дата 25.6.2004, 09:04 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 9
Регистрация: 8.12.2003

Репутация: нет
Всего: нет

Есть некая консольная утилита, надо к ней написать GUI. Эта утилита делает довольно длительную обработку данных и выводит в консоль процент выполнения. В связи с такой задачей возникают вопросы:

1. Как запустить такую утилиту (ShellExecute,CreateProcess) чтобы можно было:
2. Скрыть окно консоли в котором она работает и
3. Перенаправить вывод консоли в своё приложение ну и читать данные (ну чтобы прогрессбар там сделать хотя-бы).

Alex

Дата 25.6.2004, 13:48 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Экс. модератор
Сообщений: 4147
Регистрация: 25.3.2002
Где: Москва

Репутация: 6
Всего: 162

Код

unit consoleoutput;  

interface 

uses 
  Controls, Windows, SysUtils, Forms; 

function GetDosOutput(const CommandLine:string): string; 

implementation 

function GetDosOutput(const CommandLine:string): string; 
var 
  SA: TSecurityAttributes; 
  SI: TStartupInfo; 
  PI: TProcessInformation; 
  StdOutPipeRead, StdOutPipeWrite: THandle; 
  WasOK: Boolean; 
  Buffer: array[0..255] of Char; 
  BytesRead: Cardinal; 
  WorkDir, Line: String; 
begin 
  Application.ProcessMessages; 
  with SA do 
  begin 
    nLength := SizeOf(SA); 
    bInheritHandle := True; 
    lpSecurityDescriptor := nil; 
  end; 
  // создаём пайп для перенаправления стандартного вывода 
  CreatePipe(StdOutPipeRead,  // дескриптор чтения 
             StdOutPipeWrite, // дескриптор записи 
             @SA,              // аттрибуты безопасности 
             0                // количество байт принятых для пайпа - 0 по умолчанию 
             ); 
  try 
    // Создаём дочерний процесс, используя StdOutPipeWrite в качестве стандартного вывода, 
    // а так же проверяем, чтобы он не показывался на экране. 
    with SI do 
    begin 
      FillChar(SI, SizeOf(SI), 0); 
      cb := SizeOf(SI); 
      dwFlags := STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES; 
      wShowWindow := SW_HIDE; 
      hStdInput := GetStdHandle(STD_INPUT_HANDLE); // стандартный ввод не перенаправляем 
      hStdOutput := StdOutPipeWrite; 
      hStdError := StdOutPipeWrite; 
    end; 

    // Запускаем компилятор из командной строки 
    WorkDir := ExtractFilePath(CommandLine); 
    WasOK := CreateProcess(nil, PChar(CommandLine), nil, nil, True, 0, nil, PChar(WorkDir), SI, PI); 

    // Теперь, когда дескриптор получен, для безопасности закрываем запись. 
    // Нам не нужно, чтобы произошло случайное чтение или запись. 
    CloseHandle(StdOutPipeWrite);  
    // если процесс может быть создан, то дескриптор, это его вывод 
    if not WasOK then 
      raise Exception.Create('Could not execute command line!') 
    else 
      try 
        // получаем весь вывод до тех пор, пока DOS-приложение не будет завершено 
        Line := ''; 
        repeat 
          // читаем блок символов (могут содержать возвраты каретки и переводы строки) 
          WasOK := ReadFile(StdOutPipeRead, Buffer, 255, BytesRead, nil); 

          // есть ли что-нибудь ещё для чтения? 
          if BytesRead > 0 then 
          begin 
            // завершаем буфер PChar-ом 
            Buffer[BytesRead] := #0; 
            // добавляем буфер в общий вывод 
            Line := Line + Buffer; 
          end; 
        until not WasOK or (BytesRead = 0); 
        // ждём, пока завершится консольное приложение 
        WaitForSingleObject(PI.hProcess, INFINITE); 
      finally 
        // Закрываем все оставшиеся дескрипторы 
        CloseHandle(PI.hThread); 
        CloseHandle(PI.hProcess); 
      end; 
  finally 
      result:=Line; 
      CloseHandle(StdOutPipeRead); 
  end; 
end; 


end.

Взято с Исходников.ru http://www.sources.ru

--------------------

Написать можно все - главное четко представлять, что ты хочешь получить в конце.

h2o

Дата 22.8.2005, 16:03 (ссылка)

(нет голосов)

Загрузка ...

Бывалый

Профиль
Группа: Участник
Сообщений: 199
Регистрация: 19.8.2005

Репутация: нет
Всего: 1

Работоспособности добиться не удалось... у кого-нибудь хоть получилось???

Где в этой проге что запускается (мне к примеру winrar нужно запустить)????

И где в этой проге вывод? Точнее куда всё выводится??? Куда???

--------------------

Я нифига не знаю! мало что понимаю! Помогите тупому... У меня стоит D7!

_hunter

Дата 22.8.2005, 16:35 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 8564
Регистрация: 24.6.2003
Где: Europe::Ukraine:: Kiev

Репутация: 9
Всего: 98

в пайп. там же все написанно...

--------------------

Tempora mutantur, et nos mutamur in illis...

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: WinAPI и системное программирование \| Следующая тема »