Модераторы: Akina

Поиск:

Ответ в темуСоздание новой темы Создание опроса
> Как отловить приход данных на COM-порт? без применения контролов 
V
    Опции темы
JusTalionis
Дата 20.5.2008, 14:00 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 576
Регистрация: 11.7.2006

Репутация: 6
Всего: 17



Во исполнение моего обещания, здесь данного cardinalу, рассказываю, как я все-таки добил задачу, и выкладываю готовый проект.

Я испробовал много вариантов. Во-первых, должен отметить, что использование контрола в данном случае дает настолько большие облегчения в работе, что я попытался временно отказаться от своего принципа не применять контролы. И тут же налетел на другую проблему: на моей машине все работало легко и просто, но принес экзешник на работу - и на той машине сразу вылетело сообщение, что в системе установлен неподходящий контрол,- и точка. Я писал об этом в соседней темке. Попробовал переименовать файл контрола; пробовал даже сменить внутри контрола все имена - не вышло, все равно запускался либо тот, что в системе, либо на новый надо было перерегистрировать. Пришлось на этот путь конкретно забить. Контролы - неплохая в основе идея, но Микрософт сделали всё от них зависящее, чтоб пользоваться ими было невозможно.

Вторым вариантом было проверить "смешанную" работу бейсика и API. Я попытался открыть порт обычным бейсиковским Open, а настроить его скорости и проч.- функцией API (потому что в VB6 у Open теперь нет параметров настройки порта). Но функция настройки требует хэндл порта, а как его получить?.. Я пробовал использовать описатель файла, возвращаемый Open (#1, #2,... то есть). Не сработало. Ничего не зависало, но порт не настраивался все равно.

Остается только полностью использовать API, что я всем и рекомендую.
Работа API разбиралась на основе найденного мною примера, который был мной выложен выше. С удивлением я обнаружил, что тот проект прекрасно работает с on-board портом, но отказывается писать/читать эмулированный под XP порт, являющийся шнуром USB-COM. Выяснилось, что автором примера допущена ошибка в объявлении функций ReadFile и WriteFile: последний параметр этих функций lpOverlapped должен быть типа OVERLAPPED, а автор присвоил ему Long. Видимо, посмотрел- что вроде всё работает, и выкинул "излишнюю" структуру. Вот вред "отсебятины". Кроме того, в том примере неправильно описан тип DCB, но это не приводит к ошибкам, если не пытаться писать в поля "в ручную". Так что мне пришлось самому подробно разобрать всё, что требуют API.

А вот с этого места начинается FAQ, запрошенный cardinalом.
Выкладываю полный текст моего модуля для работы с COM-портом при помощи API: 
Код

'   МОДУЛЬ ДЛЯ РАБОТЫ С COM-ПОРТОМ
'            при помощи API.
'--------------------------------------------------------
'для использования в программе здесь четыре подпрограммы:
'OpenCOM -открытие порта. Имеет аргументом единственное число - номер указанного порта.
'SetCommParam -настройка порта. Имеет параметрами четыре числа.
'ReadCOM -функция получения данных с порта. Параметр - количество запрашиваемых символов.
'WriteCOM -отправка данных в порт. Параметр - отправляемая строка символов

'Перед завершением программы обязательно закрывайте открытый порт следующим образом:
' If ComNum > 0 Then fin_com = CloseHandle(ComNum)

Option Explicit

'глобальные переменные
Global ComNum As Long 'хэндл открытого порта; >0, если порт открыт.
Global BarDCB As DCB 'таблица параметров порта
Global CtimeOut As COMMTIMEOUTS 'таймауты порта
Global bRead(2047) As Byte 'буфер принятых символов

'Структуры для параметров настройки порта
Type COMMTIMEOUTS
        ReadIntervalTimeout As Long
        ReadTotalTimeoutMultiplier As Long
        ReadTotalTimeoutConstant As Long
        WriteTotalTimeoutMultiplier As Long
        WriteTotalTimeoutConstant As Long
End Type
Type DCB
        DCBlength As Long
        BaudRate As Long
        fBitFields As Long
        wReserved As Integer
        XonLim As Integer
        XoffLim As Integer
        ByteSize As Byte
        parity As Byte
        StopBits As Byte
        XonChar As Byte
        XoffChar As Byte
        ErrorChar As Byte
        EofChar As Byte
        EvtChar As Byte
        wReserved1 As Integer
End Type

'структура для операций файлового чтения-записи
Type OVERLAPPED
        Internal As Long
        InternalHigh As Long
        offset As Long
        OffsetHigh As Long
        hEvent As Long
End Type

'объявления функций API
Declare Function CreateFile Lib "kernel32" Alias "CreateFileA" (ByVal lpFileName As String, ByVal dwDesiredAccess As Long, ByVal dwShareMode As Long, ByVal lpSecurityAttributes As Long, ByVal dwCreationDisposition As Long, ByVal dwFlagsAndAttributes As Long, ByVal hTemplateFile As Long) As Long
Declare Function PurgeComm Lib "kernel32" (ByVal hFile As Long, ByVal dwFlags As Long) As Long
Public Declare Function SetCommTimeouts Lib "kernel32" (ByVal hFile As Long, lpCommTimeouts As COMMTIMEOUTS) As Long
Public Declare Function SetCommState Lib "kernel32" (ByVal hCommDev As Long, lpDCB As DCB) As Long
Declare Function ReadFile Lib "kernel32" (ByVal hFile As Long, lpBuffer As Any, ByVal nNumberOfBytesToRead As Long, lpNumberOfBytesRead As Long, lpOverlapped As OVERLAPPED) As Long
Declare Function WriteFile Lib "kernel32" (ByVal hFile As Long, lpBuffer As Any, ByVal nNumberOfBytesToWrite As Long, lpNumberOfBytesWritten As Long, lpOverlapped As OVERLAPPED) As Long
Public Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Public Declare Function GetLastError Lib "kernel32" () As Long


Public Sub OpenCOM(ByVal com As Integer) 'Открытие COM-порта
    Dim retval As Long

    ComNum = CreateFile(("COM" + Trim(Str$(com))), &HC0000000, 0, 0&, &H3, 0, 0)
    If ComNum = -1 Then
        MsgBox "Ошибка открытия порта COM" + Trim(Str$(com)), vbCritical
      Else
         retval = PurgeComm(ComNum, 0) 'очистка порта, очередей
    End If
    
    ' Начальное заполнение таблицы параметров приемопередачи
    BarDCB.DCBlength = 28  'длина блока DCB
    BarDCB.BaudRate = 2400  'скорость приемопередачи в бодах
    BarDCB.fBitFields = &H83 'Битовое поле, биты которого означают следующее:
            '1 fBinary вкл двоичный режим. Всегда 1 (кроме Windows 3.x :))
            '2 fParity          1 -проверять четность, возвращать код ошибки.
            '3 fOutxCtsFlow     1 -задействовать сигнал CTS: при сброшенном CTS приостанавливает передачу до появления CTS.
            '4 OutxDsrFlow      1 -точно так же задействовать сигнал DSR
            '5,6 fDtrControl    режим управления DTR. Три значения, не выяснил, каких.
            '7 fDsrSensitivity  чувствительность драйвера к DSR. При 1 драйвер устройства будет игнорировать данные, принятые без DSR.
            '8 fTXContinueOnXoff 0 - прием будет приостанавливаться принятым символом Xoff и возобновляться Xon.
            '9 fOutX            1 -передача будет приостанавливаться принятым символом Xoff и возобновляться Xon.
            '10 fInX            1 -драйвер будет передавать управляющие символы Xon\Xoff
            '11 fErrorChar      1 -при ошибке по четности заменить ошибочный символ на заданный в поле ErrorChar
            '12 fNull           1 -отбрасывать при передаче нулевые байты
            '13,14 fRtsControl  0 -выдавать сигнал RTS. Возможны три значения для выбора режима управления, какая кодировка - не выяснил.
            '15 fAbortOnError   1 -при возникновении ошибки драйвер остановится до вызова функции ClearCommError.
            '16 fDummy2         =0 зарезервировано, не используется.
    BarDCB.wReserved = 0 'не используется, должен быть 0
    BarDCB.XonLim = 128 'Задает минимальное число символов в приемном буфере перед посылкой символа XON
    BarDCB.XoffLim = 64 'Определяет макс кол-во байт в приемном буфере перед посылкой символа XOFF. Оно вычисляется вычитанием данного значения из размера применого буфера (в байтах)
    BarDCB.ByteSize = 8      'разрядность данных (кол-во бит)
    BarDCB.parity = 0      '1-проверять нечетность, 2-проверять четность, 0-не проверять ничего
    BarDCB.StopBits = 0     'количество стоповых бит: 0 -один, 1 -полтора, 2 -два
    BarDCB.XonChar = 17 'символ, используемый в качестве Xon
    BarDCB.XoffChar = 19 'символ, используемый в качестве Xoff
    BarDCB.ErrorChar = 35 'символ, заменяющий принятый с ошибкой
    BarDCB.EofChar = 26 'символ "конец данных"
    BarDCB.EvtChar = 0  'символ для сигнализации о событии
    BarDCB.wReserved1 = 0 'зарезервировано. Не используется.

    'Времена ожидания (Time Outs) в миллисекундах
    CtimeOut.ReadIntervalTimeout = 1 'максимальное время между двумя принимаемыми символами.
    CtimeOut.ReadTotalTimeoutConstant = 1 'постоянная часть таймаута на прием
    CtimeOut.ReadTotalTimeoutMultiplier = 1 'время на прием одного символа (для вычисления переменной части таймаута)
    CtimeOut.WriteTotalTimeoutConstant = 20 'постоянная часть таймаута на передачу
    CtimeOut.WriteTotalTimeoutMultiplier = 5 'время на передачу одного символа (для вычисления переменной части таймаута)
                                                         'нулевые времена означают, что таймауты не используются.

End Sub

    
Public Sub SetCommParam(baud As Long, parity As Byte, bits As Byte, stops As Byte)
'подпрограмма установки параметров порту
'все аргументы- числа:
' baud -скорость обмена в бодах, из принятой шкалы скоростей.
' parity -четность. 1=проверять нечетность, 2=проверять четность, 0=не проверять ничего
' bits -битность данных. Число: 5, 6, 7 или 8 бит.
' stops 0=один стоповый бит, 1=полтора стоповых бита, 2=два стоповых бита.


    Dim retval As Long

    'установка таймаутов
 '   CtimeOut.ReadIntervalTimeout = 1 + Int(12000 / baud)
 '   CtimeOut.ReadTotalTimeoutConstant = 1
 '   CtimeOut.ReadTotalTimeoutMultiplier = 1 + Int(12000 / baud)
    CtimeOut.WriteTotalTimeoutMultiplier = 1 + Int(12000 / baud)
    retval = SetCommTimeouts(ComNum, CtimeOut)
    If retval = -1 Then
        retval = GetLastError()
        MsgBox "Ошибка при установке таймаутов, Error: " & retval
    End If
    
    BarDCB.BaudRate = baud  'скорость приемопередачи в бодах
    BarDCB.ByteSize = bits  'разрядность данных (кол-во бит)
    BarDCB.parity = parity  '1-проверять нечетность, 2-проверять четность, 0-не проверять ничего
    BarDCB.StopBits = stops 'количество стоповых бит: 0 -один, 1 -полтора, 2 -два
    retval = SetCommState(ComNum, BarDCB)
    If retval = -1 Then
        retval = GetLastError()
        MsgBox "Не удается настроить порт на заданные параметры Error: " & retval
    End If
         
End Sub

Public Function ReadCOM(ByVal numChar As Integer) As String
'функция приема через COM
'параметр - число принимаемых за раз символов, до 2047
'(при циклическом вызове его можно уменьшить для ускорения работы)
    Dim RetBytes As Long, i As Integer, ReadStr As String, retval As Long
    Dim lpOverlapped As OVERLAPPED

    'чтение с порта
    retval = ReadFile(ComNum, bRead(0), numChar, RetBytes, lpOverlapped)
    If retval = 0 Then
        retval = GetLastError()
        MsgBox "Ошибка работы с портом Error: " & retval
    End If

    ReadStr = ""
    If (RetBytes > 0) Then
        For i = 0 To RetBytes - 1
            ReadStr = ReadStr + Chr(bRead(i))
        Next i
    End If

    ReadCOM = ReadStr

End Function

Public Sub WriteCOM(COMString As String)
'Подпрограмма передачи в порт.
'Параметр - передаваемая строка символов

    Dim RetBytes As Long, LenVal As Long, retval As Long
    Dim lpOverlapped As OVERLAPPED

    If COMString = "" Then Exit Sub

    'Рекурсивный вызов: передача длинных строк
    'частями по 2048 знаков (потому что буфер приемопередачи- 2048 знаков)
    If Len(COMString) > 2047 Then
        Call WriteCOM(Left$(COMString, 2047))
        Call WriteCOM(Right$(COMString, Len(COMString) - 2047))
        Exit Sub
    End If

    'передача знаков в буфер
    For LenVal = 0 To Len(COMString) - 1
        bRead(LenVal) = Asc(Mid$(COMString, LenVal + 1, 1))
    Next LenVal

    'передачa через COM
    retval = WriteFile(ComNum, bRead(0), Len(COMString), RetBytes, lpOverlapped)
    If retval = 0 Then
        retval = GetLastError()
        MsgBox "Ошибка передачи Error: " & retval & vbCrLf & "Передано " & RetBytes & " байт"
    End If
End Sub


Как использовать. Создаете в своем проекте модуль и вписываете в него целиком этот код. В результате в вашей проге доступны три подпрограммы и две функции для работы с COMом.
Сначала открываете желаемый порт подпрограммой OpenCOM. Аргументом ее является только число, напр. 2 (а не COM2: ). Потом настраиваете желаемую скорость и прочее при помощи SetCommParam - у нее тоже все аргументы числовые. Вместо "9600,8,n,1" задаем 9600, 0, 8, 0 . Подробное описание поставил в комментах.
Всё! После этого можно посылать данные WriteCOM и принимать ReadCOM. ReadCOM имеет параметром количество читаемых знаков. Это сделано для того, чтобы при циклическом вызове можно было ускорить вращение цикла, убавив число принимаемых за раз символов (все равно вызовы идут друг за другом!). Можно сделать даже посимвольный прием, но тогда скорость опять падает за счет увеличения количества проходов цикла. Оптимум- 10 - 15 в цикле и 255 знаков при разовом приеме кнопкой.
Замеченные ошибки мной исправлены, формат DCB правильный. При желании можно писать "в ручную" прямо в поля переменной BarDCB, а потом вызвать SetCommParam, которая отправит настройки в порт. Про DCB я могу рассказать отдельно (если спросите), впрочем я постарался по возможности подробно ее откомментировать.

И одно важное предупреждение:
перед завершением программы следует порт закрыть ОБЯЗАТЕЛЬНО! Если Вы этого не сделаете - он останется открытым и недоступным для всех программ. Я не знаю другого способа вернуть такой порт в действие, кроме перезагрузки компа. API принадлежат собственно не Бейсику, а Виндам, и поэтому их действие сохраняется и после закрытия вашей программы. В данном случае - это единственный минус использования API.
Закрыть порт в нашей программе можно, использовав непосредственно функцию API, поставленную в событие Unload формы:
fin_com = CloseHandle(ComNum)
ComNum у нас хранит хэндл порта, полученный при открытии. Эту переменную можно использовать в программе для проверки, открыт ли порт. Если ComNum больше нуля - то открыт.

К этому сообщению я приаттачиваю полностью проект. Собственно, всё необходимое для работы с портом сосредоточено в модуле. А форма - это только пользовательский интерфейс, и все, что наворочено в ней - всего лишь связи элементов между собой. (Дело в том, что текстовые поля не отображают нулевой код, а мне хотелось, чтоб он отсылался/принимался тоже. Пришлось дублировать данные в переменных, и проч. мутату).
Проект был задуман как терминал для отладки микроконтроллеров, и поэтому внешне он реализует подход электронщика, а не программиста. Кнопки "Open" нет: порт открывается автоматически, когда начинается работа с ним, а закрывается при закрытии программы.
Форма About первоначально была предназначена для дополнительных параметров, типа размера буферов. Это делайте сами smile 

Благодарности: Неизвестному автору примера, на котором я тренировался, и от которого остались имена и некоторые решения.
Олегу Титову, за замечательную статью , которая мне всё разъяснила. Об этом я постараюсь рассказать в отдельной темке.

Всем удачи! smile 





Это сообщение отредактировал(а) JusTalionis - 25.5.2008, 10:21

Присоединённый файл ( Кол-во скачиваний: 73 )
Присоединённый файл  comm_API.zip 8,66 Kb
PM MAIL   Вверх
Derks
Дата 13.9.2008, 22:51 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Новичок



Профиль
Группа: Участник
Сообщений: 1
Регистрация: 19.6.2008

Репутация: нет
Всего: нет



Вообщем можете верить можете проверить... но когда пытался использовать данный код, возникла маленькая проблемка...
Порт никак не хотел открываться. Все заработало когда заменил "COM1" на "\.\\COM1". Решение нашел по адресу http://support.microsoft.com/kb/115831. Может это сэкономит кому время...
PM MAIL   Вверх
JusTalionis
Дата 14.9.2008, 14:13 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 576
Регистрация: 11.7.2006

Репутация: 6
Всего: 17



Цитата(Microsoft)
 HOWTO: Specify Serial Ports Larger than COM9
SUMMARY
CreateFile() can be used to get a handle to a serial port. The "Win32 Programmer's Reference" entry for "CreateFile()" mentions that the share mode must be 0, the create parameter must be OPEN_EXISTING, and the template must be NULL. 

CreateFile() is successful when you use "COM1" through "COM9" for the name of the file; however, the message 
INVALID_HANDLE_VALUE 
is returned if you use "COM10" or greater. 

If the name of the port is \\.\COM10, the correct way to specify the serial port in a call to CreateFile() is as follows:    CreateFile(
      "\\\\.\\COM10",     // address of name of the communications device
      fdwAccess,          // access (read-write) mode
      0,                  // share mode
      NULL,               // address of security descriptor
      OPEN_EXISTING,      // how to create
      0,                  // file attributes
      NULL                // handle of file with attributes to copy
   );

    
NOTES: This syntax also works for ports COM1 through COM9. Certain boards will let you choose the port names yourself. This syntax works for those names as well. 

APPLIES TO
• Microsoft Win32 Application Programming Interface, when used with: 
    Microsoft Windows 95 
    Microsoft Windows 98 Standard Edition 
    Microsoft Windows 2000 Standard Edition 
    Microsoft Windows Millennium Edition 
    Microsoft Windows NT 4.0 
    the operating system: Microsoft Windows XP 


mihanik!!! smile 
Вы у нас тут специалист,  сертифицированный Микрософт; разъясните, пожалуйста, как же все-таки следует правильно писать имена портов: \\.\COM10, \\\\.\\COM10 или \.\\COM1 ?
И с какой, вообще, стати в именах портов появилась непонятная куча слэшей?

PM MAIL   Вверх
mihanik
Дата 14.9.2008, 15:12 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


-=Белый Медведь=-
****


Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 11
Всего: 109



Цитата(JusTalionis @  14.9.2008,  14:13 Найти цитируемый пост)
mihanik!!!  
Вы у нас тут специалист,  сертифицированный Микрософт; разъясните, пожалуйста, как же все-таки следует правильно писать имена портов: \\.\COM10, \\\\.\\COM10 или \.\\COM1 ?
И с какой, вообще, стати в именах портов появилась непонятная куча слэшей?


А что сразу я-то?  smile 
Я сертифицированный специалист в области ОС Windows XP, а не программер?
(Хотя VB6 немного знаю...)

Думаю, что это как-то связано с организацией работы API... 
Цитата

APPLIES TO
• Microsoft Win32 Application Programming Interface, when used with: 


(Вы заметили парность слешей, если их больше 1?)


Это сообщение отредактировал(а) mihanik - 14.9.2008, 15:13


--------------------
Программистами не рождаются, - это родовая травма...
user posted imageuser posted image
PM MAIL WWW ICQ   Вверх
JusTalionis
Дата 14.9.2008, 15:36 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 576
Регистрация: 11.7.2006

Репутация: 6
Всего: 17



нет, не заметил. Там их по три штуки есть.  И все-таки сколько их должно быть-то? Три или шесть? (хотя бы у двузначных COM-ов)? Я что-то не въезжаю, что в Микрософтовской цитате рекомендовано.

PM MAIL   Вверх
mihanik
Дата 14.9.2008, 17:08 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


-=Белый Медведь=-
****


Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 11
Всего: 109



Цитата(JusTalionis @  14.9.2008,  15:36 Найти цитируемый пост)
Там их по три штуки есть

Где?
Если это
Цитата(mihanik @  14.9.2008,  15:12 Найти цитируемый пост)
\\.\

то это не считается. Это не 3, а 2 и 1.

Цитата(JusTalionis @  14.9.2008,  15:36 Найти цитируемый пост)
Я что-то не въезжаю, что в Микрософтовской цитате рекомендовано.

Ну... Там сказамо, что если ты обращаешься к порту 10 и выше, то стоит использовать такую вот странную нотацию.
Кроме того сказано, что и для портов с номерами от 1 до 9 эта нотация также работает...



--------------------
Программистами не рождаются, - это родовая травма...
user posted imageuser posted image
PM MAIL WWW ICQ   Вверх
JusTalionis
Дата 14.9.2008, 20:00 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 576
Регистрация: 11.7.2006

Репутация: 6
Всего: 17



А какую именно: \\.\ или \\\\.\\ ?

PM MAIL   Вверх
mihanik
Дата 14.9.2008, 21:22 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


-=Белый Медведь=-
****


Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 11
Всего: 109



Цитата

If the name of the port is \\.\COM10, the correct way to specify the serial port in a call to CreateFile() is as follows:    CreateFile(
      "\\\\.\\COM10",     // address of name of the communications device
      fdwAccess,          // access (read-write) mode
      0,                  // share mode
      NULL,               // address of security descriptor
      OPEN_EXISTING,      // how to create
      0,                  // file attributes
      NULL                // handle of file with attributes to copy
   );


Вольный перевод

Цитата

Если имя порта - это "\\.\COM10", правильный(корректный) способ определить порт в вызове процедуры CreateFile() является следующим
CreateFile(
      "\\\\.\\COM10",     // адрес имени комуникационного устройства
      fdwAccess,          // способ доступа (read-write)
      0,                  // режим шары
      NULL,               // адрес дискриптора безопасности
      OPEN_EXISTING,      // как создавать
      0,                  // атрибуты файла
      NULL                // хэндл файла с атрибутами для копирования
   );




Ну... Как-то так...

Добавлено через 2 минуты и 19 секунд
JusTalionis, изучай не только VB6, но и английский...  ;-)


Это сообщение отредактировал(а) mihanik - 14.9.2008, 21:23


--------------------
Программистами не рождаются, - это родовая травма...
user posted imageuser posted image
PM MAIL WWW ICQ   Вверх
JusTalionis
Дата 15.9.2008, 08:43 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 576
Регистрация: 11.7.2006

Репутация: 6
Всего: 17



Пасиб за пожелание относительно английского; этот вольный перевод и у меня получился таким же, но меня смутило вот что: "ЕСЛИ имя порта - это "\\.\COM10". А если просто COM10? Тогда как?.. Ведь у Derks заработало \.\\COM1 а не \\.\COM1.

(Извиняй, что докапываюсь, но хочется чтоб код работал везде, а не на одной конкретной машине.)


PM MAIL   Вверх
mihanik
Дата 15.9.2008, 22:16 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


-=Белый Медведь=-
****


Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 11
Всего: 109



JusTalionis, это как твоя аватара.
Кто-то видит саксофониста, а кто-то прекрасную девушку...
Я бы поступил так, если номер порта 1-9, то использовал бы одну нотацию, если 10-... , то другую.
Оператор If ещё не отменили...

 smile 



--------------------
Программистами не рождаются, - это родовая травма...
user posted imageuser posted image
PM MAIL WWW ICQ   Вверх
JusTalionis
Дата 16.9.2008, 08:38 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 576
Регистрация: 11.7.2006

Репутация: 6
Всего: 17



If без проблем. Но не в этом же дело. А дело в том, чтобы получить исправно рабочий код.
В реальности ни я, ни кто другой, не в состоянии в ручную проверить работоспособность кода на ВСЕХ компах, которые могут существовать на свете.
Для этого существуют стандарты и правила. Их соблюдение гарантирует работоспособность в оговоренных условиях. Например путь C:\WINDOWS гарантированно приведет нас в папку, если таковая существует.

Мне нет проблемы добавить два или 4 слэша. И посмотреть, заработает или нет. Но это "шаманство", потому что у меня - всё заработает, а на твоем компе - фиг знает. Код, который я выше писал, работал на двух машинах у меня, работал под '95 и '98 на работе, работал под Вистой.
А вот у  Derks не заработал. Я добавлю слэши так и эдак - и у скольких людей тогда код перестанет работать и начнет глючить? Не можешь сказать? Вот поэтому и надо придерживаться в написаннии правил, которые обеспечивают работоспособность.
А правило не может быть двусмысленным, как моя аватара. Кстати, на ней, имхо, Че Гевара в молодости, а не девушка))))))

И в данном случае мне непонятно, что же тогда считается правильным "именем порта"? Я в простоте душевной полагал, что в программировании "правильным" является именно то имя, которое фигурирует в вызове, а не в устной речи.
В тексте же "именем порта" названо одно, а в вызове - другое. Вот такое правило мне не понятно, разъясните кто-нибудь мне, старому дураку!

PM MAIL   Вверх
Akina
Дата 16.9.2008, 09:09 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Советчик
****


Профиль
Группа: Модератор
Сообщений: 20430
Регистрация: 8.4.2004
Где: Зеленоград

Репутация: 32
Всего: 449



Цитата(JusTalionis @  16.9.2008,  09:38 Найти цитируемый пост)
правило не может быть двусмысленным

Оно и не является дувусмысленным.

UNC-путь должен начинаться двумя слешами, если указывается имя компьютера, и одним - если не указывается. В записи \\.\COM10 в начале два слеша - значит, компьютер указан, а раз там точка - путь указывает на текущий компьютер. Кстати, допустима запись типа \\?\Resource\Folder\Filename - вернее, как раз в данном случае, когда ресурс есть устройство (COM10), недопустима, а вот для файлового ресурса не только допустима, но и предпочтительна.
Цитата(Derks @  13.9.2008,  23:51 Найти цитируемый пост)
Все заработало когда заменил "COM1" на "\.\\COM1". 

Нотация с ошибочным количеством слешей сработала просто потому, что все происходит локально. Но не факт, что это будет на всех компьютерах - особенности ОС могут привести к проблемам. А вот указанный в документации вариант \\.\COM10 сработает всегда.


--------------------
 О(б)суждение моих действий - в соответствующей теме, пожалуйста. Или в РМ. И высшая инстанция - Администрация форума.

PM MAIL WWW ICQ Jabber   Вверх
JusTalionis
Дата 16.9.2008, 11:02 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 576
Регистрация: 11.7.2006

Репутация: 6
Всего: 17



Akina:
С учетом выше сказанного Вами, будет ли безусловно верен следующий (развернутый) перевод? -

"Если номер COM-порта превышает 9, то к нему следует обращаться как к сетевому даже в том случае, когда он находится непосредственно на текущем компьютере, то есть сетевое имя его например \\.\COM10
При вызове функции CreateFile() в адресе следует добавить слэши следующим образом: 
Код
 CreateFile(
      "\\\\.\\COM10",     // адрес имени комуникационного устройства
      fdwAccess,          // способ доступа (read-write)
      0,                  // режим шары
      NULL,               // адрес дискриптора безопасности
      OPEN_EXISTING,      // как создавать
      0,                  // атрибуты файла
      NULL                // хэндл файла с атрибутами для копирования
   ); 

Этот способ работает также и для портов 1 - 9."
?


Derks:
Пробовали ли Вы использовать в точности микрософтовский вариант вызова "\\\\.\\COM1" ? Заработал ли такой синтакисис?
И почему Вы остановились на "\.\\COM1" ?



PM MAIL   Вверх
Akina
Дата 16.9.2008, 13:17 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Советчик
****


Профиль
Группа: Модератор
Сообщений: 20430
Регистрация: 8.4.2004
Где: Зеленоград

Репутация: 32
Всего: 449



Цитата(JusTalionis @  16.9.2008,  12:02 Найти цитируемый пост)
будет ли безусловно верен следующий (развернутый) перевод?

Термин "сетевой" в данном случае неверен. Правильнее использовать термин "UNC-путь".


--------------------
 О(б)суждение моих действий - в соответствующей теме, пожалуйста. Или в РМ. И высшая инстанция - Администрация форума.

PM MAIL WWW ICQ Jabber   Вверх
RA3PKJ
Дата 18.6.2011, 10:03 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Новичок



Профиль
Группа: Участник
Сообщений: 2
Регистрация: 9.10.2008

Репутация: нет
Всего: нет



Всё работает отлично. Спасибо за код. Но есть замечание. После закрытия порта следует обнулить переменную ComNum, т.е. вписать ComNum = 0. Ни кто за нас это не сделает. Ещё раз говорю - Спасибо.
PM MAIL   Вверх
Google
  Дата 16.12.2019, 10:50 (ссылка)  





  Вверх
Страницы: (4) Все 1 2 [3] 4 
Ответ в темуСоздание новой темы Создание опроса
Правила форума "VB6"
Akina

Запрещается!

1. Публиковать ссылки на вскрытые компоненты

2. Обсуждать взлом компонентов и делиться вскрытыми компонентами

  • Литературу по VB обсуждаем здесь
  • Действия модераторов можно обсудить здесь
  • С просьбами о написании курсовой, реферата и т.п. обращаться сюда
  • Вопросы по реализации алгоритмов рассматриваются здесь
  • Используйте теги [code=vb][/code] для подсветки кода. Используйтe чекбокс "транслит" (возле кнопок кодов) если у Вас нет русских шрифтов.


Если Вам понравилась атмосфера форума, заходите к нам чаще! С уважением, Akina.

 
0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема | VB6 | Следующая тема »


 




[ Время генерации скрипта: 0.1024 ]   [ Использовано запросов: 22 ]   [ GZIP включён ]


Реклама на сайте     Информационное спонсорство

 
По вопросам размещения рекламы пишите на vladimir(sobaka)vingrad.ru
Отказ от ответственности     Powered by Invision Power Board(R) 1.3 © 2003  IPS, Inc.