VPF::Как узнать размерность множества

Delphist

Дата 25.10.2006, 14:42 (ссылка)

(нет голосов)

Загрузка ...

Delphist Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 2145
Регистрация: 3.2.2004
Где: всегда в сети

Репутация: 2
Всего: 3

Есть переменная:

Код


Type
  TMyBtn = set of (btnYes, btnNo, btnCancel)
Var
   MyBtn: TMyBtn;

MyBtn := [btnYes, btnNo]
Как узнать количество элементов хранящихся в MyBtn.

--------------------

ProcessInfo 1-ая моя программа (аналог spyxx.exe с гораздо большим функц-ом - внедрение dll в адр. простр. процесса, перехват API-функций, разбор приложения на окна мн.др).
Когда-то давным-давно использовал это...

digs

Дата 25.10.2006, 15:41 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 62
Регистрация: 14.10.2006

Репутация: нет
Всего: 1

Код


Count := 0;
for i:=Low(TMyBtn) to High(TMyBtn) do
  if i in MyBtn  then Inc(Count);

Это сообщение отредактировал(а) digs - 25.10.2006, 15:43

Delphist

Дата 25.10.2006, 15:54 (ссылка)

(нет голосов)

Загрузка ...

Delphist Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 2145
Регистрация: 3.2.2004
Где: всегда в сети

Репутация: 2
Всего: 3

У меня компилятор выдает ошибку на Low(TMyBtn)

--------------------

Vit

Дата 25.10.2006, 16:00 (ссылка)

(нет голосов)

Загрузка ...

Vitaly Nevzorov

Профиль
Группа: Экс. модератор
Сообщений: 10964
Регистрация: 25.3.2002
Где: Chicago

Репутация: 48
Всего: 207

Странно, но нет стандартных функций... Поглядел в то что делает компиллятор с этими Set, вроде как должно работать что-то типа такого:

Код


  Function GetNum(MySet:TMyBtn):byte;
    var i:integer;
        test:byte;

    function power2(power:byte):byte;
      var i:integer;
    begin
      result:=1;
      for i:=1 to power do result:=result*2;
    end;

  begin
    test:=byte((@MySet)^);
    result:=0;
    for i:=0 to 7 do
      if test and power2(i)<>0 then inc(result);
  end;

Во всяком случае если количество элементов в Set меньше 8, если больше, то надо вместо байта использовать соответствующие типы...

Добавлено @ 16:01
digs, это для массивов, в set по определению элементы не пронумерованы и нет high и low значений

--------------------

With the best wishes, Vit
I have done so much with so little for so long that I am now qualified to do anything with nothing
Самый большой Delphi FAQ на русском языке здесь: www.drkb.ru

Yanis

Дата 25.10.2006, 17:06 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 2937
Регистрация: 9.2.2004
Где: Москва

Репутация: 72
Всего: 111

Код

type
  MySet = set of (msF1, msF2, msF3, msF4, msF5, msF6, msF7, msF8);

var
  b: Byte;
  i: Integer;
  s: MySet;
  c: Integer;
begin
  s := [msF1, msF4, msF8];
  c := 0;
  for i := 0 to (SizeOf(b) * 8) - 1 do
    begin
      if Byte(s) and (1 shl i) > 0 then
        Inc(c);
    end;

  ShowMessage(IntToStr(c));
end;

Множество это обычное число smile

--------------------

*щёлк*

digs

Дата 25.10.2006, 23:49 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 62
Регистрация: 14.10.2006

Репутация: нет
Всего: 1

Код


Type    
  TMyBtn = (btnYes, btnNo, btnCancel);
  TMyBtns = set of TMyBtn;
Var    
  MyBtns: TMyBtns;
  i : TMyBtn;
begin
  MyBtns := [btnYes, btnNo];
  ...
  Count := 0;    
  for i:=Low(TMyBtn) to High(TMyBtn) do    
    if i in MyBtns  then Inc(Count);

Вроде так должно работать

Delphist

Дата 26.10.2006, 07:54 (ссылка)

(нет голосов)

Загрузка ...

Delphist Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 2145
Регистрация: 3.2.2004
Где: всегда в сети

Репутация: 2
Всего: 3

Цитата(digs @ 26.10.2006, 00:49

)

TMyBtn = (btnYes, btnNo, btnCancel);
TMyBtns = set of TMyBtn;

Я понимаю, что
TMyBtn = (btnYes, btnNo, btnCancel);
TMyBtns = set of TMyBtn;
это аналог TMyBtns = (btnYes, btnNo, btnCancel); но мне нужно чтобы было именно так для того, чтобы была возможность передавать напрямую в процедуру конкретные значения

Код


procedure MyProc(My: TMyBtn);
begin
...
end;
...
MyProc([btnYes, btnNo])

--------------------

Rennigth

Дата 26.10.2006, 09:38 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 1708
Регистрация: 21.6.2004
Где: Moscow

Репутация: 49
Всего: 76

Delphist,
Подругому не получиться наверно, да и нестоит извращаться.
Делай Set of как уже советовали, посмотри туже реализацию MessageDlg (CreateMessageDialog).

--------------------

(* Honesta mors turpi vita potior *)

digs

Дата 26.10.2006, 18:33 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 62
Регистрация: 14.10.2006

Репутация: нет
Всего: 1

Указывай множество (добавил одну букву)

Код


procedure MyProc(My: TMyBtns);    
begin    
...    
end;    
...    
MyProc([btnYes, btnNo])

Girder

Дата 28.10.2006, 23:38 (ссылка)

(нет голосов)

Загрузка ...

Лентяй 2

Профиль
Группа: Участник Клуба
Сообщений: 1993
Регистрация: 12.5.2004

Репутация: 31
Всего: 155

Код


function get_bit1(const m; size:integer):integer;
var i:integer;
function zzz(b : byte):byte;
begin
 b:=(b and 85) + ((b shr 1) and 85);
 b:=(b and 51) + ((b shr 2) and 51);
 b:=(b and 15) + ((b shr 4) and 15);
 Result:=b;
end;
begin
 Result:=0;
 for i:=0 to (size-1) do
  Result:=Result+zzz(pbyte(integer(@m)+i)^);
end;

procedure TForm1.Button1Click(Sender: TObject);
Type
  TSet1 = set of 1..250;
  TSet2 = set of (btnYes, btnNo, btnCancel);
var
   Set1: TSet1;
   Set2: TSet2;
begin
 Set1:=[1,2,100,200];
 Set2:=[btnYes];
 caption:='Set1: '+IntToStr(get_bit1(Set1,SizeOf(TSet1)))+'; Set2: '+IntToStr(get_bit1(Set2,SizeOf(TSet2)));
end;

--------------------

Как слышим, так и пишим.
Истина где-то там...

Yanis

Дата 29.10.2006, 03:06 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 2937
Регистрация: 9.2.2004
Где: Москва

Репутация: 72
Всего: 111

А чем мой способ не подходит?
Или я в суть вопроса не въехал как обычно? smile

Girder
Мой код вроде попроще smile

--------------------

*щёлк*

Girder

Дата 29.10.2006, 09:02 (ссылка)

(нет голосов)

Загрузка ...

Лентяй 2

Профиль
Группа: Участник Клуба
Сообщений: 1993
Регистрация: 12.5.2004

Репутация: 31
Всего: 155

Цитата(Yanis @ 29.10.2006, 04:06

)

А чем мой способ не подходит?

А разьве кто-то это говорит?

Цитата(Yanis @ 29.10.2006, 04:06

)

Мой код вроде попроще

Они принципиально разные весчи решают. Или если точнее... get_bit1 любое множество проглотит.

--------------------

Как слышим, так и пишим.
Истина где-то там...

Yanis

Дата 29.10.2006, 10:09 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 2937
Регистрация: 9.2.2004
Где: Москва

Репутация: 72
Всего: 111

Цитата(Girder @ 29.10.2006, 10:02

)

А разьве кто-то это говорит?

Бональный интерес.

Цитата(Girder @ 29.10.2006, 10:02

)

Они принципиально разные весчи решают. Или если точнее... get_bit1 любое множество проглотит.

Ок. Хотя мой код можно подкорректировать и он тоже будет крут smile

M
Girder

Не оффтопь!

--------------------

*щёлк*

Delphist

Дата 31.5.2007, 10:26 (ссылка)

(нет голосов)

Загрузка ...

Delphist Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 2145
Регистрация: 3.2.2004
Где: всегда в сети

Репутация: 2
Всего: 3

Цитата(Yanis @ 29.10.2006, 11:09

)

Ок. Хотя мой код можно подкорректировать и он тоже будет крут

Выкладываю универсальный пример может кому нужен будет:

Код


type 
   TEnum = (Elem1, Elem2,..., ElemN);
   TSets = set of TEnum;

function CountElement(sets: TSets): integer;
var
  i: integer;
  Enum: TEnum;
begin

  Result := 0;
  for i := integer(Low(TEnum)) to integer(High(TEnum)) do
    if TEnum(i) in sets then
      inc(Result);
end;

--------------------

MetalFan

Дата 31.5.2007, 10:49 (ссылка)

(нет голосов)

Загрузка ...

Аццкий Сотона

Профиль
Группа: Комодератор
Сообщений: 3815
Регистрация: 2.10.2006
Где: Moscow

Репутация: 62
Всего: 128

Delphist, это как раз не универсальный пример... а частный для TEnum и TSets

Это сообщение отредактировал(а) MetalFan - 31.5.2007, 11:44

--------------------

There are always someone smarter than you...

MetalFan

Дата 31.5.2007, 11:48 (ссылка)

(нет голосов)

Загрузка ...

Аццкий Сотона

Профиль
Группа: Комодератор
Сообщений: 3815
Регистрация: 2.10.2006
Где: Moscow

Репутация: 62
Всего: 128

вот накидал универсальный пример, исходя из следующих соображений:
множества в делфи - это "набор" битов, длинной до 256.
соотв. достаточно узнать указатель и размер(занимаемый в памяти) множества,
чтобы подсчитать кол-во элементов.
вот что у меня получилось:

Код


function GetSetElementCount( ASetPtr: Pointer; ASize: Integer ): Integer;
var
  lByte: Byte;
  i, j: Integer;
begin
  Result := 0;
  if (ASetPtr = nil) or (ASize = 0) then Exit;
  for i := 0 to pred(ASize) do //по всем байтам, содержащих множество
  begin
    lByte := Byte( Pointer(dword(ASetPtr)+i)^); //берем Nый байт от начала...
    if lByte = 0 then continue; //зачем проверять "пустой" байт.
    for j := 1 to 8 do
    begin
      if Boolean(lByte and $01) then Inc( Result ); //если первый бит = 1 то инкременируем
      lByte := lByte shr 1; //сдвигаем содержимое байта вправо
      if lByte = 0 then Break; //если в байте нет битов =1, то прерываем цикл.
    end;
  end;
end;

//пример использования
procedure TForm1.btn1Click(Sender: TObject);
type
   TEnum = 1..255; //некий тип
   TSet = set of TEnum;//и множество
var
  lSet: TSet;
  lCount: Integer;
begin
  lSet := [1,2,10,11,200]; //что-то задаем
  lCount := GetSetElementCount( @lSet, SizeOf( lSet ) ); //и сколько ж мы задали?
  ShowMessage(Format('lSet elements count: %d',[lCount])); //АГА!!!
end;

конечно же на асме это получилось бы быстрее и оптимальнее, но я в нем не силен)
жду критики smile

з.ы. эх не увидел. у меня почти то же, что и ранее Girder выкладывал...

Это сообщение отредактировал(а) MetalFan - 31.5.2007, 11:52

--------------------

There are always someone smarter than you...

Delphist

Дата 31.5.2007, 12:02 (ссылка)

(нет голосов)

Загрузка ...

Delphist Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 2145
Регистрация: 3.2.2004
Где: всегда в сети

Репутация: 2
Всего: 3

Это как раз то универсальный меотд если set of назначается от перечислимого типа, то мы всегда знаем перечислимый тип и множественный. поэтому всегда может найти кол-во элементов в множественном типе. Вот этот код я хотел бы увидеть 25.10.2006, т.е. тогда, когда я сформулировал вопрос он бы сильно мне помог.

Добавлено через 3 минуты и 24 секунды

Цитата(MetalFan @ 31.5.2007, 12:48

)

вот накидал универсальный пример, исходя из следующих соображений:

И в чем твой пример превосходит мой, он еще более торможеннее работает. smile

--------------------

Alexeis

Дата 31.5.2007, 12:10 (ссылка)

(нет голосов)

Загрузка ...

Амеба

Профиль
Группа: Админ
Сообщений: 11743
Регистрация: 12.10.2005
Где: Зеленоград

Репутация: 109
Всего: 459

Delphist, ну и зря, код Гирдера во много раз быстрее.

--------------------

Vit вечная память.

Обсуждение действий администрации форума производятся только в этом форуме

гениальность идеи состоит в том, что ее невозможно придумать

Delphist

Дата 31.5.2007, 13:58 (ссылка)

(нет голосов)

Загрузка ...

Delphist Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 2145
Регистрация: 3.2.2004
Где: всегда в сети

Репутация: 2
Всего: 3

Цитата(Alexeis @ 31.5.2007, 13:10

)

Delphist, ну и зря, код Гирдера во много раз быстрее.

Не знаю, не знаю но мой код намного нагляднее

--------------------

MetalFan

Дата 31.5.2007, 15:49 (ссылка)

(нет голосов)

Загрузка ...

Аццкий Сотона

Профиль
Группа: Комодератор
Сообщений: 3815
Регистрация: 2.10.2006
Где: Moscow

Репутация: 62
Всего: 128

Цитата(Delphist @ 31.5.2007, 13:58

)

мой код намного нагляднее

типизированность параметров функции подсчета. основной минус.
если у меня 3 типа множеств, то придется для каждого писать свою функцию

--------------------

There are always someone smarter than you...

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »