VPF::WMI - Форум программистов

bagos

Дата 19.7.2007, 21:03 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 275
Регистрация: 17.6.2006

Репутация: нет
Всего: 1

Собственно вылезает ошибка "Недопустимая строка указания класса."
Что делаю не так?
objWMIService := CreateOleObject('winmgmts:\\xzxz\root\cimv2');

_RIM_

Дата 19.7.2007, 22:44 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Awaiting Authorisation
Сообщений: 26
Регистрация: 7.7.2007
Где: СПб

Репутация: нет
Всего: нет

Ты опиши полностью задачу - и кусок кода.
А так ты будешь вечно искать ответ на свой вопрос.
smile

bagos

Дата 19.7.2007, 23:16 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 275
Регистрация: 17.6.2006

Репутация: нет
Всего: 1

пытаюсь поменять IP с помощью WMI.

Код


var
i:integer;
objNetAdapter,objWMIService,colNetAdapters:Variant;
strGatewayMetric,strComputer,strIPAddress,strSubnetMask,strGateway,strDNSserver ,strMACadapter :string;
errEnable,errGateways,errDNS : string;
begin
strComputer := 'xzsoft';
objWMIService := CreateOleObject('winmgmts:\\' + strComputer + '\root\cimv2');
colNetAdapters := objWMIService.ExecQuery('Select * from Win32_NetworkAdapterConfiguration where IPEnabled=TRUE');

strIPAddress  := '***.***.***.***';
strSubnetMask := '***.***.***.***';
strGateway    := '***.***.***.***';
strDNSserver  := '***.***.***.***';
strMACadapter := '00:00:00:00:00:00';

strGatewayMetric := '';

For i := 0 to colNetAdapters.Count - 1 do begin
objNetAdapter := colNetAdapters[i];
If objNetAdapter.MACAddress = strMACadapter then begin
  errEnable := objNetAdapter.EnableStatic(strIPAddress, strSubnetMask);
  errGateways := objNetAdapter.SetGateways(strGateway, strGatewaymetric);
  errDNS := objNetAdapter.SetDNSServerSearchOrder(strDNSServer);
end;
end;

M
Alexeis

Модератор: используйте подсветку кода http://forum.vingrad.ru/index.php?show_typ...howtopic=126445

Это сообщение отредактировал(а) Alexeis - 19.7.2007, 23:18

Yanis

Дата 21.7.2007, 16:13 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 2937
Регистрация: 9.2.2004
Где: Москва

Репутация: 72
Всего: 111

Ну сделай при помощи TSWbemLocator.

Добавлено через 53 секунды
Вообще на VBS это всегда замечательно прокатывало что то типа:

Код

strComputer = "." 
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2") 
' Obtain an instance of the the class 
' using a key property value.
Set objShare = objWMIService.Get("Win32_NetworkAdapterConfiguration.Index='1'")

' Obtain an InParameters object specific
' to the method.
Set objInParam = objShare.Methods_("EnableStatic"). _
    inParameters.SpawnInstance_()


' Add the input parameters.
objInParam.Properties_.Item("IPAddress") =  "192.168.0.1"
objInParam.Properties_.Item("SubnetMask") =  "255.255.255.0"

' Execute the method and obtain the return status.
' The OutParameters object in objOutParams
' is created by the provider.
Set objOutParams = objWMIService.ExecMethod("Win32_NetworkAdapterConfiguration.Index='1'", "EnableStatic", objInParam)

' List OutParams
Wscript.Echo "Out Parameters: "
Wscript.echo "ReturnValue: " & objOutParams.ReturnValue

Добавлено через 2 минуты и 15 секунд
Но если этот код портировать в Delphi, то выскакивает ошибка :(

--------------------

*щёлк*

bagos

Дата 23.7.2007, 14:58 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 275
Регистрация: 17.6.2006

Репутация: нет
Всего: 1

и че делать будем ?

Yanis

Дата 23.7.2007, 20:12 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 2937
Регистрация: 9.2.2004
Где: Москва

Репутация: 72
Всего: 111

Цитата(Yanis @ 21.7.2007, 17:13

)

сделай при помощи TSWbemLocator.

WMI - практика применения в Delphi.

--------------------

*щёлк*

bagos

Дата 23.7.2007, 23:02 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 275
Регистрация: 17.6.2006

Репутация: нет
Всего: 1

получилось, получаю данные, но проблема появилась при вытаскивании самого ip,

MSDN:
IPAddress
Data type: string array
Access type: Read-only

Array of all of the IP addresses associated with the current network adapter. Starting with Windows Vista, this property can contain either IPv6 addresses or IPv4 addresses. For more information, see IPv6 and IPv4 Support in WMI.

Example IPv6 address: "2010:836B:4179::836B:4179"
Windows Server 2003, Windows XP, Windows 2000, and Windows NT 4.0: This property contains addresses in IPv4 format.

Example: "172.16.22.0"

при обычном

Код



 if Sprop.Name = 'IPAddress' then
        label8.caption := Sprop.Get_Value;

вылезает ошибка:
Could not convert variant of type (Array variant) into type (String)

Как быть? smile

Yanis

Дата 24.7.2007, 09:25 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 2937
Регистрация: 9.2.2004
Где: Москва

Репутация: 72
Всего: 111

Попробуй через for Element in ArrayExpr do Stmt.

--------------------

*щёлк*

bagos

Дата 24.7.2007, 09:34 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 275
Регистрация: 17.6.2006

Репутация: нет
Всего: 1

у меня delphi 7, а это вроде для 2005

Yanis

Дата 24.7.2007, 10:27 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 2937
Регистрация: 9.2.2004
Где: Москва

Репутация: 72
Всего: 111

Цитата(bagos @ 24.7.2007, 10:34

)

у меня delphi 7

А ну пардон smile

Тогда работай с вариантными массивами. Смотри функции модуля Variants.pas. Там точно есть.

--------------------

*щёлк*

bagos

Дата 24.7.2007, 12:35 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 275
Регистрация: 17.6.2006

Репутация: нет
Всего: 1

пока получилось брать ip, а изменять его как?
на  MSDN:

IPAddress
   Data type: string array
   Access type: Read-only

получается с помощью WMI нельзя "изменять"?

Yanis

Дата 24.7.2007, 15:22 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 2937
Регистрация: 9.2.2004
Где: Москва

Репутация: 72
Всего: 111

Я же привёл код. У класса Win32_NetworkAdapterConfiguration есть метод EnableStatic.

Это сообщение отредактировал(а) Yanis - 24.7.2007, 15:23

--------------------

*щёлк*

bagos

Дата 24.7.2007, 17:35 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 275
Регистрация: 17.6.2006

Репутация: нет
Всего: 1

Делаю так:

Код


    SObject:= Service.Get('Win32_NetworkAdapterConfiguration.Index="1"', 0, nil);
    Method:= SOBject.Methods_.Item('EnableStatic', 0);
    InParam:= Method.InParameters.SpawnInstance_(0);
    MyProperty:= InParam.Properties_.Item('IPAddress',0);
    PropValue:= '192.168.0.123';
    MyProperty.Set_Value(PropValue);
    OutParam:= SObject.ExecMethod_('EnableStatic', InParam, 0, nil);
    SProp1:= outParam.Properties_.Item('ReturnValue', 0);

Где та не правильно делаю...

Yanis

Дата 30.7.2007, 19:21 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Участник Клуба
Сообщений: 2937
Регистрация: 9.2.2004
Где: Москва

Репутация: 72
Всего: 111

Код

uses ComObj, ActiveX, UrlMon;

// ======================================================================
// SetIpConfig()
// Set IPAddress, Gateway and Subnetmask via WMI
// Arguments ...
// AIpAddress - If Null String or 'DHCP' then DHCP is ENABLED
//              else STATIC IP is set.
// AGateWay   - [Optional] If Omitted then GATEWAY is left unchanged.
// SubnetMask - [Optional] If Omited then default = '255.255.255.0'.
//
// SetDnsServers()
// Set  DNS Servers via WMI
// Arguments ...
// APrimaryDNS   - If Null String then DNS Server List is CLEARED.
// AAlternateDNS - [Optional]
//
// Return Values ...
//   0 Successful completion, no reboot required.
//   1 Successful completion, reboot required.
//  -1 Unknown OLE Error
//  64 Method not supported on this platform.
//  65 Unknown failure.
//  66 Invalid subnet mask.
//  67 An error occurred while processing an instance that was returned.
//  68 Invalid input parameter.
//  69 More than five gateways specified.
//  70 Invalid IP address.
//  71 Invalid gateway IP address.
//  72 An error occurred while accessing the registry for the info.
//  73 Invalid domain name.
//  74 Invalid host name.
//  75 No primary or secondary WINS server defined.
//  76 Invalid file.
//  77 Invalid system path.
//  78 File copy failed.
//  79 Invalid security parameter.
//  80 Unable to configure TCP/IP service.
//  81 Unable to configure DHCP service.
//  82 Unable to renew DHCP lease.
//  83 Unable to release DHCP lease.
//  84 IP not enabled on adapter.
//  85 IPX not enabled on adapter.
//  86 Frame/network number bounds error.
//  87 Invalid frame type.
//  88 Invalid network number.
//  89 Duplicate network number.
//  90 Parameter out of bounds.
//  91 Access denied.
//  92 Out of memory.
//  93 Already exists.
//  94 Path, file, or object not found.
//  95 Unable to notify service.
//  96 Unable to notify DNS service.
//  97 Interface not configurable.
//  98 Not all DHCP leases could be released or renewed.
//  100 DHCP not enabled on adapter.
// ======================================================================


// ==================================================================
// IP Address,Gateway and Subnet Mask
// EnableStatic takes array of string as a parameter
// for the Addresses. You may wish to rewrite this using
// array of string as parameter for multiple IP Addresses.
// I only have use for 1 IP address and Gateway in our application
// but it's nice to be able to expand it for other users.
// ==================================================================

function SetIpConfig(const AIpAddress : string;
                     const AGateWay : string = '';
                     const ASubnetMask : string = '') : integer;
var Retvar : integer;
    oBindObj : IDispatch;
    oNetAdapters,oNetAdapter,
    oIpAddress,oGateWay,
    oWMIService,oSubnetMask : OleVariant;
    i,iValue : longword;
    oEnum : IEnumvariant;
    oCtx : IBindCtx;
    oMk : IMoniker;
    sFileObj : widestring;
begin
  Retvar := 0;
  sFileObj := 'winmgmts:\\.\root\cimv2';

  // Create OLE [IN} Parameters
  oIpAddress := VarArrayCreate([1,1],varOleStr);
  oIpAddress[1] := AIpAddress;
  oGateWay := VarArrayCreate([1,1],varOleStr);
  oGateWay[1] := AGateWay;
  oSubnetMask := VarArrayCreate([1,1],varOleStr);
  if ASubnetMask = '' then
    oSubnetMask[1] := '255.255.255.0'
  else
    oSubnetMask[1] := ASubnetMask;

  // Connect to WMI - Emulate API GetObject()
  OleCheck(CreateBindCtx(0,oCtx));
  OleCheck(MkParseDisplayNameEx(oCtx,PWideChar(sFileObj),i,oMk));
  OleCheck(oMk.BindToObject(oCtx,nil,IUnknown,oBindObj));
  oWMIService := oBindObj;

  oNetAdapters := oWMIService.ExecQuery('Select * from ' +
                                        'Win32_NetworkAdapterConfiguration ' +
                                        'where IPEnabled=TRUE');
  oEnum := IUnknown(oNetAdapters._NewEnum) as IEnumVariant;

  while oEnum.Next(1,oNetAdapter,iValue) = 0 do begin
    try
      // Set by DHCP ? (Gateway and Subnet ignored)
      if (AIpAddress = '') or SameText(AIpAddress,'DHCP') then
        Retvar := oNetAdapter.EnableDHCP
      // Set via STATIC ?
      else begin
        Retvar := oNetAdapter.EnableStatic(oIpAddress,oSubnetMask);
        // Change Gateway ?
        if (Retvar = 0) and (AGateWay <> '') then
          Retvar := oNetAdapter.SetGateways(oGateway);

        // *** This is where we need some sort of ***
        // *** Network Mapped Resource Refresh    ***
      end;
    except
      Retvar := -1;
    end;

    oNetAdapter := Unassigned;
  end;

  oGateWay := Unassigned;
  oSubnetMask := Unassigned;
  oIpAddress := Unassigned;
  oNetAdapters := Unassigned;
  oWMIService := Unassigned;
  Result := Retvar;
end;


// ====================================================
// Set DNS Servers
// Instead of Primary and Alternate you may wish
// to rewrite this using array of string as the
// parameters as SetDNSServerSearchOrder will take
// a list of many DNS addresses. I only have use for
// Primary and Alternate.
// ====================================================

function SetDnsServers(const APrimaryDNS : string;
                       const AAlternateDNS : string = '') : integer;
var Retvar : integer;
    oBindObj : IDispatch;
    oNetAdapters,oNetAdapter,
    oDnsAddr,oWMIService : OleVariant;
    i,iValue,iSize : longword;
    oEnum : IEnumvariant;
    oCtx : IBindCtx;
    oMk : IMoniker;
    sFileObj : widestring;
begin
  Retvar := 0;
  sFileObj := 'winmgmts:\\.\root\cimv2';
  iSize := 0;
  if APrimaryDNS <> '' then inc(iSize);
  if AAlternateDNS <> '' then inc(iSize);

  // Create OLE [IN} Parameters
  if iSize > 0 then begin
   oDnsAddr := VarArrayCreate([1,iSize],varOleStr);
   oDnsAddr[1] := APrimaryDNS;
   if iSize > 1 then oDnsAddr[2] := AAlternateDNS;
  end;

  // Connect to WMI - Emulate API GetObject()
  OleCheck(CreateBindCtx(0,oCtx));
  OleCheck(MkParseDisplayNameEx(oCtx,PWideChar(sFileObj),i,oMk));
  OleCheck(oMk.BindToObject(oCtx,nil,IUnknown,oBindObj));
  oWMIService := oBindObj;

  oNetAdapters := oWMIService.ExecQuery('Select * from ' +
                                        'Win32_NetworkAdapterConfiguration ' +
                                        'where IPEnabled=TRUE');
  oEnum := IUnknown(oNetAdapters._NewEnum) as IEnumVariant;

  while oEnum.Next(1,oNetAdapter,iValue) = 0 do begin
    try
      if iSize > 0 then
        Retvar := oNetAdapter.SetDNSServerSearchOrder(oDnsAddr)
      else
        Retvar := oNetAdapter.SetDNSServerSearchOrder();
    except
      Retvar := -1;
    end;

    oNetAdapter := Unassigned;
  end;

  oDnsAddr := Unassigned;
  oNetAdapters := Unassigned;
  oWMIService := Unassigned;
  Result := Retvar;
end;

--------------------

*щёлк*

bagos

Дата 31.7.2007, 13:38 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 275
Регистрация: 17.6.2006

Репутация: нет
Всего: 1

Спасибо, то что надо smile

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »