Модераторы: Poseidon, Snowy, bems, MetalFan

Поиск:

Ответ в темуСоздание новой темы Создание опроса
> Как удалить кнопку, Как удалить кнопку через ее же onClick 
V
    Опции темы
Mina
Дата 26.11.2007, 12:40 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 83
Регистрация: 11.11.2005

Репутация: нет
Всего: нет
Кнопки создаются в Run-time.
Если возможно, то как удалить кнопки, при нажатии на них самих.
Вот код

Код

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure MyButtonClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;


var
  Form1: TForm1;
  b: array of TButton;
  i: integer;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
 Inc(i);
 SetLength(b, i);
 b[i - 1]:= TButton.Create(Self);
 b[i - 1].Parent:= Self;
 b[i - 1].Name:= 'But' + IntToStr(i);
 b[i - 1].Caption:= b[i - 1].Name;
 b[i - 1].Top:= i * 30;
 b[i - 1].OnClick:= MyButtonClick;
end;



procedure TForm1.MyButtonClick(Sender: TObject);
begin
// Что здесь написать для удаления кнопки
end;




Что написать в обработчике события кнопки
PM MAIL   Вверх
Romkin
Дата 26.11.2007, 13:13 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Бывалый
*


Профиль
Группа: Участник
Сообщений: 189
Регистрация: 14.11.2006
Где: Москва

Репутация: 2
Всего: 5
Послать сообщение форме с просьбой удалить self. Смотри TForm.Release. Просто делать self.Free крайне не рекомендую. 
PM ICQ   Вверх
WaReZMEN
Дата 26.11.2007, 13:20 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Опытный
**


Профиль
Группа: Участник
Сообщений: 683
Регистрация: 9.6.2006
Где: Россия, Санкт-Пет ербург

Репутация: нет
Всего: 3
Можно сделать так 
Код

procedure TForm1.MyButtonClick(Sender: TObject);
begin
  Sender.Destroy;
end;

НО, удалять можно будет только в том порядке в котором создавались кнопки...
И вообще не рекамендую smile

Это сообщение отредактировал(а) WaReZMEN - 26.11.2007, 13:24
PM MAIL ICQ   Вверх
Poseidon
Дата 26.11.2007, 14:26 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Delphi developer
****


Профиль
Группа: Комодератор
Сообщений: 5273
Регистрация: 4.2.2005
Где: Гомель, Беларусь

Репутация: 53
Всего: 133
Удалить корректно сможет только зачистчик Windows после закрытия программы. Так что я бы рекомендовал просто "скрыть".

Код
procedure TForm1.MyButtonClick(Sender: TObject);
begin
(Sender as TButton).Parent:= nil;
end;



--------------------
Если хочешь, что бы что-то работало - используй написанное, 
если хочешь что-то понять - пиши сам...
PM MAIL ICQ   Вверх
MetalFan
Дата 26.11.2007, 15:33 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Аццкий Сотона
****


Профиль
Группа: Комодератор
Сообщений: 3815
Регистрация: 2.10.2006
Где: Moscow

Репутация: 62
Всего: 128
Цитата(Romkin @  26.11.2007,  13:13 Найти цитируемый пост)
Послать сообщение форме с просьбой удалить

самое верное из всех приведенных решение имхо. как-то так:
Код

interface
const
  WM_FREEOBJECT = WM_APP + 1;
...
  procedure Button1Click( Sender: TObject );
  procedure OnWMFreeObject( var AMsg: TMessage ); message WM_FREEOBJECT;
..
implementation

  procedure TForm1.Button1Click( Sender: TObject );
  begin
    PostMessage( Self.Handle, WM_FREEOBJECT, Integer(Sender), 0 );
  end;

  procedure TForm1.OnWMFreeObject( var AMsg: TMessage );
  begin
    TObject( AMsg.LParam ).Free;
  end;



Это сообщение отредактировал(а) MetalFan - 26.11.2007, 15:33


--------------------
There are always someone smarter than you...
PM MAIL   Вверх
Rennigth
Дата 26.11.2007, 15:51 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1708
Регистрация: 21.6.2004
Где: Moscow

Репутация: 49
Всего: 76
Цитата(WaReZMEN @  26.11.2007,  13:20 Найти цитируемый пост)
Можно сделать так 

код Pascal/Delphi
1:
2:
3:
4:

procedure TForm1.MyButtonClick(Sender: TObject);
begin
  Sender.Destroy;
end;

НО, удалять можно будет только в том порядке в котором создавались кнопки...
И вообще не рекамендую 


Ага, и словить при этом в большой долей вероятности AV или abstract error, или еще что похуже!!



--------------------
(* Honesta mors turpi vita potior *)
PM MAIL ICQ   Вверх
Lexicss
Дата 26.11.2007, 16:48 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Бывалый
*


Профиль
Группа: Участник
Сообщений: 197
Регистрация: 16.8.2006
Где: Беларусь, Минск

Репутация: нет
Всего: 1
Фактически можно сделать так:
Код

procedure TForm1.MyButtonClick(Sender: TObject);
begin
  b[i - 1].Parent := nil;
  b[i - 1].Free;
end;



Делфи в данный момент никаких ошибок не выдаёт, но теоритически это неправильно, по крайней мере в документации написано, что так делать не рекомендуются - выполнять уничтожение кнопки из события вызванного по её нажатию. 

Более красивый вариант предложен от MetalFan. Только позволю себе заметить, что правильнее будет указать в обработчике код TObject( AMsg.WParam ).Free; (а не LParam)

--------------------
Бери от жизни всё.
PM MAIL WWW ICQ Skype   Вверх
MetalFan
Дата 26.11.2007, 16:51 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Аццкий Сотона
****


Профиль
Группа: Комодератор
Сообщений: 3815
Регистрация: 2.10.2006
Где: Moscow

Репутация: 62
Всего: 128
Lexicss, да знаешь ли... взял за правило примеры с ошибочками приводить, чтобы головой думали))))
но здесь реально перепутал, ибо писал на коленке без проверки в IDE


--------------------
There are always someone smarter than you...
PM MAIL   Вверх
Alexeis
Дата 26.11.2007, 17:24 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Амеба
Group Icon


Профиль
Группа: Админ
Сообщений: 11743
Регистрация: 12.10.2005
Где: Зеленоград

Репутация: 109
Всего: 459
Никаких проблем не должно быть при простом банальном удалении.
См код.
Код

destructor TComponent.Destroy;
begin
  Destroying;
  if FFreeNotifies <> nil then
  begin
    while Assigned(FFreeNotifies) and (FFreeNotifies.Count > 0) do
      TComponent(FFreeNotifies[FFreeNotifies.Count - 1]).Notification(Self, opRemove);
    FreeAndNil(FFreeNotifies);
  end;
  DestroyComponents;
//----------------------------------------------------------------------------------
  if FOwner <> nil then FOwner.RemoveComponent(Self);
//----------------------------------------------------------------------------------
  inherited Destroy;
end;

Все компоненты удаляют себя у родителей. Глюки в чем-то другом.

Добавлено через 2 минуты и 25 секунд
p.s. пример из первого поста отлично работает.

Добавлено через 14 минут и 20 секунд
На всякий случай проверил нет ли обращений к полям данных после вызова обработчика OnClick. Действительно нет никаких обращений, вполне допустимые действия.


--------------------
Vit вечная память.

Обсуждение действий администрации форума производятся только в этом форуме

гениальность идеи состоит в том, что ее невозможно придумать
PM ICQ Skype   Вверх
Rennigth
Дата 26.11.2007, 17:39 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1708
Регистрация: 21.6.2004
Где: Moscow

Репутация: 49
Всего: 76
Цитата(Alexeis @  26.11.2007,  17:24 Найти цитируемый пост)
Никаких проблем не должно быть при простом банальном удалении.
См код.

код Pascal/Delphi
1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:

destructor TComponent.Destroy;
begin
  Destroying;
  if FFreeNotifies <> nil then
  begin
    while Assigned(FFreeNotifies) and (FFreeNotifies.Count > 0) do
      TComponent(FFreeNotifies[FFreeNotifies.Count - 1]).Notification(Self, opRemove);
    FreeAndNil(FFreeNotifies);
  end;
  DestroyComponents;
//----------------------------------------------------------------------------------
  if FOwner <> nil then FOwner.RemoveComponent(Self);
//----------------------------------------------------------------------------------
  inherited Destroy;
end;





Все компоненты удаляют себя у родителей. Глюки в чем-то другом.

Добавлено через 2 минуты и 25 секунд
p.s. пример из первого поста отлично работает. 


Проблемы будут не из-за какого-то неправильного дестроя,а в ситуации например такой(код вымышленный):

Код

 
procedure TSomeObject.DoClick;
begin
  if Assigned(FOnClick) then
    FOnClick(Self); тут происходит уничтожение объекта.

//после этого мы обращаемся к полям не существующего объекта
  Font.Size := 12;
  DoResize;
  DoPaint;
end;

Что произойдет одному всевышнему известно. Проблемма не в том что именно для кнопки это прокатывает, а в том что мы не знаем, есть ли обращения к полям/методам класса после его разрушения или нет. Это априори опасно!!! smile



--------------------
(* Honesta mors turpi vita potior *)
PM MAIL ICQ   Вверх
Alexeis
Дата 26.11.2007, 17:52 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Амеба
Group Icon


Профиль
Группа: Админ
Сообщений: 11743
Регистрация: 12.10.2005
Где: Зеленоград

Репутация: 109
Всего: 459
Цитата(Rennigth @  26.11.2007,  17:39 Найти цитируемый пост)
Проблемы будут не из-за какого-то неправильного дестроя,а в ситуации например такой(код вымышленный):

  Для того и учатся правильно писать код. Не писать же код с поправкой на дурака  smile Большинство таких поправок уже сделала VCL  smile 


--------------------
Vit вечная память.

Обсуждение действий администрации форума производятся только в этом форуме

гениальность идеи состоит в том, что ее невозможно придумать
PM ICQ Skype   Вверх
Romkin
Дата 26.11.2007, 17:58 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Бывалый
*


Профиль
Группа: Участник
Сообщений: 189
Регистрация: 14.11.2006
Где: Москва

Репутация: 2
Всего: 5
TComponent - далеко. TWinControl - оно ближе. А там окно.
Хотя такое выглядит допустимым, но я не уверен.
PM ICQ   Вверх
Alexeis
Дата 26.11.2007, 18:11 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Амеба
Group Icon


Профиль
Группа: Админ
Сообщений: 11743
Регистрация: 12.10.2005
Где: Зеленоград

Репутация: 109
Всего: 459
Цитата(Romkin @  26.11.2007,  17:58 Найти цитируемый пост)
TComponent - далеко. TWinControl - оно ближе. А там окно.

  Детишок контролы определяют как TComponent, потому нужный код следовало искать именно там, а TWinControl как TWinControl у него свой деструктор уничтожающий окно, только и всего. 
  Многие сообщения реализуются именно в TComponent благодаря VCL. 


--------------------
Vit вечная память.

Обсуждение действий администрации форума производятся только в этом форуме

гениальность идеи состоит в том, что ее невозможно придумать
PM ICQ Skype   Вверх
Rennigth
Дата 26.11.2007, 18:26 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1708
Регистрация: 21.6.2004
Где: Moscow

Репутация: 49
Всего: 76
Цитата(Alexeis @  26.11.2007,  17:52 Найти цитируемый пост)
Большинство таких поправок уже сделала VCL    

ню незнаю... имхо на vcl надейся а сам не плошай! smile



--------------------
(* Honesta mors turpi vita potior *)
PM MAIL ICQ   Вверх
Alexeis
Дата 26.11.2007, 18:28 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Амеба
Group Icon


Профиль
Группа: Админ
Сообщений: 11743
Регистрация: 12.10.2005
Где: Зеленоград

Репутация: 109
Всего: 459
Rennigth, я уж привык, что логичные вещи в VCL работают так как этого хочеться. 


--------------------
Vit вечная память.

Обсуждение действий администрации форума производятся только в этом форуме

гениальность идеи состоит в том, что ее невозможно придумать
PM ICQ Skype   Вверх
Romkin
Дата 26.11.2007, 20:35 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Бывалый
*


Профиль
Группа: Участник
Сообщений: 189
Регистрация: 14.11.2006
Где: Москва

Репутация: 2
Всего: 5
Цитата(Alexeis @  26.11.2007,  18:11 Найти цитируемый пост)
 Детишок контролы определяют как TComponent, потому нужный код следовало искать именно там, а TWinControl как TWinControl у него свой деструктор уничтожающий окно, только и всего. 

Не совсем так. Достаточно все-таки посмотреть в TWinControl.Destroy. За окнами следит окно, если речь о детишках.
Но главное действие - да, уничтожается хендл.
Все-таки надо смотреть:
Есть кнопка, и на OnClick вызывается Free для нее же. Что происходит: OnClick кнопки вызывается из обработчика сообщения, WM_LBUTTONUP:
Код
procedure TControl.WMLButtonUp(var Message: TWMLButtonUp);
begin
  inherited;
  if csCaptureMouse in ControlStyle then MouseCapture := False;
  if csClicked in ControlState then
  begin
    Exclude(FControlState, csClicked);
    if PtInRect(ClientRect, SmallPointToPoint(Message.Pos)) then Click;
  end;
  DoMouseUp(Message, mbLeft);
end;

procedure TControl.Click;
begin
  { Call OnClick if assigned and not equal to associated action's OnExecute.
    If associated action's OnExecute assigned then call it, otherwise, call
    OnClick. }
  if Assigned(FOnClick) and (Action <> nil) and (@FOnClick <> @Action.OnExecute) then
    FOnClick(Self)
  else if not (csDesigning in ComponentState) and (ActionLink <> nil) then
    ActionLink.Execute(Self)
  else if Assigned(FOnClick) then
    FOnClick(Self);
end;

procedure TControl.DoMouseUp(var Message: TWMMouse; Button: TMouseButton);
begin
  if not (csNoStdEvents in ControlStyle) then
    with Message do MouseUp(Button, KeysToShiftState(Keys), XPos, YPos);
end;

procedure TControl.MouseUp(Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  if Assigned(FOnMouseUp) then FOnMouseUp(Self, Button, Shift, X, Y);
end;

Замечу, что у TButton метод Click перекрыт, но предок вызывается, разумеется. Что видим? В методе Click вызывается обработчик. Допустим, там у нас вызов Free. По стеку выше: при шлепании по кнопке Click вызывается из WMLButtonUp. Смотрим: после вызова Click идет вызов DoMouseUp и MouseUp. Поскольку, я уверен, после выхода из Click объект уже прошел деструктор, а повода предполагать иное нет, то  if Assigned(FOnMouseUp) then FOnMouseUp(Self, Button, Shift, X, Y); обращается к полю уже уничтоженного объекта. Это не слишком элегантно.
Далее. Уничтожение хендла окна в деструкторе. Предположим, что пользователь сделал doubleClick по кнопке. В этом случае идет два сообщения, если память мне не изменяет. Первое - Click. На нем кнопка вызовет деструктор, в котором, как помянуто, уничтожается окно. Мне интересно, что будет, когда второе сообщение придет на уничтоженный хендл...
Но пока: я ошибся где-нибудь или все-таки нет?
PM ICQ   Вверх
Romkin
Дата 26.11.2007, 20:51 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Бывалый
*


Профиль
Группа: Участник
Сообщений: 189
Регистрация: 14.11.2006
Где: Москва

Репутация: 2
Всего: 5
Так. Продолжаю. Я осмелился проверить, что, собственно, происходит. Для этого я написал потомка TButton, немного его поменяв:
Код
type TMyButton = class(TButton)
  procedure FreeInstance; override;
end;

procedure TMyButton.FreeInstance;
begin
  FillMemory(Self, InstanceSize, $DA);
  inherited FreeInstance;
end;

Всего лишь просто забиваем память маской при уничтожении.
Теперь создадим:
Код
procedure TForm9.MyButtonClick(Sender: TObject);
begin
  TMyButton(Sender).Free;
end;

procedure TForm9.Button1Click(Sender: TObject);
begin
  with TMyButton.Create(Self) do
  begin
    Parent := Self;
    Left := 10;
    Top := 10;
    OnClick := MyButtonClick;
  end;
  ShowMessage('Yo!');
end;

Ну и нажмем. 
Access violation at address 004038C6 in module 'Project7.exe'. Read of address DADADADA.

Нет. Не рекомендуется.

Это сообщение отредактировал(а) Romkin - 26.11.2007, 21:07
PM ICQ   Вверх
Alexeis
Дата 26.11.2007, 21:21 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Амеба
Group Icon


Профиль
Группа: Админ
Сообщений: 11743
Регистрация: 12.10.2005
Где: Зеленоград

Репутация: 109
Всего: 459
Romkin, на самом деле объект не так просто уничтожается. После вызова деструктора там еще система чего-то химичит smile

Добавлено @ 21:31
Romkin, более того ошибка возникла в procedure TObject.CleanupInstance; по причине порчи ссылки на VMT  smile 

Хотя таки код 
Код

  if csCaptureMouse in ControlStyle then MouseCapture := False;
  if csClicked in ControlState then
  begin
    Exclude(FControlState, csClicked);
    if PtInRect(ClientRect, SmallPointToPoint(Message.Pos)) then Click;
  end;
  DoMouseUp(Message, mbLeft);

выполняется после освобождения памяти, а тут обращение к полям объекта. Выходит что неправильно, а жаль...


--------------------
Vit вечная память.

Обсуждение действий администрации форума производятся только в этом форуме

гениальность идеи состоит в том, что ее невозможно придумать
PM ICQ Skype   Вверх
Alexeis
Дата 26.11.2007, 22:09 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Амеба
Group Icon


Профиль
Группа: Админ
Сообщений: 11743
Регистрация: 12.10.2005
Где: Зеленоград

Репутация: 109
Всего: 459
Тогда предлагаю такой вариант 
Код

procedure TForm1.MyButtonClick(Sender: TObject);
begin
 (Sender as TControl).perform(WM_CLOSE, 0, 0);
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  with TButton.Create(Self) do
  begin
    Parent := Self;
    Left := 10;
    Top := 10;
    OnClick := MyButtonClick;
  end;
end;

Проверка показала, что в WM_CLOSE срабатывает сразу после WMLButtonUp (без задержки), потому все завершается успешно.


--------------------
Vit вечная память.

Обсуждение действий администрации форума производятся только в этом форуме

гениальность идеи состоит в том, что ее невозможно придумать
PM ICQ Skype   Вверх
Romkin
Дата 26.11.2007, 23:35 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Бывалый
*


Профиль
Группа: Участник
Сообщений: 189
Регистрация: 14.11.2006
Где: Москва

Репутация: 2
Всего: 5
Цитата(Alexeis @  26.11.2007,  21:21 Найти цитируемый пост)
Romkin, на самом деле объект не так просто уничтожается. После вызова деструктора там еще система чего-то химичит 

Оххх. Сорри. ЗАпутался :(
Код

procedure TMyButton.FreeInstance;
begin
  inherited;
  FillMemory(self, InstanceSize, $DA);
end;

Немного нехорошо (виноват, но ничего уже в голову не лезет), но при простом закрытии формы - порядок, а при нажатии - 
Access violation at address 004371D4 in module 'Project7.exe'. Read of address DADADB1E.

А WM_CLOSE я бы все-таки через PostMessage сделал. И после hide. Потому что после WM_LBUTTONUP может скользнуть сообщение.
PM ICQ   Вверх
Alexeis
Дата 26.11.2007, 23:45 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Амеба
Group Icon


Профиль
Группа: Админ
Сообщений: 11743
Регистрация: 12.10.2005
Где: Зеленоград

Репутация: 109
Всего: 459
Цитата(Romkin @  26.11.2007,  23:35 Найти цитируемый пост)
А WM_CLOSE я бы все-таки через PostMessage сделал. И после hide. Потому что после WM_LBUTTONUP может скользнуть сообщение. 

  Да не я дебагом прошел, все отлично. Post прийдет с задержкой. 


--------------------
Vit вечная память.

Обсуждение действий администрации форума производятся только в этом форуме

гениальность идеи состоит в том, что ее невозможно придумать
PM ICQ Skype   Вверх
Mina
Дата 27.11.2007, 07:19 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 83
Регистрация: 11.11.2005

Репутация: нет
Всего: нет
Да, не думал, что все так будет сложно. 
Скорее всего я наверно неверно задал вопрос. По идеи мне нужно удалять этой кнопкой фрейм на котором расположена эта кнопка, но при его удалении 
Код

procedure TFrame2.Button1Click(Sender: TObject);
begin
 FreeAndNil(Self);
end;

возникает ошибка, и как мне кажется из за удаления самой кнопки.
Вот код формы:
Код

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses
 unit2;

var
 Block: array of TFrame2;
 n: integer;

procedure TForm1.Button1Click(Sender: TObject);
begin
 inc(n);
 SetLength(Block, n);
 Block[n - 1]:= TFrame2.Create(Self);
 Block[n - 1].Parent:= Self;
 Block[n - 1].Name:= 'Block' + IntToStr(n);
 Block[n - 1].Label1.Caption:= Block[n - 1].Name;
end;


Код фрейма:
Код

type
  TFrame2 = class(TFrame)
    Button1: TButton;
    Label1: TLabel;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

implementation

{$R *.dfm}

procedure TFrame2.Button1Click(Sender: TObject);
begin
 FreeAndNil(Self);
end;


Может так будет проще решить эту проблему
PM MAIL   Вверх
Romkin
Дата 27.11.2007, 09:49 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Бывалый
*


Профиль
Группа: Участник
Сообщений: 189
Регистрация: 14.11.2006
Где: Москва

Репутация: 2
Всего: 5
Код

procedure TFrame2.Button1Click(Sender: TObject);
begin
   PostMessage(Handle, WM_QUIT, 0, 0);
end;

Так. Класс фрейма переименуй нормально, и привыкай, что автоматические имена, такие как label1, TFrame2 и тд в коде не пишут. К форме это тоже относится.
Block: array of TFrame2; - не нужен тебе, уж поверь. Напиши без него. Не нужно тебе к фрейму обращаться извне, делай так, чтобы фрейм сам обращался куда надо. Тем более, что наращивание массива на 1 постоянно глаза режет ;)
PM ICQ   Вверх
Mina
Дата 27.11.2007, 10:04 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 83
Регистрация: 11.11.2005

Репутация: нет
Всего: нет
Цитата(Romkin @  27.11.2007,  09:49 Найти цитируемый пост)
Класс фрейма переименуй нормально, и привыкай, что автоматические имена, такие как label1, TFrame2 и тд в коде не пишут

Это я знаю, это было написано для примера.

Цитата(Romkin @  27.11.2007,  09:49 Найти цитируемый пост)
Block: array of TFrame2; - не нужен тебе, уж поверь

Мне нужно создавать фреймы в Run-time.
Как тогда без массива создавать фреймы, чтобы потом можно было бы обращаться к компонентам которые на них расположены? 

Цитата(Romkin @  27.11.2007,  09:49 Найти цитируемый пост)
PostMessage(Handle, WM_QUIT, 0, 0);

Попробывал, приложение совсем закрывается, а надо чтобы удалялся фрейм.
PM MAIL   Вверх
Romkin
Дата 27.11.2007, 10:18 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Бывалый
*


Профиль
Группа: Участник
Сообщений: 189
Регистрация: 14.11.2006
Где: Москва

Репутация: 2
Всего: 5
Цитата(Mina @  27.11.2007,  10:04 Найти цитируемый пост)
Как тогда без массива создавать фреймы, чтобы потом можно было бы обращаться к компонентам которые на них расположены? 

Фрейм и без массива хорошо создается. И пиши так, чтобы к компонентам на фрейме не обращаться. Фрейм у тебя - объект. Напиши у него нужные методы и свойства, и обращайся к ним. А лучше вообще не обращаться, с какой целью?
PM ICQ   Вверх
Alexeis
Дата 27.11.2007, 10:28 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Амеба
Group Icon


Профиль
Группа: Админ
Сообщений: 11743
Регистрация: 12.10.2005
Где: Зеленоград

Репутация: 109
Всего: 459
Цитата(Mina @  27.11.2007,  10:04 Найти цитируемый пост)
Попробывал, приложение совсем закрывается, а надо чтобы удалялся фрейм. 

  Потому что не тот хэндл 
(Sender as TControl).perform(WM_CLOSE, 0, 0);


--------------------
Vit вечная память.

Обсуждение действий администрации форума производятся только в этом форуме

гениальность идеи состоит в том, что ее невозможно придумать
PM ICQ Skype   Вверх
Mina
Дата 27.11.2007, 10:28 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 83
Регистрация: 11.11.2005

Репутация: нет
Всего: нет
Цитата(Romkin @  27.11.2007,  10:18 Найти цитируемый пост)
А лучше вообще не обращаться, с какой целью?

На фрейме находятся другие компоненты (Memo, Edit и др.)

Добавлено через 8 минут и 28 секунд
Цитата(Alexeis @  27.11.2007,  10:28 Найти цитируемый пост)
(Sender as TControl).perform(WM_CLOSE, 0, 0); 

Удаляется только кнопка (к стати без ошибки), фрейм со всем остальным остается.
PM MAIL   Вверх
Rennigth
Дата 27.11.2007, 11:21 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1708
Регистрация: 21.6.2004
Где: Moscow

Репутация: 49
Всего: 76
Alexeis, 
Romkin, 
ребят, не хочу вас разочаровывать, но:
1. Вариант с посылкой WM_CLOSE подходит только к классу TCustomForm, с выстановленным CloseAction = caFree в OnClose. Согласитесь не универсальный вариант. 
2. Про WM_QUIT, WM_DESTROY(WM_NCDESTROY) тоже нечего говорить, они ни каким боком не уничтожат WinControl.


Mina, в твоем случае думаю не стоит извращаться, сделай по старинке как в самом начале предлагал MetalFan. В твоем случает это будет выглядеть примерно так:
Код

type
  TFrame2 = class(TFrame)
    Button1: TButton;
    Label1: TLabel;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

implementation

{$R *.dfm}

procedure TFrame2.Button1Click(Sender: TObject);
begin
  PostMessage(Handle, WM_FREEOBJECT, Integer(Self), 0);
end;


Код

const
  WM_FREEOBJECT = WM_APP + 1;
  TForm1 = class(TForm)
  //...
  private
    procedure OnWMFreeObject(var VMsg: TMessage ); message WM_FREEOBJECT;
  //...
  end;

implementation
//...
procedure TForm1.OnWMFreeObject(var VMsg: TMessage );
begin
  TObject(AMsg.WParam).Free;
end;




--------------------
(* Honesta mors turpi vita potior *)
PM MAIL ICQ   Вверх
Mina
Дата 27.11.2007, 12:12 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 83
Регистрация: 11.11.2005

Репутация: нет
Всего: нет
Ругается на строку
Цитата(Rennigth @  27.11.2007,  11:21 Найти цитируемый пост)
TObject(AMsg.WParam).Free;
PM MAIL   Вверх
Rennigth
Дата 27.11.2007, 12:29 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1708
Регистрация: 21.6.2004
Где: Moscow

Репутация: 49
Всего: 76
TObject(VMsg.WParam).Free

писал в браузер 


--------------------
(* Honesta mors turpi vita potior *)
PM MAIL ICQ   Вверх
Mina
Дата 27.11.2007, 12:45 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 83
Регистрация: 11.11.2005

Репутация: нет
Всего: нет
Rennigth, 
Фрейм удаляется, а что на нем находится нет.
После удаления и при создании нового фрейма появляются старые.
Вот исходник что у меня получилось

Присоединённый файл ( Кол-во скачиваний: 3 )
Присоединённый файл  Proba.rar 10,16 Kb
PM MAIL   Вверх
Rennigth
Дата 27.11.2007, 13:14 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Эксперт
***


Профиль
Группа: Участник Клуба
Сообщений: 1708
Регистрация: 21.6.2004
Где: Moscow

Репутация: 49
Всего: 76
паренту надо было слать... smile

Присоединённый файл ( Кол-во скачиваний: 7 )
Присоединённый файл  Proba.rar 13,92 Kb


--------------------
(* Honesta mors turpi vita potior *)
PM MAIL ICQ   Вверх
Mina
Дата 28.11.2007, 04:53 (ссылка) | (нет голосов) Загрузка ... Загрузка ... Быстрая цитата Цитата


Шустрый
*


Профиль
Группа: Участник
Сообщений: 83
Регистрация: 11.11.2005

Репутация: нет
Всего: нет
Rennigth, спасибо огромное. То что нужно было. smile 
PM MAIL   Вверх
Страницы: (3) [Все] 1 2 3 
 Ответ в темуСоздание новой темы Создание опроса
Правила форума "Delphi: Общие вопросы"
SnowyMetalFan
bemsPoseidon
Rrader

Запрещается!

1. Публиковать ссылки на вскрытые компоненты

2. Обсуждать взлом компонентов и делиться вскрытыми компонентами

  • Литературу по Дельфи обсуждаем здесь
  • Действия модераторов можно обсудить здесь
  • С просьбами о написании курсовой, реферата и т.п. обращаться сюда
  • Вопросы по реализации алгоритмов рассматриваются здесь
  • 90% ответов на свои вопросы можно найти в DRKB (Delphi Russian Knowledge Base) - крупнейшем в рунете сборнике материалов по Дельфи

Если Вам понравилась атмосфера форума, заходите к нам чаще! С уважением, Snowy, MetalFan, bems, Poseidon, Rrader.
 
0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема | Delphi: Общие вопросы | Следующая тема »

Подписаться на тему | Подписка на этот форум | Скачать/Распечатать тему


 




[ Время генерации скрипта: 0.0916 ]   [ Использовано запросов: 22 ]   [ GZIP включён ]


Реклама на сайте     Информационное спонсорство

 
 По вопросам размещения рекламы пишите на vladimir(sobaka)vingrad.ru
Отказ от ответственности     Powered by Invision Power Board(R) 1.3 © 2003  IPS, Inc.