VPF::Внешние диски - Форум программистов

GorbunovDiman

Дата 8.3.2008, 10:23 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 89
Регистрация: 3.3.2008

Репутация: нет
Всего: нет

Как узнать информацию о диске? Мол кто есть кто. Наприер мне надо узнать имя сидирома или флешки!

Akina

Дата 8.3.2008, 21:45 (ссылка)

(нет голосов)

Загрузка ...

Советчик

Профиль
Группа: Модератор
Сообщений: 20581
Регистрация: 8.4.2004
Где: Зеленоград

Репутация: 34
Всего: 454

Win32_DiskDrive
Win32_DiskDriveToDiskPartition
Win32_DiskPartition
Win32_LogicalDisk
Win32_LogicalDiskToPartition
Получай доступ и читай свойства.

PS. Ни у сидюка, ни у флешки нет имени. Имя есть у раздела.

PPS. Или речь о BiosID?

--------------------

О(б)суждение моих действий - в соответствующей теме, пожалуйста. Или в РМ. И высшая инстанция - Администрация форума.

GorbunovDiman

Дата 11.3.2008, 20:59 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 89
Регистрация: 3.3.2008

Репутация: нет
Всего: нет

Цитата

Win32_DiskDrive
Win32_DiskDriveToDiskPartition
Win32_DiskPartition
Win32_LogicalDisk
Win32_LogicalDiskToPartition
Получай доступ и читай свойства.

Например мне надо узнать является ли диск F локальным или это временный носитель! smile

Пожалуйста распишите мне всё это подробно вмемсте с объялениями переменных!

GorbunovDiman

Дата 20.3.2008, 08:56 (ссылка)

(нет голосов)

Загрузка ...

Шустрый

Профиль
Группа: Участник
Сообщений: 89
Регистрация: 3.3.2008

Репутация: нет
Всего: нет

сдесь идёт GetDriveType smile

mihanik

Дата 20.3.2008, 11:02 (ссылка)

(нет голосов)

Загрузка ...

-=Белый Медведь=-

Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 11
Всего: 109

Вот пример из того проекта, который сейчас делаю...

Код


'********************************************************************
'*
'* Процедура ListDriveTypes
'* Описание: Определяет список всех дисков компьютера
'* Вход    : Нет
'* Выход   : массив DriveList(), содержащий список дисков компьютера
'*
'********************************************************************
Sub ListDriveTypes ()
Dim strComputer, objWMIService, colDisks, objDisk, S, I

    ReDim DriveList(0) ' DriveList объявлен на глобальном уровне
    
    WScript.Echo "Создаём список дисков компьютера..."
    Call WriteEvent(EVENT_SUCCESS, CurrentBuild & ". " & "Создаём список дисков компьютера...")

    strComputer = "."
    S = vbCrLf

Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colDisks = objWMIService.ExecQuery _
    ("Select * from Win32_LogicalDisk")

For Each objDisk in colDisks
    S = S & "DeviceID: "& objDisk.DeviceID & vbCrLf      
    Select Case objDisk.DriveType
        Case 1
            S = S & "No root directory. Drive type could not be " _
                & "determined." & vbCrLf
        Case 2
            S = S & "DriveType: "& "Removable drive." & vbCrLf
        Case 3
            S = S & "DriveType: "& "Local hard disk." & vbCrLf
            ReDim Preserve DriveList (UBound(DriveList)+1)
            DriveList (UBound(DriveList)) = objDisk.DeviceID
        Case 4
            S = S & "DriveType: "& "Network disk."   & vbCrLf    
        Case 5
            S = S & "DriveType: "& "Compact disk."  & vbCrLf     
        Case 6
            S = S & "DriveType: "& "RAM disk."    & vbCrLf
        Case Else
            S = S & "Drive type could not be determined." & vbCrLf
    End Select
Next

        WScript.Echo "Найдены следующие диски:" & vbCrLf & S 
        Call WriteEvent(EVENT_SUCCESS, CurrentBuild & ". " & vbcrlf & "Найдены следующие диски:"  & vbCrLf & S)

        S = "Для работы выбраны жёсткие диски:" & vbCrLf
        For I = 1 To UBound(DriveList)
            S = S & DriveList(I) & vbCrLf
        Next 
        WScript.Echo S
        Call WriteEvent(EVENT_SUCCESS, CurrentBuild & ". " &  S)
        
End Sub

Добавлено через 1 минуту и 20 секунд
Пройедура WriteEvent записывает событие в журнал событий системы с именем "Приложение"

--------------------

Программистами не рождаются, - это родовая травма...

mihanik

Дата 20.3.2008, 12:50 (ссылка)

(нет голосов)

Загрузка ...

-=Белый Медведь=-

Профиль
Группа: Комодератор
Сообщений: 4054
Регистрация: 24.4.2006
Где: г. Тверь

Репутация: 11
Всего: 109

А вот так было в оригинале...

Код


' List Drive Types

' Windows Server 2003 : Yes
' Windows XP : Yes
' Windows 2000 : Yes
' Windows NT 4.0 : Yes
' Windows 98 : Yes

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colDisks = objWMIService.ExecQuery _
    ("Select * from Win32_LogicalDisk")

For Each objDisk in colDisks
    Wscript.Echo "DeviceID: "& objDisk.DeviceID       
    Select Case objDisk.DriveType
        Case 1
            Wscript.Echo "No root directory. Drive type could not be " _
                & "determined."
        Case 2
            Wscript.Echo "DriveType: "& "Removable drive."
        Case 3
            Wscript.Echo "DriveType: "& "Local hard disk."
        Case 4
            Wscript.Echo "DriveType: "& "Network disk."      
        Case 5
            Wscript.Echo "DriveType: "& "Compact disk."      
        Case 6
            Wscript.Echo "DriveType: "& "RAM disk."   
        Case Else
            Wscript.Echo "Drive type could not be determined."
    End Select
Next

--------------------

Программистами не рождаются, - это родовая травма...

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| VB6 \| Следующая тема »