VPF::Сохранить TStringList в файл - Форум программистов

Zlo

Дата 25.5.2008, 00:22 (ссылка)

(нет голосов)

Загрузка ...

Бывалый

Профиль
Группа: Участник
Сообщений: 235
Регистрация: 18.9.2004

Репутация: 1
Всего: 1

Есть функция которая сохраняет в файл вот такую структуру:

Код


type
   SPKcfgStruct=Record
       unicname:string[255];//Уникальное имя конфигурации
       CreateDate:TDateTime;//Дата воздания/редактирования
       AttakType:integer;//Тип контактов
       ContaktList:TStringList;//Список контактов
   end;
cfgFile=SPKcfgStruct;
var
cfg:cfgFile;
f:File of cfgFile;

Код самой функции сохранения:

Код


procedure savespkcfg(s:string);
var
i:integer;
cfgS:TStringList;
begin

    AssignFile(f,s);
    Rewrite(f);
    
    cfgS:=TStringList.Create;
    cfg.ContaktList:=TStringList.Create;

    cfg.unicname:=Form1.Edit2.Text;
    cfg.CreateDate:=Now;
    cfg.AttakType:=0;

    for i:=0 to Form1.ListBox1.Items.Count-1 do begin
         cfgS.Add(Form1.ListBox1.Items.Strings[i]);
    end;


    cfg.ContaktList.Text:=cfgS.Text;


    Write(f,cfg);
    CloseFile(f);

    cfg.ContaktList.Free;
    cfgS.Free;
end;

Фишка в том что поля

Код


unicname
CreateDate
AttakType

сохраняются, а поле ContaktList нет, как быть что делать как исправить?
помогите плиззз!!!!

Rrader

Дата 25.5.2008, 08:40 (ссылка)

(голосов:2)

Загрузка ...

Inspired =)

Профиль
Группа: Экс. модератор
Сообщений: 1535
Регистрация: 7.5.2005

Репутация: 70
Всего: 191

И не будет сохраняться smile

Цитата(Zlo @ 25.5.2008, 07:22

)

как быть что делать как исправить?

Полностью переписать код. Отказаться от TStringList. Судя по коду, он напрямую не нужен.

Код


type
  SPKCfgStruct = record
    UnicName: ShortString; //Уникальное имя конфигурации
    CreateDate: TDateTime; //Дата воздания/редактирования
    AttakType: Longint; //Тип контактов
    ContactList: String; //Список контактов
  end;
  CfgFile = SPKcfgStruct;

var
  Cfg: CfgFile;

...

procedure SaveSPKCfg(FileName: String);
var
  I: Longint;
  F: TFileStream;
begin
  F := TFileStream.Create(FileName, fmCreate);
  try
    Cfg.UnicName := 'SomeText';
    Cfg.CreateDate := Now;
    Cfg.AttakType := 0;
    { Write Data }
    F.Write(Cfg.UnicName, SizeOf(ShortString));
    F.Write(Cfg.CreateDate, SizeOf(TDateTime));
    F.Write(Cfg.AttakType, SizeOf(Longint));
    { Get Items }
    Cfg.ContactList := Form1.ListBox1.Items.Text;
    { Write Text }
    I := Length(Cfg.ContactList);
    F.Write(I, SizeOf(Longint));
    F.Write(Cfg.ContactList[1], I);
  finally
    F.Free;
  end;
end;

procedure LoadSPKCfg(FileName: String);
var
  I: Longint;
  F: TFileStream;
begin
  F := TFileStream.Create(FileName, fmOpenReadWrite or fmShareDenyNone);
  try
    { Read Data }
    F.Read(Cfg.UnicName, SizeOf(ShortString));
    F.Read(Cfg.CreateDate, SizeOf(TDateTime));
    F.Read(Cfg.AttakType, SizeOf(Longint));
    { Read Text }
    F.Read(I, SizeOf(Longint));
    SetLength(Cfg.ContactList, I);
    F.Read(Cfg.ContactList[1], I);
    { Set Items }
    Form1.ListBox1.Items.Text := Cfg.ContactList;
  finally
    F.Free;
  end;
end;

И вот что еще:

Код


for i := 0 to Form1.ListBox1.Items.Count - 1 do 
begin
  cfgS.Add(Form1.ListBox1.Items.Strings[i]);
end;

Не стоит так делать. Стоит делать так:

Код


cfgS.Items.Assign(Form1.ListBox1.Items);

Это сообщение отредактировал(а) Rrader - 6.2.2009, 06:40

--------------------

Let's do this quickly!
Rest in peace, Vit!

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Общие вопросы \| Следующая тема »