VPF::добавление jpg изображений в ресурс

Violina

Дата 10.1.2009, 13:11 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 12
Регистрация: 4.5.2008

Репутация: нет
Всего: нет

Здравствуйте, не подскажите, можно-ли как-то добавить несколько .jpg изображений в один ресурс файл?
спасибо)

Dobermann

Дата 10.1.2009, 13:31 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 992
Регистрация: 7.1.2008

Репутация: нет
Всего: 0

В cmd C:\>copy /b E:\1.jpg+E:\2.jpg+E:\3.jpg E:\123.dat

Violina

Дата 10.1.2009, 13:45 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 12
Регистрация: 4.5.2008

Репутация: нет
Всего: нет

Dobermann, спасибо) - буду пробовать сейчас

Borland_Delphi_6

Дата 10.1.2009, 14:10 (ссылка)

(голосов:1)

Загрузка ...

LoneLINEss

Профиль
Группа: Участник Клуба
Сообщений: 2509
Регистрация: 5.11.2002
Где: in fortune dreams ...

Репутация: нет
Всего: 20

Цитата(Dobermann @ 10.1.2009, 14:31

)

В cmd C:\>copy /b E:\1.jpg+E:\2.jpg+E:\3.jpg E:\123.dat

Навскидку совершенно непонятно, причем тут ресурс файл.

Violina, если мне не изменяет память, это делается так:
1. Создать текстовый документ, в него добавить код:

Код


RCDATA img1 filename1.jpg
RCDATA img2 filename2.jpg

2. Сохранить файл с расширением RC
3. Скомпилировать с помощью brcc32.exe из комлпекта delphi: brcc32 test.rc

На выходе получим test.res с секцией RCDATA и двумя картинками, взятыми из filename1 и filename2 соответственно.

--------------------

Blind Guardian Fan :: BMSTU Student :: A polar bear is a rectangular bear after a coordinate transform.

Мои фотографии

Dobermann

Дата 10.1.2009, 14:17 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 992
Регистрация: 7.1.2008

Репутация: нет
Всего: 0

Код


{Грузим ресурс} 
{$R FOO.RES} 

uses Jpeg; 

procedure LoadJPEGFromRes(TheJPEG : string; ThePicture : TPicture); 
var        
 ResHandle : THandle;        
 MemHandle : THandle;        
 MemStream : TMemoryStream;        
 ResPtr   : PByte;        
 ResSize  : Longint;        
 JPEGImage : TJPEGImage; 
begin        
 ResHandle := FindResource(hInstance, PChar(TheJPEG), 'JPEG');        
 MemHandle := LoadResource(hInstance, ResHandle);        
 ResPtr   := LockResource(MemHandle);        
 MemStream := TMemoryStream.Create;        
 JPEGImage := TJPEGImage.Create;        
 ResSize := SizeOfResource(hInstance, ResHandle);         
 MemStream.SetSize(ResSize);        
 MemStream.Write(ResPtr^, ResSize);        
 FreeResource(MemHandle);        
 MemStream.Seek(0, 0);        
 JPEGImage.LoadFromStream(MemStream);         
 ThePicture.Assign(JPEGImage);        
 JPEGImage.Free;        
 MemStream.Free; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
begin        
 LoadJPEGFromRes('MYJPEG', Image1.Picture); 
end;

THandle

Дата 10.1.2009, 14:27 (ссылка)

(нет голосов)

Загрузка ...

Хранитель Клуба
Group Icon

Награды: 1

Профиль
Группа: Админ
Сообщений: 3639
Регистрация: 31.7.2007
Где: Moscow, Dubai

Репутация: 50
Всего: 372

Dobermann, к чему это все?

Вопрос как запихнуть в ресурс несколько картинок.

2ТС: Посмотри вот этот пост:
http://forum.vingrad.ru/index.php?showtopi...t&p=1624563

Только в файле rc соответственно несколько записей... Так как сказал Borland_Delphi_6 smile

Violina

Дата 10.1.2009, 19:17 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 12
Регистрация: 4.5.2008

Репутация: нет
Всего: нет

спасибо всем огромное за помощь)
Смотрите, вот что с делала - создала image.rc - написала там
RCDATA img1 01.jpg
RCDATA img2 02.jpg
RCDATA img3 03.jpg
потом все это при помощи cmd.exe превратила в image.RES smile

А вот дальше я коды не поняла немного... можно сделать как-то так, что бы эти катртинки из ресурса грузило в image1 там какой-то - сначала 01.jpg автоматом загружало, а потом при нажатии на баттон - 02.jpg грузило, еще раз нажав - 03.jpg уже и т. д. Вот такого принципа хочу добиться...
спасибо)

AntonN

Дата 10.1.2009, 21:07 (ссылка)

(нет голосов)

Загрузка ...

Опытный

Профиль
Группа: Участник
Сообщений: 491
Регистрация: 8.8.2006

Репутация: 3
Всего: 18

Violina,

Цитата

потом все это при помощи cmd.exe превратила в image.RES

вот тут надо поподробнее - как конкретно через cmd? smile

нужно через brcc32.exe, в потом в самом проекте программы вписать {$R image.RES} и тогда ресурс будет в программе.

--------------------

Violina

Дата 10.1.2009, 21:25 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 12
Регистрация: 4.5.2008

Репутация: нет
Всего: нет

AntonN, да - в cmd.exe написала brcc32 C:\image.rc - ну вообщем тоже самое - просто так я умею только делать)) В программу ресурс {$R image.RES} добавила, а вот как из этого ресурса в TImage извлекать картинки толком не понимаю...

Это сообщение отредактировал(а) Violina - 10.1.2009, 21:29

THandle

Дата 10.1.2009, 22:38 (ссылка)

(голосов:1)

Загрузка ...

Хранитель Клуба
Group Icon

Награды: 1

Профиль
Группа: Админ
Сообщений: 3639
Регистрация: 31.7.2007
Где: Moscow, Dubai

Репутация: 50
Всего: 372

Violina, пример в аттаче.

Присоединённый файл ( Кол-во скачиваний: 11 )

ExResource.rar 337,44 Kb

Violina

Дата 10.1.2009, 22:58 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 12
Регистрация: 4.5.2008

Репутация: нет
Всего: нет

THandle, спасибо) - это я уже качала в ссылке, что Вы давали до этого). Вот не понимаю как сделать, что бы при нажатии на один и тот же баттон меняло картинки) smile

THandle

Дата 10.1.2009, 23:08 (ссылка)

(голосов:1)

Загрузка ...

Хранитель Клуба
Group Icon

Награды: 1

Профиль
Группа: Админ
Сообщений: 3639
Регистрация: 31.7.2007
Где: Moscow, Dubai

Репутация: 50
Всего: 372

Вот пример. Если нужны другие имена картинок/другое количество, измените константу PICTURES_COUNT на количество картинок и измените данные массива.

Код



unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Image1: TImage;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

const
  PICTURES_COUNT = 3;
  PictureNames: Array [1..PICTURES_COUNT] Of String =
    ('KARTINKO1', 'KARTINKO2', 'KARTINKO3');
var
  Form1: TForm1;
  PictureNumber: Byte = 1;

implementation

{$R *.dfm}

uses Jpeg;

procedure LoadJPEGFromRes(const AJPEGName: string; APicture: TPicture);
var
  ResourceStream: TResourceStream;
  JPEGImage: TJPEGImage;
begin
  ResourceStream := TResourceStream.Create(HInstance, AJPEGName, RT_RCDATA);
  try
    JPEGImage := TJPEGImage.Create;
    try
      JPEGImage.LoadFromStream(ResourceStream);
      APicture.Bitmap.Assign(JPEGImage);
    finally
      JPEGImage.Free;
    end;
  finally
    ResourceStream.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  LoadJPEGFromRes(PictureNames[PictureNumber], Image1.Picture);
  if PictureNumber = PICTURES_COUNT then
    PictureNumber := 1
  else
    Inc(PictureNumber);
end;

end.

Проект в аттаче.

Присоединённый файл ( Кол-во скачиваний: 14 )

ExResource.rar 71,46 Kb

Violina

Дата 10.1.2009, 23:55 (ссылка)

(нет голосов)

Загрузка ...

Новичок

Профиль
Группа: Участник
Сообщений: 12
Регистрация: 4.5.2008

Репутация: нет
Всего: нет

огромнейшее спасибо всем ) здорово помогли мне!
а можно еще для batton 2 сделать, что бы он обратно менял - то есть предыдущую показывал - а batton 3 самую первую? smile

THandle

Дата 11.1.2009, 00:03 (ссылка)

(голосов:1)

Загрузка ...

Хранитель Клуба
Group Icon

Награды: 1

Профиль
Группа: Админ
Сообщений: 3639
Регистрация: 31.7.2007
Где: Moscow, Dubai

Репутация: 50
Всего: 372

Можно.

Присоединённый файл ( Кол-во скачиваний: 10 )

ExResource.rar 71,60 Kb

Данкинг

Дата 11.1.2009, 00:03 (ссылка)

(нет голосов)

Загрузка ...

Yersinia pestis

Профиль
Группа: Завсегдатай
Сообщений: 8302
Регистрация: 7.11.2006
Где: მოსკოვი

Репутация: 11
Всего: 130

Цитата(Violina @ 10.1.2009, 23:55

)

а можно еще для batton 2 сделать, что бы он обратно менял - то есть предыдущую показывал - а batton 3 самую первую?

Можно. Для этого стоит подумать над процедурками обработки кликов кнопок 2 и 3. Для 3 я придумал. smile

Код


procedure TForm1.Button3Click(Sender: TObject);
begin
  LoadJPEGFromRes(PictureNames[1], Image1.Picture);
end;

А для 2 - предоставляю возможность подумать самостоятельно! smile

Это сообщение отредактировал(а) Данкинг - 11.1.2009, 00:03

--------------------

There's nothing left but silent epitaphs.

1 Пользователей читают эту тему (1 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Delphi: Для новичков \| Следующая тема »