VPF::[Asm] Слова налаживаются друг на друга при выводе

Igor_K

Дата 25.5.2009, 18:51 (ссылка)

(нет голосов)

Загрузка ...

Бывалый

Профиль
Группа: Участник
Сообщений: 166
Регистрация: 4.2.2008
Где: Kyiv

Репутация: нет
Всего: нет

Здравствуйте!
Уже давно не могу разобраться с программой. В ней нужно ввести имя и фамилию. Потом напечатать их на экране.

Написал так:

Код


DOSSEG
.MODEL SMALL
.STACK 100h
.DATA
imia     db 255, 255, 255 dup("$")
familiya db 255, 255, 255 dup("$")
prabel   db ' ', '$'
privet   db 'Privet ', '$'
vvod1    db 'Imia: ', '$'
vvod2    db 'Familiya: ', '$'
CR_LF   db 13,10,"$"

.CODE
st_pr:
    mov ax,@Data
    mov ds,ax

    ; Ввод имени
    mov ah, 09h
    mov dx, offset vvod1
    int 21h
    mov dx, offset imia
    mov ah, 0ah
    int 21h

    ; Перевод строки
    mov ah, 09h
    mov dx, offset CR_LF
    int 21h

    ; Ввод фамилии
    mov ah, 09h
    mov dx, offset vvod2
    int 21h
    mov dx, offset familiya
    mov ah, 0ah
    int 21h

    ; Перевод строки
    mov ah, 09h
    mov dx, offset CR_LF
    int 21h

    ; вывод Привет имя фамилия
    mov ah, 09h
    mov dx, offset privet
    int 21h
    mov dx, offset imia
    int 21h
    mov dx, offset familiya
    int 21h


    mov ah, 4ch
    int 21h
END st_pr

Так выводит на экран:
user posted image

Цитата

C:\BP\BIN>zx
Imia: Vasia
Familiya: Pupkin
♠Pupkin♣Vasia
C:\BP\BIN>zx
Imia: Vasilisa
Familiya: Pupkina
Pupkinaasilisa

Ввожу Василиса Пупкина. одну букву "схавало" Pupkinaasilisa
Если ввести длинее слово, то схавает больше символов

Мне посоветовали прибавить двойки:

Код


    mov dx, offset imia+2
    int 21h
    mov dx, offset familiya+2
    int 21h

Символов ♣ и ♠ нету. Но буквы "хавает" всеравно.

И еще почему-то не выводится слово Privet. Оно стоит в самом начале и его не видно вообще....

Код


; вывод Привет имя фамилия
    mov ah, 09h
    mov dx, offset privet
    int 21h
    mov dx, offset imia
    int 21h
    mov dx, offset familiya
    int 21h

Помогите пожалуйста переделать программу чтобы выводило правильно на экран!
Чтобы было PrivetVasiaPupkin

586

Дата 25.5.2009, 20:44 (ссылка)

(нет голосов)

Загрузка ...

Эксперт

Профиль
Группа: Завсегдатай
Сообщений: 2243
Регистрация: 8.5.2006

Репутация: 7
Всего: 146

Слово "Privet" не печатается из за того, что в буфере ведённых слов присутствует символ переноса каретки CR. При печатании слов каретка переносится на начало, и стирает слово привет.
14BD:0000        FF 05 56 61 73 69-61 0D 24 24 24 24 24 24     ..Vasia.$$$$$$
14BD:0010  24 24 24 24 24 24 24 24-24 24 24 24 24 24 24 24   $$$$$$$$$$$$$$$$
14BD:0020  24 24 24 24 24 24 24 24-24 24 24 24 24 24 24 24   $$$$$$$$$$$$$$$$
Первые два символа в буфере - это не строка. Если интересно, что это такое - читай описание:

Цитата(http://www.ctyme.com/intr/rb-2563.htm)

Offset  Size    Description     (Table 01344)
00h    BYTE    maximum characters buffer can hold
01h    BYTE    (call) number of chars from last input which may be recalled
(ret) number of characters actually read, excluding CR
02h  N BYTEs   actual characters read, including the final carriage return

Код

DOSSEG
.MODEL SMALL
.STACK 100h
.DATA
imia     db 255, 255, 255 dup("$")
familiya db 255, 255, 255 dup("$")
prabel   db ' ', '$'
privet   db 'Privet ', '$'
vvod1    db 'Imia: ', '$'
vvod2    db 'Familiya: ', '$'
CR_LF   db 13,10,"$"

.CODE
st_pr:
    mov ax,@Data
    mov ds,ax

    ; Ввод имени
    mov ah, 09h
    mov dx, offset vvod1
    int 21h

    mov dx, offset imia
    mov ah, 0ah
    int 21h

    mov  bx,offset imia
    mov  al,[bx+1]
    add  al,01
    xor  ah,ah
    mov  si,ax
    mov  byte [bx+si],'$'

    ; Перевод строки
    mov ah, 09h
    mov dx, offset CR_LF
    int 21h

    ; Ввод фамилии
    mov ah, 09h
    mov dx, offset vvod2
    int 21h

    mov dx, offset familiya
    mov ah, 0ah
    int 21h

    mov  bx,offset familiya
    mov  al,[bx+1]
    add  al,01
    xor  ah,ah
    mov  si,ax
    mov  byte [bx+si],'$'

    ; Перевод строки
    mov ah, 09h
    mov dx, offset CR_LF
    int 21h

    ; вывод Привет имя фамилия
mov al, 0
    mov ah, 09h
    mov dx, offset privet
    int 21h

    mov ah, 09h
    mov dx, offset imia+2
    int 21h

mov ah, 02h
mov dl, ' '
int 21h            ; putch(' ')

    mov ah, 09h
    mov dx, offset familiya+2
    int 21h

    mov ah, 4ch
    int 21h

END st_pr

Это сообщение отредактировал(а) 586 - 25.5.2009, 20:48

Igor_K

Дата 1.6.2009, 14:59 (ссылка)

(нет голосов)

Загрузка ...

Бывалый

Профиль
Группа: Участник
Сообщений: 166
Регистрация: 4.2.2008
Где: Kyiv

Репутация: нет
Всего: нет

586, СПАСИБО!!! smile

0 Пользователей читают эту тему (0 Гостей и 0 Скрытых Пользователей)
0 Пользователей:
« Предыдущая тема \| Центр помощи \| Следующая тема »